-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathtumblelog.pl
1445 lines (1162 loc) · 42.3 KB
/
tumblelog.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!/usr/bin/perl
use strict;
use warnings;
use open ':std', ':encoding(UTF-8)';
use URI;
use JSON::XS;
use YAML::XS;
use Path::Tiny;
use CommonMark qw(:opt :node :event);
use Time::Piece;
use Time::Seconds;
use Getopt::Long;
use List::Util 'min';
use Encode 'decode';
use Try::Tiny;
my $VERSION = '5.3.5';
my $RE_DATE_TITLE_ARTICLE = qr/
^(\d{4}-\d{2}-\d{2}) # A date in yyyy-mm-dd format at the start
[ \t]+ # One or more spaces or tabs
(.*?) # A title. If empty, an exception will be thrown
[ \t]* # Optional trailing spaces or tabs
\n # A new line
((?:.|\n)*) # An article
/x;
my $RE_NAME_LABEL_DATE_TITLE_ARTICLE =qr/
^@([a-z0-9_-]+) # AT sign followed by a page name at the start
\[[ \t]* # Start label followed by optional spaces or tabs
(.*?) # A label. If empty, an exception will be thrown
[ \t]*\] # Optional spaces or tabs followed by end label
[ \t]+ # One or more spaces or tabs
(\d{4}-\d{2}-\d{2})(!?) # A date in yyyy-mm-dd format with an optional !
[ \t]+ # One or more spaces or tabs
(.*?) # A title. If empty, an exception will be thrown
[ \t]* # Optional trailing spaces or tabs
\n # A new line
((?:.|\n)*) # An article
/x;
my $RE_YAML_MARKDOWN = qr/\s*(---\n.*?\.\.\.\n)?(.*)/sm;
my $RE_TAG = qr/^[\p{Ll}\d]+(?: [\p{Ll}\d]+)*$/;
my $RE_TITLE = qr/\[% \s* title \s* %\]/x;
my $RE_YEAR_RANGE = qr/\[% \s* year-range \s* %\]/x;
my $RE_LABEL = qr/\[% \s* label \s* %\]/x;
my $RE_CSS = qr/\[% \s* css \s* %\]/x;
my $RE_NAME = qr/\[% \s* name \s* %\]/x;
my $RE_AUTHOR = qr/\[% \s* author \s* %\]/x;
my $RE_DESCRIPTION = qr/\[% \s* description \s* %\]/x;
my $RE_VERSION = qr/\[% \s* version \s* %\]/x;
my $RE_PAGE_URL = qr/\[% \s* page-url \s* %\]/x;
my $RE_RSS_FEED_URL = qr/\[% \s* rss-feed-url \s* %\]/x;
my $RE_JSON_FEED_URL = qr/\[% \s* json-feed-url \s* %\]/x;
my $RE_BODY = qr/\[% \s* body \s* %\] \n/x;
my $RE_ARCHIVE = qr/\[% \s* archive \s* %\] \n/x;
my @MON_LIST = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
my @DAY_LIST = qw( Sun Mon Tue Wed Thu Fri Sat );
BEGIN {
# An older version of CommonMark hasn't got this constant yet, so
# we can safely set it to 0
unless ( defined &OPT_UNSAFE ) {
eval 'use constant OPT_UNSAFE => 0';
}
}
create_blog( get_config() );
sub get_config {
my %arguments = (
'template-filename' => undef,
'output-dir' => undef,
'author' => undef,
'name' => undef,
'description' => undef,
'blog-url' => undef,
'days' => 14,
'css' => 'styles.css',
'date-format' => '%d %b %Y',
'label-format' => 'week %V, %Y',
'min-year' => undef,
'tags' => 0,
'tags-label' => 'tags',
'tags-title' => 'Tags',
'feed-size' => 25,
'quiet' => 0,
'version' => 0,
'help' => 0,
);
GetOptions(
\%arguments,
'template-filename=s',
'output-dir=s',
'author=s',
'name=s',
'description=s',
'blog-url=s',
'days=i',
'css=s',
'date-format=s',
'label-format=s',
'min-year=i',
'tags',
'tags-label=s',
'tags-title=s',
'feed-size=i',
'quiet',
'version',
'help',
);
show_usage_and_exit() if $arguments{ help };
if ( $arguments{ version } ) {
print "$VERSION\n";
exit;
}
my $missing = 0;
my %required = (
'template-filename' =>
'Use --template-filename to specify a template',
'output-dir' =>
'Use --output-dir to specify an output directory for HTML files',
'author' =>
'Use --author to specify an author name',
'name' =>
'Use --name to specify a name for the blog and its feeds',
'description' =>
'Use --description to specify a description of the blog'
.' and its feeds',
'blog-url' =>
'Use --blog-url to specify the URL of the blog itself',
);
for my $name ( sort keys %required ) {
if ( !defined $arguments{ $name } ) {
warn "$required{ $name }\n";
$missing++;
}
}
show_usage_and_exit( 2 ) if $missing;
my $filename = shift @ARGV;
if ( !defined $filename ) {
warn "Specify a filename that contains the entries\n";
show_usage_and_exit( 1 );
}
warn "Additional arguments have been skipped\n" if @ARGV;
my %config = %arguments;
$config{ filename } = $filename;
$config{ template } = path( $config{ 'template-filename' } )
->slurp_utf8();
$config{ 'json-path' } = 'feed.json';
$config{ 'json-feed-url' } = URI->new_abs(
@config{ qw( json-path blog-url ) }
)->as_string();
$config{ 'rss-path' } = 'feed.rss';
$config{ 'rss-feed-url' } = URI->new_abs(
@config{ qw( rss-path blog-url ) }
)->as_string();
return \%config;
}
sub create_blog {
my $config = shift;
my ( $days, $pages ) = collect_days_and_pages(
read_entries( $config->{ filename } )
);
if ( $config->{ tags } ) {
convert_articles_with_metablock_to_html( $days, $config );
}
else {
convert_articles_to_html( $days );
}
convert_articles_to_html( $pages );
my $max_year = ( localtime() )[ 5 ] + 1900; # current year
my $min_year;
if ( defined $config->{ 'min-year' } ) {
$min_year = $config->{ 'min-year' };
}
else {
$min_year = $max_year;
$min_year = min(
$min_year, ( split_date( $days->[ -1 ]{ date } ) )[ 0 ]
) if @$days;
$min_year = min(
$min_year, ( split_date( $pages->[ -1 ]{ date } ) )[ 0 ]
) if @$pages;
}
path( $config->{ 'output-dir' } )->mkpath();
my $archive = create_archive( $days );
if ( @$days ) {
create_index( $days, $archive, $config, $min_year, $max_year );
create_day_and_week_pages(
$days, $archive, $config, $min_year, $max_year
);
create_month_pages(
$days, $archive, $config, $min_year, $max_year
);
create_year_pages(
$days, $archive, $config, $min_year, $max_year
);
create_tag_pages(
$days, $archive, $config, $min_year, $max_year
) if $config->{tags};
create_rss_feed( $days, $config );
create_json_feed( $days, $config );
}
create_pages( $pages, $archive, $config, $min_year, $max_year );
return;
}
sub create_index {
my ( $days, $archive, $config, $min_year, $max_year ) = @_;
my $body_html;
my $todo = $config->{ days };
for my $day ( @$days ) {
$body_html .= html_for_date(
$day->{ date }, $config->{ 'date-format' }, $day->{ title },
'archive'
) . join( '', map { $_->{ html } } @{ $day->{ articles } } );
--$todo or last;
}
my $archive_html = html_for_archive(
$archive, undef, 'archive', $config->{ 'label-format' }
);
create_page(
'index.html', 'home', $body_html, $archive_html, $config,
'home', $min_year, $max_year
);
return;
}
sub create_day_and_week_pages {
my ( $days, $archive, $config, $min_year, $max_year ) = @_;
my $year_week;
my $week_body_html;
my $current_year_week = get_year_week( $days->[ 0 ]{ date } );
my $day_archive_html = html_for_archive(
$archive, undef, '../..', $config->{ 'label-format' }
);
my $index = 0;
for my $day ( @$days ) {
my $day_body_html = html_for_date(
$day->{ date }, $config->{ 'date-format' }, $day->{ title },
'../..'
) . join( '', map { $_->{ html } } @{ $day->{ articles } } );
my $label = decode_utf8( parse_date( $day->{ date } )
->strftime( $config->{ 'date-format' } ) );
my ( $year, $month, $day_number ) = split_date( $day->{ date } );
my $next_prev_html = html_for_next_prev( $days, $index, $config );
path( "$config->{ 'output-dir' }/archive/$year/$month")->mkpath();
create_page(
"archive/$year/$month/$day_number.html",
$day->{ title }, $day_body_html . $next_prev_html,
$day_archive_html,
$config,
$label, $min_year, $max_year
);
$year_week = get_year_week( $day->{ date } );
if ( $year_week eq $current_year_week ) {
$week_body_html .= $day_body_html;
}
else {
create_week_page(
$current_year_week, $week_body_html, $archive, $config,
$min_year, $max_year
);
$current_year_week = $year_week;
$week_body_html = $day_body_html;
}
$index++;
}
create_week_page(
$year_week, $week_body_html, $archive, $config,
$min_year, $max_year
);
return;
}
sub create_pages {
my ( $pages, $archive, $config, $min_year, $max_year ) = @_;
my $archive_html = %$archive ? html_for_archive(
$archive, undef, 'archive', $config->{ 'label-format' }
) : '';
for my $page ( @$pages ) {
my $date = $page->{ date };
my $link_text = escape(
decode_utf8(
parse_date( $date )->strftime( $config->{ 'date-format' } )
)
);
my $body_html;
if ( $page->{ 'show-date' } ) {
$body_html = qq(<time class="tl-date" datetime="$date">)
. "$link_text</time>\n";
}
else {
$body_html = qq(<div class="tl-topbar"></div>\n);
}
$body_html .= join( '', map { $_->{ html } } @{ $page->{ articles } } );
create_page(
"$page->{ name }.html",
$page->{ title }, $body_html, $archive_html, $config,
$page->{ label }, $min_year, $max_year
);
}
return;
}
sub create_week_page {
my ( $year_week, $body_html, $archive, $config, $min_year, $max_year ) = @_;
my $archive_html = html_for_archive(
$archive, $year_week, '../..', $config->{ 'label-format' }
);
my ( $year, $week ) = split_year_week( $year_week );
my $title = year_week_title( $config->{ 'label-format' }, $year, $week );
path( "$config->{ 'output-dir' }/archive/$year/week" )->mkpath();
create_page(
"archive/$year/week/$week.html",
$title, $body_html, $archive_html, $config,
$title, $min_year, $max_year
);
return;
}
sub create_month_pages {
my ( $days, $archive, $config, $min_year, $max_year ) = @_;
my %years;
for my $day ( @$days ) {
my ( $year, $month, undef ) = split_date( $day->{ date } );
unshift @{ $years{ $year }{ $month } }, $day;
}
my @month_names = get_month_names();
my $archive_html = html_for_archive(
$archive, undef, '../..', $config->{ 'label-format' }
);
for my $year ( sort keys %years ) {
for my $month ( sort keys %{ $years{ $year } } ) {
my $days_for_month = $years{ $year }{ $month };
my $first_tp = parse_date( $days_for_month->[ 0 ]{ date } );
my $month_name = decode_utf8( $first_tp->strftime( '%B' ) );
my $nav_bar = html_for_month_nav_bar(
$years{ $year }, $month, \@month_names
);
my $body_html = qq(<div class="tl-topbar"></div>\n)
. qq(<div class="tl-month-overview">\n)
. qq( <h2 class="tl-month-year">$month_name )
. qq(<a href="../../$year/">$year</a></h2>)
. qq( <dl class="tl-days">\n)
. join( '',
map { html_for_day( $_ ) } @$days_for_month
)
. " </dl>\n"
. $nav_bar
. "</div>\n";
create_page(
"archive/$year/$month/index.html",
"$month_name, $year", $body_html, $archive_html, $config,
decode_utf8( $first_tp->strftime( '%b, %Y' ) ),
$min_year, $max_year
);
}
}
return;
}
sub create_year_pages {
my ( $days, $archive, $config, $min_year, $max_year ) = @_;
my $start_year = ( split_date( $days->[ -1 ]{ date } ) )[ 0 ];
my $end_year = ( split_date( $days->[ 0 ]{ date } ) )[ 0 ];
my $archive_html = html_for_archive(
$archive, undef, '..', $config->{ 'label-format' }
);
my $day_names_row = html_for_day_names_row();
my $tp = parse_date( "$start_year-01-01" );
my $date_index = $#$days;
my $date = $days->[ $date_index ]{ date };
my $year_index = 0;
for my $year ( $start_year .. $end_year ) {
my $body_html = qq(<div class="tl-topbar"></div>\n)
. qq(<div class="tl-calendar">\n)
. html_for_year_nav_bar(
[ $start_year .. $end_year ], $year_index );
$year_index++;
while ( 1 ) {
my $tbody;
my $wday;
my $week_active = 0;
my $month_active = 0;
my $current_mon = $tp->mon();
my $month_name = decode_utf8( $tp->strftime( '%B' ) );
my @row = ( '' ) x 7;
while ( 1 ) {
$wday = ( $tp->_wday + 6 ) % 7;
if ( $date eq $tp->strftime( '%Y-%m-%d' ) ) {
$month_active = 1;
$week_active = 1;
$row[ $wday ] = html_link_for_day_number(
$days->[ $date_index ]
);
if ( $date_index > 0 ) {
$date_index--;
$date = $days->[ $date_index ]{ date };
}
}
else {
$row[ $wday ] = $tp->mday;
}
if ( $wday == 6 ) {
$tbody .= html_for_row( $year, $tp, \@row, $week_active );
$week_active = 0;
@row = ( '' ) x 7;
}
$tp += ONE_DAY;
last if $tp->mon != $current_mon;
}
$tbody .= html_for_row( $year, $tp, \@row, $week_active )
if $wday < 6;
my $caption;
if ( $month_active ) {
my $uri = sprintf '%02d/', $current_mon;
$caption = qq(<a href="$uri">$month_name</a>);
}
else {
$caption = $month_name;
}
$body_html .= qq( <table class="tl-month">\n)
. " <caption>$caption</caption>\n"
. " <thead>\n"
. $day_names_row
. " </thead>\n"
. " <tbody>\n"
. $tbody
. " </tbody>\n"
. " </table>\n";
last if $tp->year != $year;
}
$body_html .= "</div>\n";
path( "$config->{ 'output-dir' }/archive/$year")->mkpath();
create_page(
"archive/$year/index.html",
$year, $body_html, $archive_html, $config,
$year, $min_year, $max_year
);
}
return;
}
sub create_page {
my ( $path, $title, $body_html, $archive_html, $config,
$label, $min_year, $max_year ) = @_;
my $year_range = $min_year eq $max_year ?
$min_year : "$min_year\N{EN DASH}$max_year";
my $slashes = $path =~ tr{/}{};
my $css = join( '', '../' x $slashes, $config->{ css } );
( my $uri_path = $path ) =~ s/\bindex\.html$//;
my $page_url = URI->new_abs( $uri_path, $config->{ 'blog-url' } );
my $html = $config->{ template };
for ( $html ) {
s/ $RE_TITLE / escape( $title ) /gxe;
s/ $RE_YEAR_RANGE / escape( $year_range ) /gxe;
s/ $RE_LABEL / escape( $label ) /gxe;
s/ $RE_CSS / escape( $css )/gxe;
s/ $RE_NAME / escape( $config->{ name } ) /gxe;
s/ $RE_AUTHOR / escape( $config->{ author } ) /gxe;
s/ $RE_DESCRIPTION / escape( $config->{ description } ) /gxe;
s/ $RE_VERSION / escape( $VERSION ) /gxe;
s/ $RE_PAGE_URL / escape( $page_url ) /gxe;
s/ $RE_RSS_FEED_URL / escape( $config->{ 'rss-feed-url' } ) /gxe;
s/ $RE_JSON_FEED_URL / escape( $config->{ 'json-feed-url' } ) /gxe;
s/ $RE_ARCHIVE /$archive_html/gx;
s/ $RE_BODY /$body_html/x;
}
path( "$config->{ 'output-dir' }/$path" )
->append_utf8( { truncate => 1 }, $html );
$config->{ quiet } or print "Created '$path'\n";
return;
}
sub html_for_day {
my $day = shift;
my $day_number = ( split_date( $day->{ date } ) )[ 2 ];
my $uri = "$day_number.html";
my $title = escape( $day->{ title } );
return qq( <dt>$day_number</dt><dd><a href="$uri">$title</a></dd>\n);
}
sub html_for_month_nav_bar {
my ( $active_months, $current_month, $names ) = @_;
my $html = qq( <nav>\n <ul class="tl-month-navigation">\n);
for my $mon ( 1..12 ) {
my $month = sprintf '%02d', $mon;
my $name = $names->[ $mon - 1 ];
if ( exists $active_months->{ $month } ) {
if ( $month eq $current_month ) {
$html .= qq( <li class="tl-self">$name</li>\n);
}
else {
$html .= qq( <li><a href="../$month/">$name</a></li>\n);
}
}
else {
$html .= qq( <li>$name</li>\n);
}
}
$html .= " </ul>\n </nav>\n";
return $html;
}
sub html_for_day_names_row {
my $tp = parse_date( '2019-01-07' ); # Monday
my $names;
for ( 0..6 ) {
my $day_name = decode_utf8( $tp->strftime( '%a' ) );
$names .= qq( <th scope="col">$day_name</th>\n);
$tp += ONE_DAY;
}
return " <tr>\n <td></td>\n$names </tr>\n";
}
sub html_for_row {
my ( $current_year, $tp, $row, $week_active ) = @_;
my $week_html;
my ( $year, $week ) = get_year_and_week( $tp );
if ( $week_active ) {
my $week_uri = $year == $current_year ? sprintf 'week/%02d.html', $week
: sprintf '../%04d/week/%02d.html', $year, $week;
$week_html = qq(<a href="$week_uri">$week</a>);
}
else {
$week_html = $week;
}
return " <tr>\n"
. qq( <th scope="row">$week_html</th>\n)
. join( '', map { " <td>$_</td>\n" } @$row )
. " </tr>\n";
}
sub html_link_for_day_number {
my $day = shift;
my ( $year, $month, $day_number ) = split_date( $day->{ date } );
my $uri = "../$year/$month/$day_number.html";
my $title = escape( $day->{ title } );
my $mday = int( $day_number );
return qq(<a href="$uri" title="$title">$mday</a>)
}
sub html_for_year_nav_bar {
my ( $years, $year_index, $path ) = @_;
$path //= '';
my $nav;
if ( $year_index > 0 ) {
my $prev = $years->[ $year_index - 1 ];
$nav = " <div>\N{LEFTWARDS ARROW} "
. qq(<a href="../$prev/$path">$prev</a></div>\n)
}
else {
$nav .= " <div></div>\n";
}
$nav .= " <h2>$years->[ $year_index ]</h2>\n";
if ( $year_index < $#$years ) {
my $next = $years->[ $year_index + 1 ];
$nav .= qq( <div><a href="../$next/$path">$next</a> )
. "\N{RIGHTWARDS ARROW}</div>\n"
}
else {
$nav .= " <div></div>\n";
}
return qq( <div class="tl-year">\n$nav </div>\n);
}
sub html_for_date {
my ( $date, $date_format, $title, $path ) = @_;
my ( $year, $month, $day ) = split_date( $date );
my $uri = "$path/$year/$month/$day.html";
my $link_text = escape(
decode_utf8(
parse_date( $date )->strftime( $date_format )
)
);
my $title_text = escape( $title );
return qq(<time class="tl-date" datetime="$date">)
. qq(<a href="$uri" title="$title_text">$link_text</a>)
. "</time>\n";
}
sub html_for_archive {
my ( $archive, $current_year_week, $path, $label_format ) = @_;
my $html = qq(<dl>\n);
for my $year ( sort { $b <=> $a } keys %$archive ) {
$html .= qq( <dt><a href="$path/$year/">$year</a></dt>\n)
. " <dd>\n <ul>\n";
for my $week ( @{ $archive->{ $year } } ) {
my $year_week = join_year_week( $year, $week );
if ( defined $current_year_week
&& $year_week eq $current_year_week ) {
$html .= qq( <li class="tl-self">$week</li>\n);
}
else {
my $title = escape(
year_week_title( $label_format, $year, $week )
);
my $uri = "$path/$year/week/$week.html";
$html .= ' <li>'
. qq(<a href="$uri" title="$title">)
. $week . "</a></li>\n";
}
}
$html .= " </ul>\n </dd>\n";
}
$html .= "</dl>\n";
return $html;
}
sub html_link_for_day {
my ( $day, $config ) = @_;
my $title = escape( $day->{ title } );
my $label = escape(
decode_utf8(
parse_date( $day->{ date } )->strftime( $config->{ 'date-format' } )
)
);
my ( $year, $month, $day_number ) = split_date( $day->{ date } );
my $uri = "../../$year/$month/$day_number.html";
return qq(<a href="$uri" title="$label">$title</a>);
}
sub html_for_next_prev {
my ( $days, $index, $config ) = @_;
return '' if @$days == 1;
my $html = qq(<nav class="tl-next-prev">\n);
if ( $index ) {
$html .= ' <div class="next">'
. html_link_for_day( $days->[ $index - 1 ], $config )
. '</div>'
. qq(<div class="tl-right-arrow">\N{RIGHTWARDS ARROW}</div>\n);
}
if ( $index < $#$days ) {
$html .= qq( <div class="tl-left-arrow">\N{LEFTWARDS ARROW}</div>)
. '<div class="prev">'
. html_link_for_day( $days->[ $index + 1 ], $config )
. "</div>\n";
}
$html .= "</nav>\n";
return $html;
}
sub create_archive {
my $days = shift;
my %seen;
my %archive;
for my $day ( @$days ) {
my ( $year, $week ) = get_year_and_week( parse_date( $day->{ date } ) );
my $year_week = join_year_week( $year, $week );
if ( !exists $seen{ $year_week } ) {
unshift @{ $archive{ sprintf '%04d', $year } },
sprintf '%02d', $week;
$seen{ $year_week } = 1;
}
}
return \%archive
}
sub get_url_title_description {
my ( $day, $config ) = @_;
my $description = join( '', map { $_->{ html } } @{ $day->{ articles } } );
my ( $year, $month, $day_number ) = split_date( $day->{ date } );
my $url = URI->new_abs(
"archive/$year/$month/$day_number.html",
$config->{ 'blog-url' }
)->as_string();
return ( $url, $day->{ title }, $description );
}
sub get_month_names {
my @names;
for my $mon ( 1..12 ) {
my $date = sprintf '2019-%02d-01', $mon;
push @names, decode_utf8( parse_date( $date )->strftime( '%B' ) );
}
return @names;
}
sub get_end_of_day {
return Time::Piece->localtime(
Time::Piece->strptime( shift . ' 23:59:59', '%Y-%m-%d %H:%M:%S' )
);
}
sub get_tag_path {
( my $name = shift ) =~ s/ /-/g;
return "$name.html";
}
sub get_cloud_size {
my ( $count, $min_count, $max_count ) = @_;
return 1 if $min_count == $max_count;
return 1 + int(
4 * ( log( $count ) - log( $min_count ) )
/ ( log( $max_count ) - log( $min_count ) )
);
}
sub create_tag_pages {
my ( $days, $archive, $config, $min_year, $max_year ) = @_;
my $tags = {};
for my $day ( @$days ) {
my $year = ( split_date( $day->{ date } ) )[ 0 ];
for my $article ( reverse @{ $day->{ articles } } ) {
for my $tag ( @{ $article->{ tags } } ) {
$tags->{ $tag }{ count }++;
unshift @{ $tags->{ $tag }{ years }{ $year } }, {
title => $article->{ title },
date => $day->{ date },
};
}
}
}
my $archive_html = html_for_archive(
$archive, undef, '../../archive', $config->{ 'label-format' }
);
my %tag_info;
for my $tag ( sort keys %$tags ) {
my @years = sort keys %{ $tags->{ $tag }{ years } };
$tag_info{ $tag }{ end_year } = $years[ -1 ];
my $tag_path = get_tag_path( $tag );
my $year_index = 0;
for my $year ( @years ) {
my $body_html = qq(<div class="tl-topbar"></div>\n)
. qq(<div class="tl-tag-overview">\n)
. html_for_year_nav_bar( \@years, $year_index, $tag_path )
. " <h2>$tag</h2>\n";
$year_index++;
my $current_month = '';
my $rows = $tags->{ $tag }{ years }{ $year };
for my $row ( @$rows ) {
my $tp = parse_date( $row->{ date } );
my $month_name = decode_utf8( $tp->strftime( '%B' ) );
if ( $month_name ne $current_month ) {
$body_html .= " </dl>\n" if $current_month ne '';
$body_html .= " <h3>$month_name</h3>\n"
. qq( <dl class="tl-days">\n);
$current_month = $month_name;
}
my $nr = ( split_date( $row->{ date } ) )[ 2 ];
$body_html .= " <dt>$nr</dt><dd>$row->{ title }</dd>\n";
$tag_info{ $tag }{ count }++;
}
$body_html .= " </dl>\n</div>\n";
path( "$config->{ 'output-dir' }/tags/$year/")->mkpath();
create_page(
"tags/$year/$tag_path",
$tag, $body_html, $archive_html, $config,
$tag, $min_year, $max_year
);
}
}
# Create a page with a tag cloud
my ( $min_count, $max_count );
for my $tag ( keys %tag_info ) {
$min_count = $tag_info{ $tag }{ count }
if !defined $min_count || $tag_info{ $tag }{ count } < $min_count;
$max_count = $tag_info{ $tag }{ count }
if !defined $max_count || $tag_info{ $tag }{ count } > $max_count;
}
my $body_html = qq(<div class="tl-topbar"></div>\n)
. qq(<div class="tl-tags-overview">\n)
. " <h2>$config->{ 'tags-title' }</h2>\n"
. qq( <ul class="tl-tag-cloud">\n);
for my $tag ( sort keys %tag_info ) {
my $tag_path = get_tag_path( $tag );
my $size = get_cloud_size(
$tag_info{ $tag }{ count }, $min_count, $max_count
);
$body_html .= qq( <li class="tl-size-$size">)
. qq(<a href="$tag_info{ $tag }{ end_year }/$tag_path">)
. "$tag\N{NARROW NO-BREAK SPACE}($tag_info{ $tag }{ count })"
. "</a></li>\n";
}
$body_html .= " </ul>\n</div>\n";
create_page(
'tags/index.html',
$config->{ 'tags-title' }, $body_html, $archive_html, $config,
$config->{ 'tags-label' }, $min_year, $max_year
);
return;
}
sub create_rss_feed {
my ( $days, $config ) = @_;
my @items;
my $todo = $config->{ 'feed-size' };
for my $day ( @$days ) {
my ( $url, $title, $description )
= get_url_title_description( $day, $config );
my $end_of_day = get_end_of_day( $day->{ date } );
# RFC #822 in USA locale
my $pub_date = $DAY_LIST[ $end_of_day->_wday() ]
. sprintf( ', %02d ', $end_of_day->mday() )
. $MON_LIST[ $end_of_day->_mon ]
. $end_of_day->strftime( ' %Y %H:%M:%S %z' );
push @items, join( '',
'<item>',
'<title>', escape( $title ), '</title>',
'<link>', escape( $url ), '</link>',
'<guid isPermaLink="true">', escape( $url ), '</guid>',
'<pubDate>', escape( $pub_date ), '</pubDate>',
'<description>', escape( $description ), '</description>',
'</item>'
);
--$todo or last;
}
my $xml = join( '',
'<?xml version="1.0" encoding="UTF-8"?>',
'<rss version="2.0" xmlns:atom="http://www.w3.org/2005/Atom">',
'<channel>',
'<title>', escape( $config->{ name } ), '</title>',
'<link>', escape( $config->{ 'blog-url' } ), '</link>',
'<description>', escape( $config->{ description } ),'</description>',
'<atom:link href="', escape( $config->{ 'rss-feed-url' } ),
'" rel="self" type="application/rss+xml" />',
@items,
'</channel>',
'</rss>',
"\n"
);
my $path = $config->{ 'rss-path' };
path( "$config->{ 'output-dir' }/$path" )
->append_utf8( { truncate => 1 }, $xml );
$config->{ quiet } or print "Created '$path'\n";
return;
}
sub create_json_feed {
my ( $days, $config ) = @_;
my @items;
my $todo = $config->{ 'feed-size' };
for my $day ( @$days ) {
my ( $url, $title, $description )
= get_url_title_description( $day, $config );
my $end_of_day = get_end_of_day( $day->{ date } );
( my $date_published = $end_of_day->strftime( '%Y-%m-%dT%H:%M:%S%z' ) )
=~ s/(\d\d)$/:$1/a;
push @items, {
id => $url,
url => $url,
title => $title,
content_html => $description,
date_published => $date_published,
};