build.gradle.kts

import com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask

plugins {
    id("java")
    id("jacoco-report-aggregation")
    id("org.sonarqube")
    id("com.github.ben-manes.versions") version "0.51.0"
}

description = "pg-index-health build"

allprojects {
    group = "io.github.mfvanek"
    version = "0.14.4"

    repositories {
        mavenLocal()
        mavenCentral()
    }
}

dependencies {
    val excludedSubprojects = setOf("pg-index-health-bom", "spring-boot-integration")
    subprojects.forEach {
        val shouldSkip = excludedSubprojects.contains(it.name) || it.name.endsWith("-demo-app")
        if (!shouldSkip) {
            jacocoAggregation(it)
        }
    }
}

tasks{
    wrapper {
        gradleVersion = "8.11.1"
    }

    check {
        dependsOn(named<JacocoReport>("testCodeCoverageReport"))
    }

    // To avoid creation of jar's in build folder in the root
    jar {
        isEnabled = false
    }
}

sonar {
    properties {
        property("sonar.projectKey", "mfvanek_pg-index-health")
        property("sonar.organization", "mfvanek")
        property("sonar.host.url", "https://sonarcloud.io")
        property("sonar.exclusions", "**/build.gradle.kts")
    }
}

fun isNonStable(version: String): Boolean {
    val stableKeyword = listOf("RELEASE", "FINAL", "GA").any { version.uppercase().contains(it) }
    val regex = "^[0-9,.v-]+(-r)?$".toRegex()
    val isStable = stableKeyword || regex.matches(version)
    return isStable.not()
}

tasks.named<DependencyUpdatesTask>("dependencyUpdates").configure {
    checkForGradleUpdate = true
    gradleReleaseChannel = "current"
    checkConstraints = true
    rejectVersionIf {
        isNonStable(candidate.version)
    }
}