feat(nix): replace shell.nix with flake.nix

Author: tilpner

flake.lock

@@ -0,0 +1,64 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    utils.url = "github:numtide/flake-utils";
+    oxalica-rust = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = inputs@{ self, nixpkgs, utils, oxalica-rust }:
+    utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system}.extend oxalica-rust.overlays.default;
+        rustStable = pkgs.rust-bin.stable.latest;
+        rustNightly = pkgs.rust-bin.nightly.latest;
+        rust = rustStable.minimal;
+
+        unpack = drv: pkgs.runCommand "${drv.name}-unpacked" {} ''
+          mkdir extracted
+          cd extracted
+          unpackFile ${drv}
+          cp -a ./* $out
+        '';
+
+        gdb = pkgs.gdb.overrideAttrs (old: {
+          patches = pkgs.fetchpatch {
+            url = "https://sourceware.org/git/?p=binutils-gdb.git;a=patch;h=562403d4f5483e0787219fdb88da72c707c8d7f6";
+            hash = "sha256-l4zWMJ0LFAWSRQmb+ixD84yxrXe2OaX8CPxsAlu93jw=";
+          };
+        });
+      in {
+        devShell = with pkgs; mkShell {
+          buildInputs = [
+            clang pkg-config
+            (enableDebugging ffmpeg_6).out
+            (enableDebugging ffmpeg_6).dev
+
+            (rust.override {
+              extensions = [
+                "rust-src"
+                "clippy"
+              ];
+            })
+
+            # necessary for unstable format options
+            rustNightly.rustfmt
+
+            (writeShellScriptBin "gdb" ''
+              RUSTC_COMMIT="$(rustc -vV | awk '/commit-hash: (.+)/ { print $2 }')"
+              echo $RUSTC_COMMIT
+
+              exec ${gdb}/bin/gdb \
+                -ex "set substitute-path '/rustc/$RUSTC_COMMIT' '${rustStable.rust-src}/lib/rustlib/src/rust'" \
+                -d ${unpack ffmpeg_6.src} \
+                "$@"
+            '')
+          ];
+
+          RUST_BACKTRACE = 1;
+          LIBCLANG_PATH = "${llvmPackages.libclang.lib}/lib";
+        };
+      });
+}