Backport compatible changes from v4.0.0 to v3.7.0

cmake/CMakeLists.txt

@@ -11,3 +11,10 @@ install(FILES
     ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-config.cmake
     ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake
   DESTINATION ${GRAPHQL_INSTALL_CMAKE_DIR}/${PROJECT_NAME})
+
+install(FILES
+    ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-functions.cmake
+    ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-update-schema-files.cmake
+    ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-update-client-files.cmake
+  CONFIGURATIONS ${GRAPHQL_INSTALL_CONFIGURATIONS}
+  DESTINATION ${GRAPHQL_INSTALL_CMAKE_DIR}/${PROJECT_NAME})

cmake/ClientGen.rc.in → cmake/Generator.rc.in

@@ -3,8 +3,8 @@
 
 #include <winver.h>
 
-#define CLIENTGEN_RC_VERSION     @CLIENTGEN_RC_VERSION@
-#define CLIENTGEN_RC_VERSION_STR "@CLIENTGEN_RC_VERSION_STR@"
+#define GRAPHQL_RC_VERSION     @GRAPHQL_RC_VERSION@
+#define GRAPHQL_RC_VERSION_STR "@GRAPHQL_RC_VERSION_STR@"
 
 #ifndef DEBUG
 #define VER_DEBUG   0
@@ -13,8 +13,8 @@
 #endif
 
 VS_VERSION_INFO	VERSIONINFO
-FILEVERSION     CLIENTGEN_RC_VERSION
-PRODUCTVERSION  CLIENTGEN_RC_VERSION
+FILEVERSION     GRAPHQL_RC_VERSION
+PRODUCTVERSION  GRAPHQL_RC_VERSION
 FILEFLAGSMASK   VS_FFI_FILEFLAGSMASK
 FILEFLAGS       VER_DEBUG
 FILEOS          VOS__WINDOWS32
@@ -27,12 +27,12 @@ BEGIN
         BEGIN
             VALUE "CompanyName",        "Microsoft Corporation"
             VALUE "FileDescription",    "Code generator for https://github.com/microsoft/cppgraphqlgen"
-            VALUE "FileVersion",        CLIENTGEN_RC_VERSION_STR
-            VALUE "InternalName",       "clientgen"
+            VALUE "FileVersion",        GRAPHQL_RC_VERSION_STR
+            VALUE "InternalName",       "@GRAPHQL_RC_FILENAME@"
             VALUE "LegalCopyright",     "Copyright (c) Microsoft Corporation. All rights reserved. Licensed under the MIT License."
-            VALUE "OriginalFilename",   "clientgen.exe"
+            VALUE "OriginalFilename",   "@GRAPHQL_RC_FILENAME@.exe"
             VALUE "ProductName",        "CppGraphQLGen"
-            VALUE "ProductVersion",     CLIENTGEN_RC_VERSION_STR
+            VALUE "ProductVersion",     GRAPHQL_RC_VERSION_STR
         END
     END
 

cmake/cppgraphqlgen-config.cmake

@@ -5,7 +5,7 @@
 cppgraphqlgen
 -------------
 
-The following import targets are created
+The following import targets are created:
 
 ::
 
@@ -15,8 +15,20 @@ The following import targets are created
   cppgraphqlgen::graphqlintrospection
   cppgraphqlgen::graphqljson
   cppgraphqlgen::schemagen
+  cppgraphqlgen::clientgen
+
+The following functions are defined to help with code generation and build targets:
+
+::
+
+  update_graphql_schema_files
+  add_graphql_schema_target
+  add_graphql_schema_no_introspection_target
+  update_graphql_client_files
+  add_graphql_client_target
 #]=======================================================================]
 
 include(CMakeFindDependencyMacro)
 find_package(Threads REQUIRED)
 include("${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-targets.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-functions.cmake")

cmake/cppgraphqlgen-functions.cmake

@@ -0,0 +1,101 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+get_filename_component(GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT
+  "${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-update-schema-files.cmake"
+  ABSOLUTE)
+
+get_filename_component(GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT
+  "${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-update-client-files.cmake"
+  ABSOLUTE)
+
+function(update_graphql_schema_files SCHEMA_TARGET SCHEMA_GRAPHQL SCHEMA_PREFIX SCHEMA_NAMESPACE)
+  set_property(DIRECTORY APPEND
+    PROPERTY CMAKE_CONFIGURE_DEPENDS ${SCHEMA_TARGET}_schema_files)
+
+  # Collect optional arguments
+  set(ADDITIONAL_SCHEMAGEN_ARGS "")
+  if(ARGC GREATER 4)
+    math(EXPR LAST_ARG "${ARGC} - 1")
+    foreach(ARGN RANGE 4 ${LAST_ARG})
+      set(NEXT_ARG "${ARGV${ARGN}}")
+      list(APPEND ADDITIONAL_SCHEMAGEN_ARGS "${NEXT_ARG}")
+    endforeach()
+  endif()
+
+  add_custom_command(
+    OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_TARGET}_schema_files
+    COMMAND
+      ${CMAKE_COMMAND} "-DSCHEMA_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
+      "-DSCHEMA_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
+      "-DSCHEMAGEN_PROGRAM=$<TARGET_FILE:cppgraphqlgen::schemagen>"
+      "-DSCHEMA_TARGET=${SCHEMA_TARGET}" "-DSCHEMA_GRAPHQL=${SCHEMA_GRAPHQL}"
+      "-DSCHEMA_PREFIX=${SCHEMA_PREFIX}" "-DSCHEMA_NAMESPACE=${SCHEMA_NAMESPACE}"
+      "-DADDITIONAL_SCHEMAGEN_ARGS=${ADDITIONAL_SCHEMAGEN_ARGS}"
+      -P ${GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT}
+    DEPENDS ${SCHEMA_GRAPHQL} ${GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT} cppgraphqlgen::schemagen
+    COMMENT "Generating ${SCHEMA_TARGET} GraphQL schema"
+    VERBATIM)
+endfunction()
+
+function(add_graphql_schema_target SCHEMA_TARGET)
+  add_custom_target(${SCHEMA_TARGET}_update_schema ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_TARGET}_schema_files)
+
+  file(STRINGS ${SCHEMA_TARGET}_schema_files SCHEMA_FILES)
+  add_library(${SCHEMA_TARGET}_schema STATIC ${SCHEMA_FILES})
+  add_dependencies(${SCHEMA_TARGET}_schema ${SCHEMA_TARGET}_update_schema)
+  target_include_directories(${SCHEMA_TARGET}_schema PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+  target_link_libraries(${SCHEMA_TARGET}_schema PUBLIC cppgraphqlgen::graphqlintrospection)
+endfunction()
+
+function(add_graphql_schema_no_introspection_target SCHEMA_NO_INTROSPECTION_TARGET)
+  add_custom_target(${SCHEMA_NO_INTROSPECTION_TARGET}_update_schema ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_NO_INTROSPECTION_TARGET}_schema_files)
+
+  file(STRINGS ${SCHEMA_NO_INTROSPECTION_TARGET}_schema_files SCHEMA_FILES)
+  add_library(${SCHEMA_NO_INTROSPECTION_TARGET}_schema STATIC ${SCHEMA_FILES})
+  add_dependencies(${SCHEMA_NO_INTROSPECTION_TARGET}_schema ${SCHEMA_NO_INTROSPECTION_TARGET}_update_schema)
+  target_include_directories(${SCHEMA_NO_INTROSPECTION_TARGET}_schema PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+  target_link_libraries(${SCHEMA_NO_INTROSPECTION_TARGET}_schema PUBLIC cppgraphqlgen::graphqlservice)
+endfunction()
+
+function(update_graphql_client_files CLIENT_TARGET SCHEMA_GRAPHQL REQUEST_GRAPHQL CLIENT_PREFIX CLIENT_NAMESPACE)
+  set_property(DIRECTORY APPEND
+    PROPERTY CMAKE_CONFIGURE_DEPENDS ${CLIENT_TARGET}_client_files)
+
+  # Collect optional arguments
+  set(ADDITIONAL_CLIENTGEN_ARGS "")
+  if(ARGC GREATER 5)
+    math(EXPR LAST_ARG "${ARGC} - 1")
+    foreach(ARGN RANGE 5 ${LAST_ARG})
+      set(NEXT_ARG "${ARGV${ARGN}}")
+      list(APPEND ADDITIONAL_CLIENTGEN_ARGS "${NEXT_ARG}")
+    endforeach()
+  endif()
+
+  add_custom_command(
+    OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files
+    COMMAND
+      ${CMAKE_COMMAND} "-DCLIENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
+      "-DCLIENT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
+      "-DCLIENTGEN_PROGRAM=$<TARGET_FILE:cppgraphqlgen::clientgen>" "-DCLIENT_TARGET=${CLIENT_TARGET}"
+      "-DSCHEMA_GRAPHQL=${SCHEMA_GRAPHQL}" "-DREQUEST_GRAPHQL=${REQUEST_GRAPHQL}"
+      "-DCLIENT_PREFIX=${CLIENT_PREFIX}" "-DCLIENT_NAMESPACE=${CLIENT_NAMESPACE}"
+      "-DADDITIONAL_CLIENTGEN_ARGS=${ADDITIONAL_CLIENTGEN_ARGS}"
+      -P ${GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT}
+    DEPENDS ${SCHEMA_GRAPHQL} ${REQUEST_GRAPHQL} ${GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT} cppgraphqlgen::clientgen
+    COMMENT "Generating ${CLIENT_TARGET} client"
+    VERBATIM)
+endfunction()
+
+function(add_graphql_client_target CLIENT_TARGET)
+  add_custom_target(${CLIENT_TARGET}_update_client ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files)
+
+  file(STRINGS ${CLIENT_TARGET}_client_files CLIENT_FILES)
+  add_library(${CLIENT_TARGET}_client STATIC ${CLIENT_FILES})
+  add_dependencies(${CLIENT_TARGET}_client ${CLIENT_TARGET}_update_client)
+  target_include_directories(${CLIENT_TARGET}_client PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+  target_link_libraries(${CLIENT_TARGET}_client PUBLIC cppgraphqlgen::graphqlclient)
+endfunction()

cmake/cppgraphqlgen-update-client-files.cmake

@@ -0,0 +1,58 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+# Normalize the filesystem paths
+get_filename_component(CLIENT_SOURCE_DIR ${CLIENT_SOURCE_DIR} ABSOLUTE)
+get_filename_component(CLIENT_BINARY_DIR ${CLIENT_BINARY_DIR} ABSOLUTE)
+get_filename_component(CLIENTGEN_PROGRAM ${CLIENTGEN_PROGRAM} ABSOLUTE)
+get_filename_component(SCHEMA_GRAPHQL "${CLIENT_SOURCE_DIR}/${SCHEMA_GRAPHQL}" ABSOLUTE)
+get_filename_component(REQUEST_GRAPHQL "${CLIENT_SOURCE_DIR}/${REQUEST_GRAPHQL}" ABSOLUTE)
+
+file(MAKE_DIRECTORY ${CLIENT_BINARY_DIR})
+
+# Cleanup all of the stale files in the binary directory
+file(GLOB PREVIOUS_FILES ${CLIENT_BINARY_DIR}/*.h ${CLIENT_BINARY_DIR}/*.cpp
+     ${CLIENT_BINARY_DIR}/${CLIENT_TARGET}_client_files)
+foreach(PREVIOUS_FILE ${PREVIOUS_FILES})
+  file(REMOVE ${PREVIOUS_FILE})
+endforeach()
+
+set(CLIENTGEN_ARGS "--schema=${SCHEMA_GRAPHQL}" "--request=${REQUEST_GRAPHQL}" "--prefix=${CLIENT_PREFIX}" "--namespace=${CLIENT_NAMESPACE}")
+foreach(CLIENTGEN_ARG ${ADDITIONAL_CLIENTGEN_ARGS})
+  list(APPEND CLIENTGEN_ARGS ${CLIENTGEN_ARG})
+endforeach()
+
+# Regenerate the sources in the binary directory
+execute_process(
+  COMMAND ${CLIENTGEN_PROGRAM} ${CLIENTGEN_ARGS}
+  OUTPUT_FILE ${CLIENT_TARGET}_client_files
+  WORKING_DIRECTORY ${CLIENT_BINARY_DIR})
+
+# Get the up-to-date list of files in the binary directory
+set(FILE_NAMES "")
+file(GLOB NEW_FILES ${CLIENT_BINARY_DIR}/*.h ${CLIENT_BINARY_DIR}/*.cpp)
+foreach(NEW_FILE ${NEW_FILES})
+  get_filename_component(NEW_FILE ${NEW_FILE} NAME)
+  list(APPEND FILE_NAMES "${NEW_FILE}")
+endforeach()
+
+# Don't update the files in the source directory if no files were generated in the binary directory.
+if(NOT FILE_NAMES)
+  message(FATAL_ERROR "Schema generation failed!")
+endif()
+
+# Remove stale files in the source directory
+cmake_policy(SET CMP0057 NEW)
+file(GLOB OLD_FILES ${CLIENT_SOURCE_DIR}/*.h ${CLIENT_SOURCE_DIR}/*.cpp)
+foreach(OLD_FILE ${OLD_FILES})
+  get_filename_component(OLD_FILE ${OLD_FILE} NAME)
+  if(NOT OLD_FILE IN_LIST FILE_NAMES)
+    file(REMOVE "${CLIENT_SOURCE_DIR}/${OLD_FILE}")
+  endif()
+endforeach()
+
+# Copy new and modified files from the binary directory to the source directory
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
+    ${CLIENT_BINARY_DIR}/${CLIENT_TARGET}_client_files
+    ${NEW_FILES}
+  ${CLIENT_SOURCE_DIR})

cmake/cppgraphqlgen-update-schema-files.cmake

@@ -0,0 +1,57 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+# Normalize the filesystem paths
+get_filename_component(SCHEMA_SOURCE_DIR ${SCHEMA_SOURCE_DIR} ABSOLUTE)
+get_filename_component(SCHEMA_BINARY_DIR ${SCHEMA_BINARY_DIR} ABSOLUTE)
+get_filename_component(SCHEMAGEN_PROGRAM ${SCHEMAGEN_PROGRAM} ABSOLUTE)
+get_filename_component(SCHEMA_GRAPHQL "${SCHEMA_SOURCE_DIR}/${SCHEMA_GRAPHQL}" ABSOLUTE)
+
+file(MAKE_DIRECTORY ${SCHEMA_BINARY_DIR})
+
+# Cleanup all of the stale files in the binary directory
+file(GLOB PREVIOUS_FILES ${SCHEMA_BINARY_DIR}/*.h ${SCHEMA_BINARY_DIR}/*.cpp
+     ${SCHEMA_BINARY_DIR}/${SCHEMA_TARGET}_schema_files)
+foreach(PREVIOUS_FILE ${PREVIOUS_FILES})
+  file(REMOVE ${PREVIOUS_FILE})
+endforeach()
+
+set(SCHEMAGEN_ARGS "--schema=${SCHEMA_GRAPHQL}" "--prefix=${SCHEMA_PREFIX}" "--namespace=${SCHEMA_NAMESPACE}")
+foreach(SCHEMAGEN_ARG ${ADDITIONAL_SCHEMAGEN_ARGS})
+  list(APPEND SCHEMAGEN_ARGS ${SCHEMAGEN_ARG})
+endforeach()
+
+# Regenerate the sources in the binary directory
+execute_process(
+  COMMAND ${SCHEMAGEN_PROGRAM} ${SCHEMAGEN_ARGS}
+  OUTPUT_FILE ${SCHEMA_TARGET}_schema_files
+  WORKING_DIRECTORY ${SCHEMA_BINARY_DIR})
+
+# Get the up-to-date list of files in the binary directory
+set(FILE_NAMES "")
+file(GLOB NEW_FILES ${SCHEMA_BINARY_DIR}/*.h ${SCHEMA_BINARY_DIR}/*.cpp)
+foreach(NEW_FILE ${NEW_FILES})
+  get_filename_component(NEW_FILE ${NEW_FILE} NAME)
+  list(APPEND FILE_NAMES "${NEW_FILE}")
+endforeach()
+
+# Don't update the files in the source directory if no files were generated in the binary directory.
+if(NOT FILE_NAMES)
+  message(FATAL_ERROR "Schema generation failed!")
+endif()
+
+# Remove stale files in the source directory
+cmake_policy(SET CMP0057 NEW)
+file(GLOB OLD_FILES ${SCHEMA_SOURCE_DIR}/*.h ${SCHEMA_SOURCE_DIR}/*.cpp)
+foreach(OLD_FILE ${OLD_FILES})
+  get_filename_component(OLD_FILE ${OLD_FILE} NAME)
+  if(NOT OLD_FILE IN_LIST FILE_NAMES)
+    file(REMOVE "${SCHEMA_SOURCE_DIR}/${OLD_FILE}")
+  endif()
+endforeach()
+
+# Copy new and modified files from the binary directory to the source directory
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
+    ${SCHEMA_BINARY_DIR}/${SCHEMA_TARGET}_schema_files
+    ${NEW_FILES}
+  ${SCHEMA_SOURCE_DIR})

cmake/version.txt

@@ -1 +1 @@
-3.6.0
+3.7.0