Create new namespace for version utilities

* Move version parsing and checking to its own namespace
* Store 'ghci' or 'intero' marker along with the version
* Add version parsing tests for Intero, new GHCi, and an old GHCi

Author: owickstrom

autoload/intero/process.vim

@@ -18,9 +18,8 @@ let g:intero_started = 0
 " Whether Intero has done its initialization yet
 let s:intero_initialized = 0
 
-let s:no_version = [0, 0, 0]
 " The version of GHCi, parsed on startup.
-let g:intero_ghci_version = s:no_version
+let g:intero_ghci_version = g:intero#process#version#no_version
 
 " If true, echo the next response. Reset after each response.
 let g:intero_echo_next = 0
@@ -293,27 +292,9 @@ function! s:on_stdout(jobid, lines, event) abort
     endfor
 endfunction
 
-function! s:parse_ghci_version(output) abort
-    for l:l in a:output
-        " Try parsing regular GHCi version.
-        let l:matches = matchlist(l:l, 'GHCi, version \(\d*\)\.\(\d*\).\(\d*\):')
-        if !empty(l:matches)
-            return [l:matches[1] + 0, l:matches[2] + 0, l:matches[3] + 0]
-        else
-            " Fallback to parsing Intero-style version.
-            let l:matches = matchlist(l:l, '(GHC \(\d*\)\.\(\d*\).\(\d*\))')
-            if !empty(l:matches)
-                return [l:matches[1] + 0, l:matches[2] + 0, l:matches[3] + 0]
-            endif
-        endif
-    endfor
-
-    return g:no_version
-endfunction
-
 function! s:on_initial_compile(output) abort
-    if g:intero_ghci_version == [0, 0, 0]
-        let g:intero_ghci_version = s:parse_ghci_version(a:output)
+    if g:intero_ghci_version == g:intero#process#version#no_version
+        let g:intero_ghci_version = g:intero#process#version#parse_lines(a:output)
     endif
 
     " Trigger Neomake's parsing of the compilation errors

autoload/intero/process/version.vim

@@ -0,0 +1,40 @@
+"""""""""""
+" Version:
+"
+" This file contains functions for parsing and checking GHCi versions.
+"""""""""""
+
+" A parsed version is a list of 4 elements, containing one string (either
+" 'intero' or 'ghci'), and three numbers, for the MAJOR, MINOR, and PATCH
+" versions.
+
+" An empty version value that can be used as a default, or to signal that
+" parsing failed.
+let g:intero#process#version#no_version = ['', 0, 0, 0]
+
+" Tries to parse the GHCi or Intero version from a list of lines.
+function! intero#process#version#parse_lines(output) abort
+    for l:l in a:output
+        " Try parsing regular GHCi version.
+        let l:matches = matchlist(l:l, 'GHC\%(i\|\sInteractive\), version \(\d*\)\.\(\d*\).\(\d*\)[:,]')
+        if !empty(l:matches)
+            return ['ghci', l:matches[1] + 0, l:matches[2] + 0, l:matches[3] + 0]
+        else
+            " Fallback to parsing Intero-style version.
+            let l:matches = matchlist(l:l, 'Intero .* (GHC \(\d*\)\.\(\d*\).\(\d*\))')
+            if !empty(l:matches)
+                return ['intero', l:matches[1] + 0, l:matches[2] + 0, l:matches[3] + 0]
+            endif
+        endif
+    endfor
+
+    return g:intero#process#version#no_version
+endfunction
+
+function! intero#process#version#is_intero(version) abort
+    return a:version[0] ==# 'intero'
+endfunction
+
+function! intero#process#version#is_ghci(version) abort
+    return a:version[0] ==# 'ghci'
+endfunction

test/intero/process/version.vader

@@ -0,0 +1,16 @@
+Execute (parse_lines handles GHCi output):
+    AssertEqual intero#process#version#parse_lines([ "GHCi, version 8.2.1: http://www.haskell.org/ghc/  :? for help",
+                                                   \ "Loaded GHCi configuration from /home/user/.ghci",
+                                                   \ "Prelude>"]), ["ghci", 8, 2, 1]
+
+Execute (parse_lines handles older GHCi output):
+    AssertEqual intero#process#version#parse_lines([ "   ___         ___ _",
+                                                   \ "  / _ \ /\  /\/ __(_)",
+                                                   \ " / /_\// /_/ / /  | |      GHC Interactive, version 6.0.1, for Haskell 98.",
+                                                   \ "/ /_\\/ __  / /___| |      http://www.haskell.org/ghc/",
+                                                   \ "\____/\/ /_/\____/|_|      Type :? for help."]), ["ghci", 6, 0, 1]
+
+Execute (parse_lines handles Intero output):
+    AssertEqual intero#process#version#parse_lines([ "Intero 0.1.21 (GHC 8.0.2)",
+                                                   \ "Type :intro and press enter for an introduction of the standard commands.",
+                                                   \ "Prelude>"]), ["intero", 8, 0, 2]