framework64/cmake/framework64.desktop.cmake at main · matthewcpp/framework64 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
set(FW64_PLATFORM_DESKTOP ON)
set(CMAKE_CXX_STANDARD 17)

set(FW64_PLATFORM_NAME "desktop")

function (enable_all_warnings_as_errors)
    set(options)
    set(oneValueArgs TARGET)
    set(multiValueArgs)
    cmake_parse_arguments(ENABLE_ALL_WARNINGS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )

    set(target_name ${ENABLE_ALL_WARNINGS_TARGET})

    set_property(TARGET ${target_name} PROPERTY COMPILE_WARNING_AS_ERROR ON)

    if (MSVC)
        # warning level 4
        target_compile_options(${target_name} PRIVATE /W4)
        target_compile_definitions(${target_name} PRIVATE _CRT_SECURE_NO_WARNINGS)
    else()
        # additional warnings
        target_compile_options(${target_name} PRIVATE -Wall -Wextra -Wpedantic -Wno-strict-prototypes)
    endif()
endfunction()

# performs platform specific configuration of the framework 64 library
function (configure_core_library)
    if(NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
        message(FATAL_ERROR "Desktop build requires x64 architecture")
    endif()

    find_package(CLI11 CONFIG REQUIRED)
    find_package(CURL CONFIG REQUIRED)
    find_package(GLEW REQUIRED)

    find_package(nlohmann_json CONFIG REQUIRED)
    find_package(SDL2 CONFIG REQUIRED)
    find_package(SDL2_mixer CONFIG REQUIRED)
    find_package(SDL2_image CONFIG REQUIRED)

    target_link_libraries(framework64 PUBLIC CLI11::CLI11)
    target_link_libraries(framework64 PUBLIC GLEW::GLEW)
    target_link_libraries(framework64 PUBLIC CURL::libcurl)
    target_link_libraries(framework64 PUBLIC SDL2::SDL2 SDL2::SDL2main)
    target_link_libraries(framework64 PUBLIC $<IF:$<TARGET_EXISTS:SDL2_image::SDL2_image>,SDL2_image::SDL2_image,SDL2_image::SDL2_image-static>)
    target_link_libraries(framework64 PUBLIC $<IF:$<TARGET_EXISTS:SDL2_mixer::SDL2_mixer>,SDL2_mixer::SDL2_mixer,SDL2_mixer::SDL2_mixer-static>)

    set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
    set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG ${CMAKE_BINARY_DIR}/bin)
    set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${CMAKE_BINARY_DIR}/bin)

    target_compile_definitions(framework64 PUBLIC FW64_PLATFORM_DESKTOP)
    target_compile_definitions(framework64 PUBLIC FW64_PLATFORM_IS_64_BIT)
    target_compile_definitions(framework64 PUBLIC "$<$<CONFIG:Debug>:FW64_COLLISION_GEOMETRY_DEBUG_INFO>")
    target_compile_definitions(framework64 PUBLIC "$<$<CONFIG:Debug>:FW64_RENDERER_DEBUG_INFO>")

    enable_all_warnings_as_errors(TARGET framework64)
endfunction()

# performs platform specific configuration of a framework64 game
function(create_game)
    set(options ALL_WARNINGS_AS_ERRORS)
    set(oneValueArgs TARGET SAVE_FILE_TYPE GAME_HEADER_PATH HTML_TEMPLATE_PATH)
    set(multiValueArgs SOURCES EXTRA_LIBS STATIC_MODULES)
    cmake_parse_arguments(DESKTOP_GAME "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )

    set(target_name ${DESKTOP_GAME_TARGET})
    set(game_sources ${DESKTOP_GAME_SOURCES})

    if (DEFINED DESKTOP_GAME_GAME_HEADER_PATH)
        set(game_include_path ${DESKTOP_GAME_GAME_HEADER_PATH})
    else()
        set(game_include_path "game.h")
    endif()

    set(main_file_src ${FW64_ROOT_DIR}/src/framework64/desktop/main_desktop.cpp)
    set(main_file_dest ${CMAKE_CURRENT_BINARY_DIR}/main_desktop_${target_name}.cpp)
    configure_file(${main_file_src} ${main_file_dest})

    add_executable(${target_name} ${game_sources} ${main_file_dest})
    target_link_libraries(${target_name} PUBLIC framework64)

    add_game_modules(TARGET ${target_name} MODULES ${DESKTOP_GAME_STATIC_MODULES})

    if (${DESKTOP_GAME_ALL_WARNINGS_AS_ERRORS})
        enable_all_warnings_as_errors(TARGET ${target_name})
    endif()

    # Configure target specific output directories
    set(output_dir ${CMAKE_BINARY_DIR}/bin/${target_name})
    set_target_properties(${target_name} PROPERTIES
        RUNTIME_OUTPUT_DIRECTORY ${output_dir}
        RUNTIME_OUTPUT_DIRECTORY_DEBUG ${output_dir}
        RUNTIME_OUTPUT_DIRECTORY_RELEASE ${output_dir})

    # include the game specific asset directory
    set(asset_include_dir ${output_dir}/assets/include)
    target_include_directories(${target_name} PUBLIC ${asset_include_dir})

    # Add any extra libraries that need to be linked in
    if (DEFINED DESKTOP_GAME_EXTRA_LIBS)
        target_link_libraries(${target_name} PUBLIC ${DESKTOP_GAME_EXTRA_LIBS})
    endif()

    # Fixes linker error encountered on linux
    # https://stackoverflow.com/a/55086637
    if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
        target_link_options(${target_name} PUBLIC "-Wl,--copy-dt-needed-entries")
    endif()

    target_include_directories(${target_name} PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})

    if (NOT DEFINED DESKTOP_GAME_SAVE_FILE_TYPE)
        set(DESKTOP_GAME_SAVE_FILE_TYPE "NONE")
    endif()

    target_compile_definitions(${target_name}
        PUBLIC FW64_APPLICATION_NAME="${target_name}"
        PUBLIC FW64_SAVE_FILE_TYPE="${DESKTOP_GAME_SAVE_FILE_TYPE}"
    )

endfunction()