move char/unified conversion into precompiled Util module

madness? THIS IS SPARTA

Author: mroth

bench/exmoji_bench.exs

@@ -14,11 +14,11 @@ defmodule ExmojiBench do
   bench "find_by_short_name - many", do: Exmoji.find_by_short_name("MOON")
   bench "find_by_short_name - none", do: Exmoji.find_by_short_name("zzzz")
 
-  bench "char_to_unified - single", do: Exmoji.char_to_unified("🚀")
-  bench "char_to_unified - double", do: Exmoji.char_to_unified("\x{2601}\x{FE0F}")
+  bench "char_to_unified - single", do: Exmoji.Util.char_to_unified("🚀")
+  bench "char_to_unified - double", do: Exmoji.Util.char_to_unified("\x{2601}\x{FE0F}")
 
-  bench "unified_to_char - single", do: Exmoji.unified_to_char("1F47E")
-  bench "unified_to_char - double", do: Exmoji.unified_to_char("2764-fe0f")
-  bench "unified_to_char - triple", do: Exmoji.unified_to_char("0030-FE0F-20E3")
+  bench "unified_to_char - single", do: Exmoji.Util.unified_to_char("1F47E")
+  bench "unified_to_char - double", do: Exmoji.Util.unified_to_char("2764-fe0f")
+  bench "unified_to_char - triple", do: Exmoji.Util.unified_to_char("0030-FE0F-20E3")
 
 end

lib/exmoji.ex

@@ -159,47 +159,4 @@ defmodule Exmoji do
 
   defp _from_unified(_), do: nil
 
-
-  @doc """
-  Convert a unified ID directly to its bitstring glyph representation.
-
-  ## Example
-
-      iex> Exmoji.unified_to_char("1F47E")
-      "👾"
-
-  """
-  def unified_to_char(uid) do
-    uid
-    |> String.split("-")
-    |> Enum.map( &(String.to_integer(&1, 16)) )
-    |> List.to_string
-  end
-
-
-  @doc """
-  Convert a native bitstring glyph to its unified codepoint ID.
-
-  This is a conversion operation, not a match, so it may produce unexpected
-  results with different types of values.
-
-  ## Example
-
-      iex> Exmoji.char_to_unified("👾")
-      "1F47E"
-
-  """
-  def char_to_unified(char) do
-    char
-    |> String.codepoints
-    |> Enum.map(&padded_hex_string/1)
-    |> Enum.join("-")
-    |> String.upcase
-  end
-  defp padded_hex_string(codepoint) do
-    << cp_int_value :: utf8 >> = codepoint
-    cp_int_value |> Integer.to_string(16) |> String.rjust(4,?0)
-  end
-
-
 end

lib/exmoji/emoji_char.ex

@@ -44,12 +44,12 @@ defmodule Exmoji.EmojiChar do
   """
   def render(ec, options \\ [variant_encoding: true])
   def render(ec, variant_encoding: false) do
-    Exmoji.unified_to_char(ec.unified)
+    Exmoji.Util.unified_to_char(ec.unified)
   end
   def render(ec, variant_encoding: true) do
     case variant?(ec) do
-      true  -> Exmoji.unified_to_char( variant(ec) )
-      false -> Exmoji.unified_to_char( ec.unified )
+      true  -> Exmoji.Util.unified_to_char( variant(ec) )
+      false -> Exmoji.Util.unified_to_char( ec.unified )
     end
   end
 
@@ -66,7 +66,7 @@ defmodule Exmoji.EmojiChar do
   """
   def chars(%EmojiChar{unified: uid, variations: variations}) do
     [uid] ++ variations
-    |> Enum.map(&Exmoji.unified_to_char/1)
+    |> Enum.map(&Exmoji.Util.unified_to_char/1)
   end
 
   @doc """

lib/exmoji/scanner.ex

@@ -20,7 +20,7 @@ defmodule Exmoji.Scanner do
   """
   def scan(str) do
     bscan(str)
-    |> Enum.map(&Exmoji.char_to_unified/1)
+    |> Enum.map(&Exmoji.Util.char_to_unified/1)
     |> Enum.map(&Exmoji.from_unified/1)
   end
 

lib/exmoji/util.ex

@@ -0,0 +1,99 @@
+defmodule Exmoji.Util.Unified do
+  @moduledoc false
+
+  def _unified_to_char(uid) do
+    uid
+    |> String.split("-")
+    |> Enum.map( &(String.to_integer(&1, 16)) )
+    |> List.to_string
+  end
+
+end
+
+defmodule Exmoji.Util.Char do
+  @moduledoc false
+
+  def _char_to_unified(char) do
+    char
+    |> String.codepoints
+    |> Enum.map(&padded_hex_string/1)
+    |> Enum.join("-")
+    |> String.upcase
+  end
+
+  defp padded_hex_string(codepoint) do
+    << cp_int_value :: utf8 >> = codepoint
+    cp_int_value |> Integer.to_string(16) |> String.rjust(4,?0)
+  end
+
+end
+
+
+defmodule Exmoji.Util do
+  @moduledoc """
+  Provides utility functions to convert between Unicode unified ID values and
+  rendered Emoji glyphs in bitstring format.
+
+  Pattern matched with precompiled values for all known Emoji character values
+  for maximum speed, with fallbacks to algorithmic conversion.
+  """
+
+  alias Exmoji.EmojiChar
+  alias Exmoji.Util.Unified
+  alias Exmoji.Util.Char
+
+  @doc """
+  Convert a unified ID directly to its bitstring glyph representation.
+
+  Precompiled only for uppercase format of the hex ID.
+
+  ## Example
+
+      iex> Exmoji.Util.unified_to_char("1F47E")
+      "👾"
+
+  """
+  for ec <- Exmoji.all do
+    uid = ec.unified
+    def unified_to_char( unquote(uid) ) do
+      unquote( Unified._unified_to_char(uid) )
+    end
+  end
+
+  for ec <- Exmoji.all_with_variants do
+    variant_id = EmojiChar.variant(ec)
+    def unified_to_char( unquote(variant_id) ) do
+      unquote( Unified._unified_to_char(variant_id) )
+    end
+  end
+
+  def unified_to_char(uid), do: Unified._unified_to_char(uid)
+
+
+  @doc """
+  Convert a native bitstring glyph to its unified codepoint ID.
+
+  ## Example
+
+      iex> Exmoji.Util.char_to_unified("👾")
+      "1F47E"
+
+  """
+  # create pattern matches (variants must be first)
+  for ec <- Exmoji.all_with_variants do
+    variant = List.first(ec.variations)
+    def char_to_unified( unquote(Unified._unified_to_char(variant)) ) do
+      unquote(variant)
+    end
+  end
+
+  for ec <- Exmoji.all do
+    def char_to_unified( unquote(Unified._unified_to_char(ec.unified)) ) do
+      unquote(ec.unified)
+    end
+  end
+
+  # if not found, fallback
+  def char_to_unified(uid), do: Char._char_to_unified(uid)
+
+end

test/exmoji_test.exs

@@ -1,6 +1,7 @@
 defmodule ExmojiTest do
   use ExUnit.Case, async: true
   doctest Exmoji
+  doctest Exmoji.Util
 
   # Define a number of known Emoji library characteristics.
   # We should expect to get this many from our data file.
@@ -138,42 +139,42 @@ defmodule ExmojiTest do
   # #char_to_unified
   #
   test ".char_to_unified - converts normal emoji to unified codepoint" do
-    assert Exmoji.char_to_unified("👾") == "1F47E"
-    assert Exmoji.char_to_unified("🚀") == "1F680"
+    assert Exmoji.Util.char_to_unified("👾") == "1F47E"
+    assert Exmoji.Util.char_to_unified("🚀") == "1F680"
   end
 
   test ".char_to_unified - converts double-byte emoji to proper codepoint" do
-    assert Exmoji.char_to_unified("🇺🇸") == "1F1FA-1F1F8"
+    assert Exmoji.Util.char_to_unified("🇺🇸") == "1F1FA-1F1F8"
   end
 
   test ".char_to_unified - in doublebyte, adds padding to hex codes that are <4 chars" do
-    assert Exmoji.char_to_unified("#⃣") == "0023-20E3"
+    assert Exmoji.Util.char_to_unified("#⃣") == "0023-20E3"
   end
 
   test ".char_to_unified - converts variant encoded emoji to variant unified codepoint" do
-    assert Exmoji.char_to_unified("\x{2601}\x{FE0F}") == "2601-FE0F"
+    assert Exmoji.Util.char_to_unified("\x{2601}\x{FE0F}") == "2601-FE0F"
   end
 
 
   #
   # #unified_to_char
   #
   test ".unified_to_char - converts normal unified codepoints to unicode strings" do
-    assert Exmoji.unified_to_char("1F47E") == "👾"
-    assert Exmoji.unified_to_char("1F680") == "🚀"
+    assert Exmoji.Util.unified_to_char("1F47E") == "👾"
+    assert Exmoji.Util.unified_to_char("1F680") == "🚀"
   end
 
   test ".unified_to_char - converts doublebyte unified codepoints to unicode strings" do
-    assert Exmoji.unified_to_char("1F1FA-1F1F8") == "🇺🇸"
-    assert Exmoji.unified_to_char("0023-20E3") == "#⃣"
+    assert Exmoji.Util.unified_to_char("1F1FA-1F1F8") == "🇺🇸"
+    assert Exmoji.Util.unified_to_char("0023-20E3") == "#⃣"
   end
 
   test ".unified_to_char - converts variant unified codepoints to unicode strings" do
-    assert Exmoji.unified_to_char("2764-fe0f") == "\x{2764}\x{FE0F}"
+    assert Exmoji.Util.unified_to_char("2764-fe0f") == "\x{2764}\x{FE0F}"
   end
 
   test ".unified_to_char - converts variant+doublebyte chars (triplets!) to unicode strings" do
-    assert Exmoji.unified_to_char("0030-FE0F-20E3") == "\x{0030}\x{FE0F}\x{20E3}"
+    assert Exmoji.Util.unified_to_char("0030-FE0F-20E3") == "\x{0030}\x{FE0F}\x{20E3}"
   end
 
 end