build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.3'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }
    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
    }
}

// major version is the SDK version
def versionMajor = 28
// minor version of the support library
def versionMinor = 0
// patch version of the support library
def versionPatch = 0

// composite android build version for the given support library version.
// increases when composite android receives updates but the support lib doesn't update
def versionBuild = 0

ext {
    supportLibraryVersion = "$versionMajor.$versionMinor.$versionPatch"
    VERSION_NAME = "$supportLibraryVersion" + (versionBuild != 0 ? "-$versionBuild" : "")
    VERSION_CODE = versionMajor * 10000 + versionMinor * 1000 + versionPatch * 100 + versionBuild
    MIN_SDK_VERSION = 14
    TARGET_SDK_VERSION = versionMajor
    COMPILE_SDK_VERSION = versionMajor

    ciBuild = System.getenv("TRAVIS") == "true"
}

task clean(type: Delete) {
    delete rootProject.buildDir
}