[CMake] Speed up copying of headers.

To copy headers to the build tree, ROOT was creating one target per header.
Headers are copied in packs of 100 (Windows doesn't support very long command lines).
This significantly reduces the number of CMake targets and speeds up the build.

A simple test that only moves headers:
make -j6 move_headers   New     Old
1st invocation          10.7 s  34.5 s
2nd invocation           2.7 s   3.8 s

Fix #14953.

Author: hageboeck

CMakeLists.txt

@@ -379,6 +379,10 @@ endif()
 ROOT_ADD_TEST_SUBDIRECTORY(test)
 ROOT_ADD_TEST_SUBDIRECTORY(tutorials)
 
+# Each subdirectory added above will register headers to be copied to the build tree.
+# Here, the copy targets are created:
+ROOT_CREATE_HEADER_COPY_TARGETS()
+
 get_property(__allHeaders GLOBAL PROPERTY ROOT_HEADER_TARGETS)
 get_property(__allBuiltins GLOBAL PROPERTY ROOT_BUILTIN_TARGETS)
 add_custom_target(move_headers ALL DEPENDS ${__allHeaders} ${__allBuiltins} gitinfotxt)

builtins/nlohmann/CMakeLists.txt

@@ -11,15 +11,11 @@ string(REGEX REPLACE ".+NLOHMANN_JSON_VERSION_PATCH[ ]+([0-9]+).*$" "\\1" JSON_V
 set(nlohmann_json_VERSION "${JSON_VERSION_MAJOR}.${JSON_VERSION_MINOR}.${JSON_VERSION_PATCH}" PARENT_SCOPE)
 unset(JSON_H)
 
-add_custom_command(
-     OUTPUT ${CMAKE_BINARY_DIR}/include/nlohmann/json.hpp
-     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_SOURCE_DIR}/builtins/nlohmann/json.hpp ${CMAKE_BINARY_DIR}/include/nlohmann/json.hpp
-     COMMENT "Copying nlohmann/json.hpp header to ${CMAKE_BINARY_DIR}/include"
+add_custom_target(builtin_nlohmann_json ALL
+     BYPRODUCTS ${CMAKE_BINARY_DIR}/include/nlohmann/json.hpp
+     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_SOURCE_DIR}/builtins/nlohmann/json.hpp ${CMAKE_BINARY_DIR}/include/nlohmann/json.hpp
      DEPENDS ${CMAKE_SOURCE_DIR}/builtins/nlohmann/json.hpp)
-
-add_custom_target(builtin_nlohmann_json_incl DEPENDS ${CMAKE_BINARY_DIR}/include/nlohmann/json.hpp)
-
-set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_TARGETS builtin_nlohmann_json_incl)
+set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_TARGETS builtin_nlohmann_json)
 
 install(FILES ${CMAKE_SOURCE_DIR}/builtins/nlohmann/json.hpp DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/nlohmann/)
 

cmake/modules/RootMacros.cmake

@@ -1217,7 +1217,9 @@ function(ROOT_FIND_DIRS_WITH_HEADERS result_dirs)
 endfunction()
 
 #---------------------------------------------------------------------------------------------------
-#---ROOT_INSTALL_HEADERS([dir1 dir2 ...] OPTIONS [options])
+#---ROOT_INSTALL_HEADERS([dir1 dir2 ...] [FILTER <regex>])
+# Glob for headers in the folder where this target is defined, and install them in
+# <buildDir>/include
 #---------------------------------------------------------------------------------------------------
 function(ROOT_INSTALL_HEADERS)
   CMAKE_PARSE_ARGUMENTS(ARG "OPTIONS" "" "FILTER" ${ARGN})
@@ -1232,35 +1234,77 @@ function(ROOT_INSTALL_HEADERS)
     set (options ${options} REGEX "${f}" EXCLUDE)
   endforeach()
   set (filter "(${filter})")
+  set(include_files "")
   foreach(d ${dirs})
     install(DIRECTORY ${d} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
                            COMPONENT headers
                            ${options})
     string(REGEX REPLACE "(.*)/$" "\\1" d ${d})
-    ROOT_GLOB_FILES(include_files
+    ROOT_GLOB_FILES(globbed_files
       RECURSE
-      RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}/${d}
+      RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
       FILTER ${filter}
       ${d}/*.h ${d}/*.hxx ${d}/*.icc )
-    foreach (include_file ${include_files})
-      set (src ${CMAKE_CURRENT_SOURCE_DIR}/${d}/${include_file})
-      set (dst ${CMAKE_BINARY_DIR}/include/${include_file})
-      add_custom_command(
-        OUTPUT ${dst}
-        COMMAND ${CMAKE_COMMAND} -E copy ${src} ${dst}
-        COMMENT "Copying header ${src} to ${CMAKE_BINARY_DIR}/include"
-        DEPENDS ${src})
-      list(APPEND dst_list ${dst})
-    endforeach()
+    list(APPEND include_files ${globbed_files})
+  endforeach()
+
+  string(REPLACE ${CMAKE_SOURCE_DIR} "" target_name ${CMAKE_CURRENT_SOURCE_DIR})
+  string(REPLACE / _ target_name "copy_header_${target_name}")
+  string(REGEX REPLACE "_$" "" target_name ${target_name})
+
+  # Register the files to be copied for each target directory (e.g. include/ include/ROOT include/v7/inc/ ...)
+  list(REMOVE_DUPLICATES include_files)
+  list(TRANSFORM include_files REPLACE "(.*)/[^/]*" "\\1/" OUTPUT_VARIABLE subdirs)
+  list(REMOVE_DUPLICATES subdirs)
+  foreach(subdir ${subdirs})
+    set(input_files ${include_files})
+    list(FILTER input_files INCLUDE REGEX "^${subdir}[^/]*$")
+    set(output_files ${input_files})
+
+    string(REGEX REPLACE ".*/*inc/" "" destination ${subdir})
+
+    list(TRANSFORM input_files  PREPEND "${CMAKE_CURRENT_SOURCE_DIR}/")
+    list(TRANSFORM output_files REPLACE ".*/" "${CMAKE_BINARY_DIR}/include/${destination}")
+
+    set(destination destination_${destination})
+
+    set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_COPY_LISTS ${destination})
+    set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_INPUT_${destination} ${input_files})
+    set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_OUTPUT_${destination} ${output_files})
   endforeach()
-  if (dst_list)
-    string(REPLACE ${CMAKE_SOURCE_DIR} "" tgt ${CMAKE_CURRENT_SOURCE_DIR})
-    string(MAKE_C_IDENTIFIER move_header${tgt} tgt)
-    set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_TARGETS ${tgt})
-    add_custom_target(${tgt} DEPENDS ${dst_list})
-  endif()
 endfunction()
 
+#---------------------------------------------------------------------------------------------------
+#--- ROOT_CREATE_HEADER_COPY_TARGETS
+#    Creates a target to copy all headers that have been registered for copy in ROOT_INSTALL_HEADERS
+#---------------------------------------------------------------------------------------------------
+macro(ROOT_CREATE_HEADER_COPY_TARGETS)
+  get_property(HEADER_COPY_LISTS GLOBAL PROPERTY ROOT_HEADER_COPY_LISTS)
+  list(REMOVE_DUPLICATES HEADER_COPY_LISTS)
+  foreach(copy_list ${HEADER_COPY_LISTS})
+    get_property(inputs  GLOBAL PROPERTY ROOT_HEADER_INPUT_${copy_list})
+    get_property(outputs GLOBAL PROPERTY ROOT_HEADER_OUTPUT_${copy_list})
+
+    string(REPLACE "destination_" "${CMAKE_BINARY_DIR}/include/" destination ${copy_list})
+
+    list(LENGTH inputs LIST_LENGTH)
+    # Windows doesn't support long command lines, so split them in packs:
+    foreach(range_start RANGE 0 ${LIST_LENGTH} 100)
+      list(SUBLIST outputs ${range_start} 100 sub_outputs)
+      list(SUBLIST inputs ${range_start} 100 sub_inputs)
+      list(LENGTH sub_outputs SUB_LENGTH)
+      if(NOT SUB_LENGTH EQUAL 0)
+        add_custom_command(OUTPUT ${sub_outputs}
+          COMMAND ${CMAKE_COMMAND} -E copy ${sub_inputs} ${destination}
+          COMMENT "Copy headers for ${destination} ${range_start}"
+          DEPENDS ${sub_inputs})
+      endif()
+    endforeach()
+    file(MAKE_DIRECTORY ${destination})
+    set_property(GLOBAL APPEND PROPERTY ROOT_HEADER_TARGETS ${outputs})
+  endforeach()
+endmacro()
+
 #---------------------------------------------------------------------------------------------------
 #---ROOT_STANDARD_LIBRARY_PACKAGE(libname
 #                                 [NO_INSTALL_HEADERS]         : don't install headers for this package