Added three OpenQASM samples (#2394)

Added three OpenQASM samples.

* OpenQasmHelloWorld.qasm
* BellPair.qasm
* RandomNumber.qasm

For now, the samples are only added as files. No tests are added, and
they are not available as quick templates.

---------

Co-authored-by: Dmitry Vasilevsky <dmitryv@microsoft.com>

Author: DmitryVasilevsky

samples/OpenQASM/BellPair.qasm

@@ -0,0 +1,31 @@
+// OpenQASM Bell Pair sample
+//
+// Bell pairs are specific quantum states of two qubits that represent
+// the simplest (and maximal) examples of quantum entanglement. This sample
+// prepares |Φ⁺⟩ = (|00⟩+|11⟩)/√2.
+//
+// See [Bell state](https://en.wikipedia.org/wiki/Bell_state)
+
+OPENQASM 3;
+include "stdgates.inc";
+
+// Declares use of qubits `q1` and `q2`.
+qubit q1;
+qubit q2;
+
+// Qubits are initially in an undefined state.
+// Reset is used here to initialize qubits to |0⟩ state.
+reset q1;
+reset q2;
+
+// Set qubit `q1` in superposition of |0⟩ and |1⟩ by applying a Hadamard gate.
+h q1;
+// Entangle the two qubits `q1` and `q2` using the `cx` gate.
+cx q1, q2;
+
+// Measure the two qubits and store results in classical variables `r1` and `r2`.
+bit r1 = measure q1;
+bit r2 = measure q2;
+
+// Note, that the reported result (r1, r2)
+// will always be either (Zero, Zero) or (One, One).

samples/OpenQASM/OpenQasmHelloWorld.qasm

@@ -0,0 +1,25 @@
+// OpenQASM Hello World sample
+//
+// This is one of the simplest OpenQASM programs that contains quantum part.
+// It uses one qubit, resets it and and immediately measures it.
+// Since the qubit is in |0〉 state after reset
+// such measurement will always yield `Zero`.
+
+// OpenQASM version identifier.
+OPENQASM 3;
+
+// Declares use of a single qubit and names it `q`.
+// All qubits must be declared in a global scope.
+qubit q;
+
+// Qubits are initially in an undefined state.
+// Reset is used here to initialize qubit to a |0〉 state.
+reset q;
+
+// Measures qubit and stores the result in a classical bit.
+// The qubit is in |0〉 state after reset, so the `b` will be 0.
+bit b = measure q;
+
+// Note, that the content of all classical variables
+// are reported to the user at the end of the program
+// unless explicit output declarations exist.

samples/OpenQASM/RandomNumber.qasm

@@ -0,0 +1,44 @@
+// OpenQASM Quantum Random Number Generator
+//
+// This program implements a quantum random number generator by setting qubits
+// in superposition and then using the measurement results as random bits.
+
+OPENQASM 3;
+include "stdgates.inc";
+
+// Generates one random bit using a qubit `q`.
+def GenerateRandomBit(qubit q) -> bit {
+  // Resets qubit `q` to |0〉 state
+  reset q;
+  // Sets the qubit into superposition of 0 and 1 using the Hadamard gate.
+  h q;
+
+  // At this point qubit `q` has 50% chance of being measured in the |0〉 state
+  // and 50% chance of being measured in the |1〉 state.
+  bit b = measure q;
+
+  // Return the measurement result - a random bit.
+  return b;
+}
+
+// Generates a random integer with `nBit` bits using qubit `q`
+def GenerateRandomNumber(qubit q, int nBits) -> int {
+  int number = 0;
+
+  // Loop `nBits` times to generate `nBits` random bits.
+  for int k in [1:nBits] {
+      // Shift the number left by 1 to make space for the next bit.
+      number <<= 1;
+      // Set the least significant bit of the number to a random bit.
+      number |= GenerateRandomBit(q);
+  }
+
+  // Return the random number.
+  return number;
+}
+
+// User one qubit `q`.
+qubit q;
+
+// Generate a 5-bit random number using the qubit `q`.
+int random = GenerateRandomNumber(q, 5);