Use software NRZI encoder to reduce PIO usage

[sekigon-gonnoc]

Currently, the TX state machine performs NRZI encoding, utilizing one PIO state machine and 22 instructions. If we pre-execute this encoding in software, we can reduce the number of instructions to three.

out pc, 8 side 0b00; se0
out pc, 8 side 0b10; K
out pc, 8 side 0b01; J

Then, if we could reduce the number of instructions used for RX by three, we could reduce the total number of PIOs used for PIO-USB to one.

[sekigon-gonnoc]

This can likely reduce three instructions. (not tested)

start:
    ; set x, 0
.wrap_target
set_y:
    set y, BIT_REPEAT_COUNT
irq_wait:
    wait 1 irq DECODER_TRIGGER			; wait signal from edge detector
+    jmp !y flip			; ignore stuff bit, without error check
    jmp PIN pin_high
pin_low:
-    jmp !y flip			; ignore stuff bit, without error check
    jmp !x K1
K2:
    ; x==1
-    in null, 1
-    jmp flip
+   jmp J1
K1:
    ; x==0
    in osr, 1
    jmp y-- irq_wait
    
pin_high:
-    jmp !y flip			; ignore stuff bit, without error check
    jmp !x J1
J2:
    ; x==1
-   in x, 1
-   jmp y-- irq_wait
+  jmp K1  ; y is never 0 at here
J1:
    ; x==0
    in null, 1
flip:
    mov x, ~x
.wrap

[sekigon-gonnoc]

This can likely reduce five instructions. (not tested)

start:
    ; set x, 0
.wrap_target
set_y:
    set y, BIT_REPEAT_COUNT
irq_wait:
    wait 1 irq DECODER_TRIGGER			; wait signal from edge detector
+    jmp !y flip			; ignore stuff bit, without error check
    jmp PIN pin_high
pin_low:
-    jmp !y flip			; ignore stuff bit, without error check
    jmp !x K1
K2:
    ; x==1
-    in null, 1
-    jmp flip
+ J1:
+   in null, 1
+ flip:
+     mov x, ~x
+ .wrap

- K1:
-    ; x==0
-    in osr, 1
-    jmp y-- irq_wait
    
pin_high:
-    jmp !y flip			; ignore stuff bit, without error check
    jmp !x J1
J2:
    ; x==1
-   in x, 1
-   jmp y-- irq_wait
+ K1:
+    ; x==0
+    in osr, 1
+   jmp y-- irq_wait
- J1:
-    ; x==0
-    in null, 1
- flip:
-     mov x, ~x
- .wrap

[sekigon-gonnoc]

TX pio instructions will be like this

irq IRQ_EOP side 0b00 [1]
.wrap_target
out pc, 2 side 0b10
set pindirs, 0b00, side 0b10
out pc, 2 side 0b01
.start
set pindirs, 0b11  side 0b10
.wrap

[ghost]

Hi @sekigon-gonnoc,

tested your last RX-code and it worked with my midi interface.
I would add a "jmp set_y" at the end, otherwise there could be unpredictable result in case of a bitstuffing error.

In my opinion the number of instructions can be reduced in the edge detector part. According to my experience in 'real life', less synchronisation is better than more to avoid instabilities. (I even found that RX code does work without any sycnroisation with my devices.)
So this code works with a max. correction of +/- 12,5%:

eop:
irq wait IRQ_RX_EOP
start:
jmp pin start ; Wait fall edge
irq IRQ_RX_START [1]

.wrap_target
pin_still_low:
irq DECODER_TRIGGER [3] ; Trigger NRZI decoder

; Resync on rising edge
pin_low:
jmp pin pin_went_high
pin_went_low:
jmp pin pin_went_high
jmp pin pin_went_high [1]
; jmp pin pin_went_high
; jmp pin pin_went_high
; jmp pin pin_went_high
.wrap

pin_still_high:
mov x, isr [2]
jmp x-- eop ; Jump to eop if jmp_pin and in_pin are high because both inputs are inverted
; Jump to here on rising edge
pin_went_high:
mov isr, null
in pins, 1 ; Capture the pin to check eop.
irq DECODER_TRIGGER ; Trigger NRZI decoder
jmp pin pin_still_high
; jmp pin_went_low ; To adjust interval of decoder trigger, jump to pin_went_low (not pin_low)
jmp pin_low [1]

[sekigon-gonnoc]

Thank you for your confirmation.

I would add a "jmp set_y" at the end, otherwise there could be unpredictable result in case of a bitstuffing error.

Since the irq_wait part ensures that y is not zero, y will not be zero at the end.

So this code works with a max. correction of +/- 12,5%:

The clock standard for USB Low-Speed devices is ±1.5% (especially cheap LS devices tend to have poor frequency accuracy. e.g. #18 ). The interval between rising edges can be up to 11 bits, so it needs to tolerate a 16.5% variation. If the operating frequency is set to x6 instead of x8 of USB clock, one instruction of synchronization might be sufficient.

[ghost]

Thanks for your answer.
You are totally right - y does not get zero at that point. Didn't see that.

[sekigon-gonnoc]

https://github.com/sekigon-gonnoc/Pico-PIO-USB/tree/single-pio

This worked as an FS/LS host with single PIO. I have not yet confirmed the connection via a hub and the devices.

[ghost]

Hi @sekigon-gonnoc ,

so i tested your code with my midi interface (with 3 host ports) and must say: it does work without any issues.

To be honest, i expected a lag because of the additional encoding routine, but i couldn't notice any difference.

This was great work!
'

[ATMakersBill]

Will this code that reduces the PIO usage allow an adafruit usb host feather to use the neopixel? I believe it needs PIO for the timing so perhaps this will allow them both to run