-
-
Notifications
You must be signed in to change notification settings - Fork 528
/
Copy pathax_check_liblzma.m4
143 lines (139 loc) · 5.43 KB
/
ax_check_liblzma.m4
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
# ===========================================================================
# ax_check_lzma - derived from
# https://www.gnu.org/software/autoconf-archive/ax_check_zlib.html
# ===========================================================================
#
# SYNOPSIS
#
# AX_CHECK_LIBLZMA([action-if-found], [action-if-not-found])
#
# DESCRIPTION
#
# This macro searches for an installed lzma library. If nothing was
# specified when calling configure, it searches first in /usr/local and
# then in /usr, /opt/local and /sw. If the --with-lzma=DIR is specified,
# it will try to find it in DIR/include/lzma.h and DIR/lib/liblzma.a. If
# --without-lzma is specified, the library is not searched at all.
#
# If either the header file (lzma.h) or the library (liblzma) is not found,
# shell commands 'action-if-not-found' is run. If 'action-if-not-found' is
# not specified, the configuration exits on error, asking for a valid lzma
# installation directory or --without-lzma.
#
# If both header file and library are found, shell commands
# 'action-if-found' is run. If 'action-if-found' is not specified, the
# default action appends '-I${LZMA_HOME}/include' to CPFLAGS, appends
# '-L$LZMA_HOME}/lib' to LDFLAGS, prepends '-llzma' to LIBS, and calls
# AC_DEFINE(HAVE_LIBLZMA). You should use autoheader to include a definition
# for this symbol in a config.h file. Sample usage in a C/C++ source is as
# follows:
#
# #ifdef HAVE_LIBLZMA
# #include <lzma.h>
# #endif /* HAVE_LIBLZMA */
#
# LICENSE
#
# Copyright (c) 2008 Loic Dachary <loic@senga.org>
# Copyright (c) 2010 Bastien Chevreux <bach@chevreux.org>
# Copyright (c) 2018 Dima Pasechnik <dima@pasechnik.info>
#
# This program is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the
# Free Software Foundation; either version 2 of the License, or (at your
# option) any later version.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
# Public License for more details.
#
# You should have received a copy of the GNU General Public License along
# with this program. If not, see <https://www.gnu.org/licenses/>.
#
# As a special exception, the respective Autoconf Macro's copyright owner
# gives unlimited permission to copy, distribute and modify the configure
# scripts that are the output of Autoconf when processing the Macro. You
# need not follow the terms of the GNU General Public License when using
# or distributing such scripts, even though portions of the text of the
# Macro appear in them. The GNU General Public License (GPL) does govern
# all other use of the material that constitutes the Autoconf Macro.
#
# This special exception to the GPL applies to versions of the Autoconf
# Macro released by the Autoconf Archive. When you make and distribute a
# modified version of the Autoconf Macro, you may extend this special
# exception to the GPL to apply to your modified version as well.
#serial 16
AU_ALIAS([CHECK_LZMA], [AX_CHECK_LZMA])
AC_DEFUN([AX_CHECK_LZMA],
#
# Handle user hints
#
[AC_MSG_CHECKING(if lzma is wanted)
lzma_places="/usr/local /usr /opt/local /sw"
AC_ARG_WITH([lzma],
[ --with-lzma=DIR root directory path of lzma installation @<:@defaults to
/usr/local or /usr if not found in /usr/local@:>@
--without-lzma to disable lzma usage completely],
[if test "$withval" != no ; then
AC_MSG_RESULT(yes)
if test -d "$withval"
then
lzma_places="$withval $lzma_places"
else
AC_MSG_WARN([Sorry, $withval does not exist, checking usual places])
fi
else
lzma_places=
AC_MSG_RESULT(no)
fi],
[AC_MSG_RESULT(yes)])
#
# Locate lzma, if wanted
#
if test -n "${lzma_places}"
then
# check the user supplied or any other more or less 'standard' place:
# Most UNIX systems : /usr/local and /usr
# MacPorts / Fink on OSX : /opt/local respectively /sw
for LZMA_HOME in ${lzma_places} ; do
if test -f "${LZMA_HOME}/include/lzma.h"; then break; fi
LZMA_HOME=""
done
LZMA_OLD_LDFLAGS=$LDFLAGS
LZMA_OLD_CPPFLAGS=$CPPFLAGS
if test -n "${LZMA_HOME}"; then
LDFLAGS="$LDFLAGS -L${LZMA_HOME}/lib"
CPPFLAGS="$CPPFLAGS -I${LZMA_HOME}/include"
fi
AC_LANG_PUSH([C])
AC_CHECK_LIB([lzma], [lzma_raw_decoder], [lzma_cv_liblzma=yes], [lzma_cv_liblzma=no])
AC_CHECK_HEADER([lzma.h], [lzma_cv_lzma_h=yes], [lzma_cv_lzma_h=no])
AC_LANG_POP([C])
if test "$lzma_cv_liblzma" = "yes" && test "$lzma_cv_lzma_h" = "yes"
then
#
# If both library and header were found, action-if-found
#
m4_ifblank([$1],[
CPPFLAGS="$CPPFLAGS -I${LZMA_HOME}/include"
LDFLAGS="$LDFLAGS -L${LZMA_HOME}/lib"
LIBS="-llzma $LIBS"
AC_DEFINE([HAVE_LIBLZMA], [1],
[Define to 1 if you have `lzma' library (-llzma)])
],[
# Restore variables
LDFLAGS="$LZMA_OLD_LDFLAGS"
CPPFLAGS="$LZMA_OLD_CPPFLAGS"
$1
])
else
#
# If either header or library was not found, action-if-not-found
#
m4_default([$2],[
AC_MSG_ERROR([either specify a valid lzma installation with --with-lzma=DIR or disable lzma usage with --without-lzma])
])
fi
fi
])