Add preset configurations for cross-compilation targets supported by the ldc developers, such as C, D, and linker flags, starting with Android-arm.

Author: joakim-noah

CMakeLists.txt

@@ -1,7 +1,7 @@
 cmake_minimum_required(VERSION 2.8)
 project(ldc)
 
-set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules")
+set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules" "${CMAKE_SOURCE_DIR}/runtime")
 
 include(FindDCompiler)
 include(CheckIncludeFile)

runtime/CMakeLists.txt

@@ -2,6 +2,8 @@ project(runtime)
 
 cmake_minimum_required(VERSION 2.8.9)
 
+set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_SOURCE_DIR})
+
 # Verify required variables if this CMake project is NOT embedded in the LDC CMake project.
 if(NOT LDC_EXE)
     if(NOT LDC_EXE_FULL)
@@ -40,12 +42,14 @@ set(COMPILE_ALL_D_FILES_AT_ONCE ON                            CACHE BOOL   "Comp
 set(RT_CFLAGS             ""                                  CACHE STRING "Runtime extra C compiler flags, separated by ' '")
 set(LD_FLAGS              ""                                  CACHE STRING "Runtime extra C linker flags, separated by ' '")
 set(C_SYSTEM_LIBS         AUTO                                CACHE STRING "C system libraries for linking shared libraries and test runners, separated by ';'")
-set(TARGET_SYSTEM         AUTO                                CACHE STRING "Targeted platform for cross-compilation (e.g., 'Linux;UNIX', 'Darwin;APPLE;UNIX', 'Windows;MSVC')")
+set(TARGET_SYSTEM         AUTO                                CACHE STRING "Target OS/toolchain for cross-compilation (e.g., 'Linux;UNIX', 'Darwin;APPLE;UNIX', 'Windows;MSVC')")
+set(PRESET_TARGET         AUTO                                CACHE STRING "Use preset target configuration for cross-compilation, by passing format OS-arch (e.g., 'Linux-arm', 'Mac-x64', 'Windows-aarch64', 'Android-x86')")
 
 set(CMAKE_INSTALL_LIBDIR ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
 
 # Auto-detect TARGET_SYSTEM
-if("${TARGET_SYSTEM}" STREQUAL "AUTO")
+
+if("${PRESET_TARGET}" STREQUAL "AUTO" AND "${TARGET_SYSTEM}" STREQUAL "AUTO")
     set(TARGET_SYSTEM ${CMAKE_SYSTEM_NAME})
     # Additionally add MSVC, APPLE and/or UNIX
     if(MSVC)
@@ -59,6 +63,8 @@ if("${TARGET_SYSTEM}" STREQUAL "AUTO")
     endif()
 endif()
 
+include(PresetRuntimeConfiguration)
+
 if("${TARGET_SYSTEM}" MATCHES "UNIX")
     ENABLE_LANGUAGE(ASM)
 elseif("${TARGET_SYSTEM}" MATCHES "MSVC")

runtime/PresetRuntimeConfiguration.cmake

@@ -0,0 +1,65 @@
+# - Preset cross-compilation configurations for C/ASM and D compilation
+# and linking, for supported targets
+#
+# This module sets compiler flags for a few C and assembly files in
+# DRuntime and Phobos, and linker flags to link the standard library as
+# a shared library and build the test runners, for various
+# cross-compilation targets that the LDC developers have tried out.
+#
+# It is enabled by setting PRESET_TARGET to a supported platform, after
+# which the appropriate TARGET_SYSTEM is set and a target triple is
+# appended to D_FLAGS.
+#
+# You can pass in custom RT_CFLAGS and LD_FLAGS of your choosing, but
+# if they're left unconfigured, they will also be set to sensible
+# defaults.
+
+macro(check_for_android_ndk)
+    if(NOT DEFINED ENV{NDK})
+        message(FATAL_ERROR "No NDK found! Set the 'NDK' environment variable to the path of your NDK, for example, export NDK=/home/martin/android-ndk-r15c")
+    elseif(NOT EXISTS $ENV{NDK})
+        message(FATAL_ERROR "Could not find path set in environment variable NDK: $ENV{NDK}.")
+    endif()
+endmacro()
+
+if(NOT "${PRESET_TARGET}" STREQUAL "AUTO")
+    # This initial RT_CFLAGS/LD_FLAGS configuration for Android is a
+    # convenience for natively compiling, because CMake cannot detect
+    # Android as a separate platform from Linux.
+    set(ANDROID_API "21")
+    if(RT_CFLAGS STREQUAL "" AND "${PRESET_TARGET}" MATCHES "Android")
+        set(RT_CFLAGS_UNCONFIGURED True)
+        if("${PRESET_TARGET}" MATCHES "arm")
+            set(RT_CFLAGS "-ffunction-sections -funwind-tables -fstack-protector-strong -Wno-invalid-command-line-argument -Wno-unused-command-line-argument -no-canonical-prefixes -fno-integrated-as -g -target armv7-none-linux-androideabi${ANDROID_API} -march=armv7-a -mfloat-abi=softfp -mfpu=vfpv3-d16 -mthumb -Os -DNDEBUG -DANDROID  -D__ANDROID_API__=${ANDROID_API} -Wa,--noexecstack -Wformat -Werror=format-security -fpie")
+        endif()
+    endif()
+
+    if(LD_FLAGS STREQUAL "" AND "${PRESET_TARGET}" MATCHES "Android")
+        set(LD_FLAGS_UNCONFIGURED True)
+        if("${PRESET_TARGET}" MATCHES "arm")
+            set(LD_FLAGS "-Wl,--gc-sections -Wl,-z,nocopyreloc -lgcc -Wl,--exclude-libs,libgcc.a -no-canonical-prefixes -target armv7-none-linux-androideabi${ANDROID_API} -Wl,--fix-cortex-a8 -Wl,--no-undefined -Wl,-z,noexecstack -Wl,-z,relro -Wl,-z,now -Wl,--warn-shared-textrel -Wl,--fatal-warnings -fpie -pie")
+        endif()
+    endif()
+
+    if("${PRESET_TARGET}" MATCHES "Windows")
+        set(TARGET_SYSTEM "Windows;MSVC")
+        if("${PRESET_TARGET}" MATCHES "x64")
+            # stub example, fill in with the rest
+            list(APPEND D_FLAGS "-mtriple=x86_64-pc-windows-msvc")
+        endif()
+    elseif("${PRESET_TARGET}" MATCHES "Android")
+        set(TARGET_SYSTEM "Android;Linux;UNIX")
+
+        if("${PRESET_TARGET}" MATCHES "arm")
+            list(APPEND D_FLAGS "-mtriple=armv7-none-linux-android")
+            if (RT_CFLAGS_UNCONFIGURED AND NOT CMAKE_HOST_SYSTEM_PROCESSOR MATCHES "arm")
+                check_for_android_ndk()
+                append("-gcc-toolchain $ENV{NDK}/toolchains/arm-linux-androideabi-4.9/prebuilt/linux-x86_64 --sysroot $ENV{NDK}/sysroot -isystem $ENV{NDK}/sysroot/usr/include/arm-linux-androideabi${ANDROID_API}" RT_CFLAGS)
+            endif()
+            if (LD_FLAGS_UNCONFIGURED AND NOT CMAKE_HOST_SYSTEM_PROCESSOR MATCHES "arm")
+                check_for_android_ndk()
+                append("--sysroot=$ENV{NDK}/platforms/android-${ANDROID_API}/arch-arm -gcc-toolchain $ENV{NDK}/toolchains/arm-linux-androideabi-4.9/prebuilt/linux-x86_64 -fuse-ld=bfd" LD_FLAGS)
+            endif()
+        endif()
+    endif()
+endif()