nix: add support for ghc 9.0.1

Author: berberman

configuration-ghc-901.nix

@@ -0,0 +1,103 @@
+# nix version of cabal-ghc901.project
+{ pkgs }:
+
+let
+  removePluginPackages = hpkgs:
+    removeAttrs hpkgs [
+      "hls-tactics-plugin"
+      "hls-brittany-plugin"
+      "hls-stylish-haskell-plugin"
+      "hls-fourmolu-plugin"
+      "hls-splice-plugin"
+      "hls-ormolu-plugin"
+    ];
+  hpkgsOverride = hself: hsuper:
+    with pkgs.haskell.lib;
+    let
+      lsp-src = pkgs.fetchFromGitHub {
+        owner = "anka-213";
+        repo = "lsp";
+        rev = "tag-ghc-9.0.1-without-pr-326";
+        sha256 = "lW/EdBnvKPLE2+CGE/grIekOu+U/Wh6zMCN4xhJDtPY=";
+      };
+
+      dependent-sum-src = pkgs.fetchFromGitHub {
+        owner = "anka-213";
+        repo = "dependent-sum";
+        rev = "8cf4c7fbc3bfa2be475a17bb7c94a1e1e9a830b5";
+        sha256 = "WtxTB6ufTZC6SxOtGSfhlO4mY0y9eWejMSa0yUJ7dHQ=";
+      };
+      hlint_3_3_1-src = builtins.fetchTarball {
+        url =
+          "https://hackage.haskell.org/package/hlint-3.3.1/hlint-3.3.1.tar.gz";
+        sha256 = "03vb4s4w8k5vp5cjzg7m2bsinbjz1j2aqx4q06syq4r5vb3ai5yq";
+      };
+    in {
+      blaze-textual = hself.callCabal2nix "blaze-textual"
+        (pkgs.fetchFromGitHub {
+          owner = "jwaldmann";
+          repo = "blaze-textual";
+          rev = "d8ee6cf80e27f9619d621c936bb4bda4b99a183f";
+          sha256 = "C0dIzf64fBaY8mlhMm1kCQC5Jc1wKBtNO2Y24k7YPUw=";
+        }) { };
+
+      czipwith = hself.callCabal2nix "czipwith" (pkgs.fetchFromGitHub {
+        owner = "mithrandi";
+        repo = "czipwith";
+        rev = "b6245884ae83e00dd2b5261762549b37390179f8";
+        sha256 = "2uSoGyrxT/OstRcpx55kwP4JwjPbWLxD72LajeyQV0E=";
+      }) { };
+
+      hie-bios = hself.callCabal2nix "hie-bios" (pkgs.fetchFromGitHub {
+        owner = "jneira";
+        repo = "hie-bios";
+        rev = "9b1445ab5efcabfad54043fc9b8e50e9d8c5bbf3";
+        sha256 = "8ct7t3xIxIAoC+f8VO5e5+QKrd5L5Zu1eButSaE+1Uk=";
+      }) { };
+
+      ghc-api-compat = hself.callCabal2nix "ghc-api-compat"
+        (pkgs.fetchFromGitHub {
+          owner = "hsyl20";
+          repo = "ghc-api-compat";
+          rev = "8fee87eac97a538dbe81ff1ab18cff10f2f9fa15";
+          sha256 = "byehvdxQxhNk5ZQUXeFHjAZpAze4Ct9261ro4c5acZk=";
+        }) { };
+
+      th-extras = hself.callCabal2nix "th-extras" (pkgs.fetchFromGitHub {
+        owner = "anka-213";
+        repo = "th-extras";
+        rev = "57a97b4df128eb7b360e8ab9c5759392de8d1659";
+        sha256 = "Qtha1ge/C0L+uFcV2dZ5xpG59DCxQT7LuK/OYfiM4Pk=";
+      }) { };
+
+      lsp = hself.callCabal2nix "lsp" "${lsp-src}/lsp" { };
+      lsp-types = hself.callCabal2nix "lsp-types" "${lsp-src}/lsp-types" { };
+      lsp-test = hself.callCabal2nix "lsp-test" "${lsp-src}/lsp-test" { };
+
+      dependent-sum =
+        hself.callCabal2nix "dependent-sum" "${dependent-sum-src}/dependent-sum"
+        { };
+
+      # Copied from https://github.com/NixOS/nixpkgs/blob/2e672ed71afb9d0cea962b694ddb4e63a9ee00eb/pkgs/development/haskell-modules/configuration-ghc-9.0.x.nix#L109
+      hlint = (hself.callCabal2nix "hlint" hlint_3_3_1-src { }).overrideScope
+        (self: super: {
+          ghc-lib-parser = overrideCabal self.ghc-lib-parser_9_0_1_20210324 {
+            doHaddock = false;
+          };
+          ghc-lib-parser-ex = self.ghc-lib-parser-ex_9_0_0_4;
+        });
+
+      # Disable plugins
+      haskell-language-server =
+        appendConfigureFlags hsuper.haskell-language-server [
+          "-brittany"
+          "-eval"
+          "-fourmolu"
+          "-ormolu"
+          "-splice"
+          "-stylishhaskell"
+          "-tactic"
+          "-refineImports"
+        ];
+    };
+in { tweakHpkgs = hpkgs: (removePluginPackages hpkgs).extend hpkgsOverride; }

flake.nix

@@ -30,24 +30,22 @@
       overlay = final: prev:
         with prev;
         let
-          haskellOverrides = {
-            overrides = hself: hsuper: {
-              # we override mkDerivation here to apply the following
-              # tweak to each haskell package:
-              #   if the package is broken, then we disable its check and relax the cabal bounds;
-              #   otherwise, we leave it unchanged.
-              # hopefully, this could fix packages marked as broken by nix due to check failures
-              # or the build failure because of tight cabal bounds
-              mkDerivation = args:
-                let
-                  broken = args.broken or false;
-                  check = args.doCheck or true;
-                  jailbreak = args.jailbreak or false;
-                in hsuper.mkDerivation (args // {
-                  jailbreak = if broken then true else jailbreak;
-                  doCheck = if broken then false else check;
-                });
-            };
+          haskellOverrides = hself: hsuper: {
+            # we override mkDerivation here to apply the following
+            # tweak to each haskell package:
+            #   if the package is broken, then we disable its check and relax the cabal bounds;
+            #   otherwise, we leave it unchanged.
+            # hopefully, this could fix packages marked as broken by nix due to check failures
+            # or the build failure because of tight cabal bounds
+            mkDerivation = args:
+              let
+                broken = args.broken or false;
+                check = args.doCheck or true;
+                jailbreak = args.jailbreak or false;
+              in hsuper.mkDerivation (args // {
+                jailbreak = if broken then true else jailbreak;
+                doCheck = if broken then false else check;
+              });
           };
           gitignoreSource = (import gitignore { inherit lib; }).gitignoreSource;
 
@@ -91,7 +89,10 @@
             builtins.mapAttrs (_: dir: gitignoreSource dir) sourceDirs;
 
           extended = hpkgs:
-            (hpkgs.override haskellOverrides).extend (hself: hsuper:
+            (hpkgs.override (old: {
+              overrides = lib.composeExtensions (old.overrides or (_: _: { }))
+                haskellOverrides;
+            })).extend (hself: hsuper:
               # disable all checks for our packages
               builtins.mapAttrs (_: drv: haskell.lib.dontCheck drv)
               (lib.composeExtensions
@@ -135,7 +136,7 @@
           hooks = {
             stylish-haskell.enable = true;
             # use stylish-haskell with our target ghc
-            stylish-haskell.entry = "${hpkgs.stylish-haskell}/bin/stylish-haskell --inplace";
+            stylish-haskell.entry = pkgs.lib.mkForce "${hpkgs.stylish-haskell}/bin/stylish-haskell --inplace";
             stylish-haskell.excludes = [
               # Ignored files
               "^Setup.hs$"
@@ -156,14 +157,16 @@
           };
         };
 
+        ghc901Config = (import ./configuration-ghc-901.nix) { inherit pkgs; };
+
         # GHC versions
         ghcDefault = pkgs.hlsHpkgs ("ghc"
           + pkgs.lib.replaceStrings [ "." ] [ "" ]
           pkgs.haskellPackages.ghc.version);
         ghc884 = pkgs.hlsHpkgs "ghc884";
         ghc8104 = pkgs.hlsHpkgs "ghc8104";
         ghc8105 = pkgs.hlsHpkgs "ghc8105";
-        ghc901 = pkgs.hlsHpkgs "ghc901";
+        ghc901 = ghc901Config.tweakHpkgs (pkgs.hlsHpkgs "ghc901");
 
         # Create a development shell of hls project
         # See https://github.com/NixOS/nixpkgs/blob/5d4a430472cafada97888cc80672fab255231f57/pkgs/development/haskell-modules/make-package-set.nix#L319
@@ -172,8 +175,13 @@
           hpkgs.shellFor {
             doBenchmark = true;
             packages = p:
-              with builtins;
-              map (name: p.${name}) (attrNames hlsSources);
+              with lib;
+              # we can remove sources attrs from hpkgs to exclude HLS plugins,
+              # so hpkgs may not be the superset of hlsSources
+              pipe (attrNames hlsSources) [
+                (xs: map (name: p.${name} or null) xs)
+                (xs: remove null xs)
+              ];
             buildInputs = [ gmp zlib ncurses capstone tracy (gen-hls-changelogs hpkgs) ]
               ++ (with hpkgs; [
                 cabal-install
@@ -213,14 +221,14 @@
           haskell-language-server-884-dev = mkDevShell ghc884;
           haskell-language-server-8104-dev = mkDevShell ghc8104;
           haskell-language-server-8105-dev = mkDevShell ghc8105;
-          haskell-language-server-901-dev = builtins.throw "Nix expression for developing HLS in GHC 9.0.1 is not yet available"; # mkDevShell ghc901;
+          haskell-language-server-901-dev = mkDevShell ghc901;
 
           # hls package
           haskell-language-server = mkExe ghcDefault;
           haskell-language-server-884 = mkExe ghc884;
           haskell-language-server-8104 = mkExe ghc8104;
           haskell-language-server-8105 = mkExe ghc8105;
-          haskell-language-server-901 = builtins.throw "Nix expression for building HLS in GHC 9.0.1 is not yet available"; # mkExe ghc901;
+          haskell-language-server-901 = mkExe ghc901;
         };
 
         defaultPackage = packages.haskell-language-server;