build.gradle

plugins {
    id "io.micronaut.build.internal.convention-library"
    id "org.jetbrains.kotlin.jvm"
}

dependencies {
    annotationProcessor project(":inject-java")

    api project(":inject-java")
    api libs.managed.groovy
    api(libs.spock) {
        exclude module:'groovy-all'
    }
    if (!JavaVersion.current().isJava9Compatible()) {
        api files(org.gradle.internal.jvm.Jvm.current().toolsJar)
    }

    testAnnotationProcessor project(":inject-java")
    testCompileOnly project(":inject-groovy")
    testImplementation libs.managed.validation
    testImplementation libs.javax.persistence
    testImplementation project(":runtime")
    api libs.blaze.persistence.core

    implementation libs.kotlin.compiler.embeddable
    implementation libs.kotlin.annotation.processing.embeddable
    implementation libs.kotlin.stdlib
}

tasks.named("sourcesJar") {
    from "$projectDir/src/main/groovy"
    from "$projectDir/src/main/kotlin"
}

tasks.named("compileKotlin") {
    kotlinOptions {
        jvmTarget = "17"
    }
}

tasks.named("compileGroovy") {
    // this allows groovy to access kotlin classes.
    dependsOn tasks.getByPath('compileKotlin')
    classpath += files(compileKotlin.destinationDirectory)
}

tasks.named("test", Test) {
    if(JavaVersion.current().majorVersion.toInteger() >= 17) {
        jvmArgs(
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.util=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.tree=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.main=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.jvm=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.parser=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.processing=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.code=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.comp=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.api=ALL-UNNAMED',
                '--add-opens', 'jdk.compiler/com.sun.tools.javac.file=ALL-UNNAMED'
        )
    }
}