Merge pull request #33 from Tyil/command-clean

Command clean

Author: Tyil

META6.json

@@ -21,9 +21,11 @@
   "perl": "6.c",
   "provides": {
     "App::Cpan6": "lib/App/Cpan6.pm6",
+    "App::Cpan6::Clean": "lib/App/Cpan6/Clean.pm6",
     "App::Cpan6::Commands::Bootstrap::Config": "lib/App/Cpan6/Commands/Bootstrap/Config.pm6",
     "App::Cpan6::Commands::Bootstrap::Man": "lib/App/Cpan6/Commands/Bootstrap/Man.pm6",
     "App::Cpan6::Commands::Bump": "lib/App/Cpan6/Commands/Bump.pm6",
+    "App::Cpan6::Commands::Clean": "lib/App/Cpan6/Commands/Clean.pm6",
     "App::Cpan6::Commands::Depend": "lib/App/Cpan6/Commands/Depend.pm6",
     "App::Cpan6::Commands::Dist": "lib/App/Cpan6/Commands/Dist.pm6",
     "App::Cpan6::Commands::Help": "lib/App/Cpan6/Commands/Help.pm6",
@@ -67,4 +69,4 @@
     "ecosystems"
   ],
   "version": "0.17.3"
-}
+}

bin/cpan6

@@ -5,6 +5,7 @@ use v6.c;
 use App::Cpan6::Commands::Bootstrap::Config;
 use App::Cpan6::Commands::Bootstrap::Man;
 use App::Cpan6::Commands::Bump;
+use App::Cpan6::Commands::Clean;
 use App::Cpan6::Commands::Depend;
 use App::Cpan6::Commands::Dist;
 use App::Cpan6::Commands::Help;

lib/App/Cpan6/Clean.pm6

@@ -0,0 +1,104 @@
+#! /usr/bin/env false
+
+use v6.c;
+
+use App::Cpan6::Meta;
+use App::Cpan6::Input;
+
+unit module App::Cpan6::Clean;
+
+sub clean-files (
+	Str:D :$path,
+	Bool:D :$force = False,
+	Bool:D :$verbose = False,
+	--> Bool
+) is export {
+	my %meta = get-meta;
+
+	# Clean up bin and lib directories
+	for < bin lib > -> $directory {
+		for find-files($directory) -> $file {
+			next if ~$file ~~ /\.precomp/;
+			next if %meta<provides>.values ∋ ~$file;
+
+			say "Removing $file" if $verbose;
+			unlink($file) if $force || confirm("Really delete $file?");
+		}
+	}
+
+	# Clean up resources
+	for find-files("resources") -> $file {
+		next if %meta<resources> ∋ $file.subst("resources/", "");
+
+		say "Removing $file" if $verbose;
+		unlink($file) if $force || confirm("Really delete $file?");
+	}
+}
+
+sub clean-meta (
+	Str:D :$path = ".",
+	Bool:D :$force = False,
+	Bool:D :$verbose = False,
+	--> Bool
+) is export {
+	my %meta = get-meta($path);
+	my %provides;
+	my @resources;
+
+	# Clean up provides
+	for %meta<provides>.kv -> $key, $value {
+		if ($value.IO.e) {
+			%provides{$key} = $value;
+
+			next;
+		}
+
+		say "Removing provides.$key ($value)" if $verbose;
+	}
+
+	# Clean up resources
+	for %meta<resources>.values -> $value {
+		if ("resources/$value".IO.e) {
+			@resources.push: $value;
+
+			next
+		}
+
+		say "Removing resources.$value" if $verbose;
+	}
+
+	return False unless $force || confirm("Save cleaned META6.json?");
+
+	%meta<provides> = %provides;
+	%meta<resources> = @resources;
+
+	put-meta(:%meta, :$path);
+}
+
+multi sub find-files (
+	Str:D $path
+	--> List
+) is export {
+	find-files($path.IO)
+}
+
+multi sub find-files (
+	IO::Path:D $path
+	--> List
+) is export {
+	my @files;
+
+	for $path.dir -> $object {
+		if ($object.IO.d) {
+			@files.append: find-files($object);
+
+			next;
+		}
+
+		@files.append: $object;
+	}
+
+	@files;
+}
+
+# vim: ft=perl6 noet

lib/App/Cpan6/Commands/Clean.pm6

@@ -0,0 +1,26 @@
+#! /usr/bin/env false
+
+use v6.c;
+
+use App::Cpan6::Clean;
+
+unit module App::Cpan6::Commands::Clean;
+
+multi sub MAIN(
+	"clean",
+	Str:D $path = ".",
+	Bool:D :$no-meta = False,
+	Bool:D :$no-files = False,
+	Bool:D :$force = False,
+	Bool:D :$verbose = False,
+) is export {
+	# Clean up the META6.json
+	clean-meta(:$path, :$force, :$verbose) unless $no-meta;
+
+	# Clean up unreferenced files
+	clean-files(:$path, :$force, :$verbose) unless $no-files;
+
+	True;
+}
+
+# vim: ft=perl6 noet

resources/man/cpan6.1.adoc

@@ -31,6 +31,12 @@ Bumps the module's patch, minor or major version. If no bump type is supplied,
 it will be prompted. If a `.git` repository is found, a commit and a tag will
 be created as well.
 
+=== [ --no-files ] [ --no-meta ] clean < path >
+Clean up files not referenced in the `META6.json`, and remove entries from
+`META6.json` which have no corresponding file. The `--no-files` flag will not
+remove files without a corresponding entry in the `META6.json`, while the
+`--no-meta` won't touch your `META6.json`.
+
 === [ --no-install ] depend < modules ... >
 Add a dependency to one or more modules. Will attempt to install the module
 locally as well, unless `--no-install` is supplied.

t/command-clean.t

@@ -0,0 +1,79 @@
+#! /usr/bin/env perl6
+
+use v6.c;
+
+use App::Cpan6::Commands::Clean;
+use App::Cpan6::Commands::New;
+use App::Cpan6::Meta;
+use File::Temp;
+use Test;
+
+multi sub MAIN { 0 }
+
+# Disable git
+%*ENV<CPAN6_EXTERNAL_GIT> = False;
+
+my $root = tempdir;
+
+chdir $root;
+
+plan 4;
+
+ok MAIN(
+	"new",
+	name => "Local::Test::Clean",
+	author => "Patrick Spek",
+	email => "p.spek@tyil.work",
+	perl => "c",
+	description => "Nondescript",
+	license => "GPL-3.0",
+	no-user-config => True,
+), "cpan6 new Local::Test::Clean";
+
+# Create a non-clean META6.json
+my %meta = get-meta;
+%meta<provides><Local::Test::Clean::Orphan> = "lib/non-existant.pm6";
+
+subtest "cpan6 clean", {
+	plan 3;
+
+	# Setup
+	mkdir "resources";
+	spurt "resources/alpha", "";
+	put-meta(:%meta);
+
+	# Test
+	ok MAIN("clean", :force);
+	nok "resources/alpha".IO.e;
+	nok get-meta()<provides><Local::Test::Clean::Orphan>:exists;
+}
+
+subtest "cpan6 --no-files clean", {
+	plan 3;
+
+	# Setup
+	mkdir "resources";
+	spurt "resources/beta", "";
+	put-meta(:%meta);
+
+	# Test
+	ok MAIN("clean", :force, :no-files);
+	ok "resources/beta".IO.e;
+	nok get-meta()<provides><Local::Test::Clean::Orphan>:exists;
+}
+
+subtest "cpan6 --no-meta clean", {
+	plan 3;
+
+	# Setup
+	mkdir "resources";
+	spurt "resources/gamma", "";
+	put-meta(:%meta);
+
+	# Test
+	ok MAIN("clean", :force, :no-meta);
+	nok "resources/gamma".IO.e;
+	ok get-meta()<provides><Local::Test::Clean::Orphan>:exists;
+}
+
+# vim: ft=perl6 noet