build.gradle

group = 'org.batcha.gradle.plugins'
description = 'The Git dependencies plugin provides integration of other Gradle project dependencies via git'
version = '0.1'

apply plugin: 'eclipse'
apply plugin: 'groovy'
apply plugin: 'maven'

apply plugin: 'signing'
apply plugin: 'github-pages'

buildscript {
  repositories { mavenCentral() }
  dependencies { classpath 'org.ajoberstar:gradle-git:0.2.3' }
}

repositories {	 mavenCentral() }

dependencies {
  compile (gradleApi())
  compile ('org.eclipse.jgit:org.eclipse.jgit:2.3.1.201302201838-r') {
    transitive true  
  }  
  testCompile group: 'junit', name: 'junit', version: '4.11'
  groovy localGroovy()
}

githubPages {
  repoUri = 'git@github.com:bat-cha/gradle-plugin-git-dependencies.git'
  pages {
    from(javadoc.outputs.files) {
      into 'docs/javadoc'
    }
    from(groovydoc.outputs.files) {
      into 'docs/groovydoc'
    }
  }
}

task wrapper(type: Wrapper) { gradleVersion = '1.6' }

task sourcesJar(type: Jar, dependsOn:classes) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

task javadocJar(type:Jar) {
  classifier = 'javadoc'
  from javadoc.outputs.files
}

task groovydocJar(type: Jar, dependsOn:groovydoc) {
  classifier = 'groovydoc'
  from groovydoc.destinationDir
}

artifacts {
  archives sourcesJar
  archives javadocJar
  archives groovydocJar
}

signing {
    required { gradle.taskGraph.hasTask("uploadArchives") }
  sign configurations.archives
}

uploadArchives {
  repositories {
    mavenDeployer {
      name = 'Sonatype OSS'
      repository(url:'https://oss.sonatype.org/service/local/staging/deploy/maven2') {
        authentication(userName:sonatypeUserName, password:sonatypePassword)
      }
      snapshotRepository(url:'https://oss.sonatype.org/content/repositories/snapshots') {
        authentication(userName:sonatypeUserName, password:sonatypePassword)
      }
  
      beforeDeployment { signing.signPom it }
      
      pom.project {
        name project.name
        description project.description
        url "https://github.com/bat-cha/gradle-plugin-git-dependencies"
        licenses {
          license {
            name "LGPL V3 License"
            url "https://raw.github.com/bat-cha/gradle-plugin-git-dependencies/master/lgpl-3.0.txt"
          }
        }
        developers {
          developer {
            id "bat-cha"
            name "Baptiste Chatrain"
            email "baptiste.chatrain@gmail.com"
          }
        }
        scm {
          connection "scm:git:git://github.com/bat-cha/gradle-plugin-git-dependencies.git"
          developerConnection "scm:git:git@github.com:bat-cha/gradle-plugin-git-dependencies.git"
          url "https://github.com/bat-cha/gradle-plugin-git-dependencies"
        }
      }
    }
  }
}