cmake: add cmake install + export (#7)

Author: madebr

.gitmodules

@@ -4,3 +4,6 @@
 [submodule "third_party/zlib/zlib"]
 	path = third_party/zlib/zlib
 	url = https://chromium.googlesource.com/chromium/src/third_party/zlib
+[submodule "third_party/lss/lss"]
+	path = third_party/lss/lss
+	url = https://chromium.googlesource.com/linux-syscall-support

CMakeLists.txt

@@ -1,6 +1,47 @@
-cmake_minimum_required(VERSION 3.0)
+cmake_minimum_required(VERSION 3.10)
 project(crashpad LANGUAGES C CXX)
 
+set(CRASHPAD_MAIN_PROJECT OFF)
+if(CMAKE_SOURCE_DIR STREQUAL PROJECT_SOURCE_DIR)
+    set(CRASHPAD_MAIN_PROJECT ON)
+endif()
+
+option(CRASHPAD_ENABLE_INSTALL "Enable crashpad installation" "${CRASHPAD_MAIN_PROJECT}")
+option(CRASHPAD_ENABLE_INSTALL_DEV "Enable crashpad development installation" "${CRASHPAD_MAIN_PROJECT}")
+
+if(MSVC)
+    set(CRASHPAD_ZLIB_SYSTEM_DEFAULT OFF)
+else()
+    set(CRASHPAD_ZLIB_SYSTEM_DEFAULT ON)
+endif()
+option(CRASHPAD_ZLIB_SYSTEM "Use system zlib library" "${CRASHPAD_ZLIB_SYSTEM_DEFAULT}")
+
+if(CRASHPAD_ZLIB_SYSTEM)
+    find_package(ZLIB REQUIRED)
+endif()
+
+include(GNUInstallDirs)
+set(CMAKE_INSTALL_CMAKEDIR "${CMAKE_INSTALL_LIBDIR}/cmake/crashpad")
+
+function(crashpad_install_target)
+    if(CRASHPAD_ENABLE_INSTALL)
+        install(TARGETS ${ARGN} EXPORT crashpad_export
+            ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+            LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+            RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+        )
+    endif()
+endfunction()
+function(crashpad_install_dev)
+    if(CRASHPAD_ENABLE_INSTALL_DEV)
+        install(${ARGN})
+    endif()
+endfunction()
+
+if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
+    set(LINUX TRUE)
+endif()
+
 if(WIN32)
     enable_language(ASM_MASM)
     IF(MINGW)
@@ -9,86 +50,73 @@ if(WIN32)
             SET(CMAKE_ASM_MASM_COMPILER "uasm")
             SET(CMAKE_ASM_MASM_FLAGS "-win64 -10")
         else()
-            message(FATAL_ERROR "UASM is required for MinGW builds ! Make sure you have it installed")
+            message(FATAL_ERROR "UASM is required for MinGW builds! Make sure you have it installed")
         endif()
     endif()
 else()
     enable_language(ASM)
 endif()
 
 set(CMAKE_CXX_STANDARD 14)
-set(CMAKE_CXX_STANDARD_REQUIRED True)
-
-if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
-    set(LINUX TRUE)
-endif()
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
 
-include_directories("${CMAKE_CURRENT_SOURCE_DIR}")
-include_directories("${CMAKE_CURRENT_SOURCE_DIR}/third_party/mini_chromium/mini_chromium")
-
-# These should really be in `compat`, but we want them for the whole project
-if(APPLE)
-    include_directories(SYSTEM "compat/mac")
-else()
-    include_directories(PUBLIC "compat/non_mac")
-endif()
-
-if(LINUX OR ANDROID)
-    include_directories(SYSTEM "compat/linux")
-endif()
-if(ANDROID)
-    include_directories(SYSTEM "compat/android")
-endif()
-
-if(MSVC)
-    include_directories(SYSTEM "compat/win")
-elseif(MINGW)
-    include_directories(PUBLIC "compat/mingw")
-else()
-    include_directories(PUBLIC "compat/non_win")
-endif()
-
-if(NOT LINUX AND NOT ANDROID)
-    include_directories(SYSTEM "compat/non_elf")
-endif()
+add_library(crashpad_interface INTERFACE)
+target_include_directories(crashpad_interface INTERFACE
+    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/third_party/mini_chromium/mini_chromium>
+)
+target_compile_definitions(crashpad_interface INTERFACE
+    CRASHPAD_LSS_SOURCE_EMBEDDED
+)
 
 if(MSVC)
-    add_definitions(
-        /DNOMINMAX
-        /DUNICODE
-        /DWIN32_LEAN_AND_MEAN
-        /D_CRT_SECURE_NO_WARNINGS
-        /D_HAS_EXCEPTIONS=0
-        /D_UNICODE
-        /FS
-        /W4
-        /WX
-        /Zi
-        /bigobj # Support larger number of sections in obj file.
-        /wd4100 # Unreferenced formal parameter.
-        /wd4127 # Conditional expression is constant.
-        /wd4324 # Structure was padded due to alignment specifier.
-        /wd4351 # New behavior: elements of array will be default initialized.
-        /wd4577 # 'noexcept' used with no exception handling mode specified.
-        /wd4996 # 'X' was declared deprecated.
+    target_compile_definitions(crashpad_interface INTERFACE
+        NOMINMAX
+        UNICODE
+        WIN32_LEAN_AND_MEAN
+        _CRT_SECURE_NO_WARNINGS
+        _HAS_EXCEPTIONS=0
+        _UNICODE
     )
-elseif(MINGW)
-    #redirect to wmain
-    add_link_options(
-        -municode
+    target_compile_options(crashpad_interface INTERFACE
+        $<$<COMPILE_LANGUAGE:C,CXX>:/FS>
+        $<$<COMPILE_LANGUAGE:C,CXX>:/W4>
+        $<$<COMPILE_LANGUAGE:C,CXX>:/WX>
+        $<$<COMPILE_LANGUAGE:C,CXX>:/Zi>
+        $<$<COMPILE_LANGUAGE:C,CXX>:/bigobj> # Support larger number of sections in obj file.
+        $<$<COMPILE_LANGUAGE:C,CXX>:/wd4100> # Unreferenced formal parameter.
+        $<$<COMPILE_LANGUAGE:C,CXX>:/wd4127> # Conditional expression is constant.
+        $<$<COMPILE_LANGUAGE:C,CXX>:/wd4324> # Structure was padded due to alignment specifier.
+        $<$<COMPILE_LANGUAGE:C,CXX>:/wd4351> # New behavior: elements of array will be default initialized.
+        $<$<COMPILE_LANGUAGE:C,CXX>:/wd4577> # 'noexcept' used with no exception handling mode specified.
+        $<$<COMPILE_LANGUAGE:C,CXX>:/wd4996> # 'X' was declared deprecated.
     )
+elseif(MINGW)
+    # redirect to wmain
+    # FIXME: cmake 3.13 added target_link_options
+    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -municode")
 endif()
+add_library(crashpad::interface ALIAS crashpad_interface)
 
-add_subdirectory(client)
 add_subdirectory(compat)
-add_subdirectory(handler)
 add_subdirectory(minidump)
 add_subdirectory(snapshot)
-add_subdirectory(tools)
 add_subdirectory(util)
 add_subdirectory(third_party/mini_chromium)
+add_subdirectory(client)
 
-if(MSVC)
-    add_subdirectory(third_party/getopt)
-    add_subdirectory(third_party/zlib)
-endif()
+add_subdirectory(third_party/zlib)
+add_subdirectory(third_party/getopt)
+
+add_subdirectory(tools)
+add_subdirectory(handler)
+
+if(CRASHPAD_ENABLE_INSTALL_DEV)
+    install(EXPORT crashpad_export NAMESPACE crashpad:: FILE crashpad-targets.cmake
+        DESTINATION "${CMAKE_INSTALL_CMAKEDIR}")
+    include(CMakePackageConfigHelpers)
+    configure_package_config_file(crashpad-config.cmake.in crashpad-config.cmake
+        INSTALL_DESTINATION "${CMAKE_INSTALL_CMAKEDIR}"
+    )
+    install(FILES "${CMAKE_CURRENT_BINARY_DIR}/crashpad-config.cmake" DESTINATION "${CMAKE_INSTALL_CMAKEDIR}")
+endif()

client/CMakeLists.txt

@@ -1,4 +1,4 @@
-list(APPEND CLIENT_SOURCES
+add_library(crashpad_client STATIC
     annotation.cc
     annotation.h
     annotation_list.cc
@@ -18,7 +18,7 @@ list(APPEND CLIENT_SOURCES
 )
 
 if(APPLE)
-    list(APPEND CLIENT_SOURCES
+    target_sources(crashpad_client PRIVATE
         crash_report_database_mac.mm
         crashpad_client_mac.cc
         simulate_crash_mac.cc
@@ -27,37 +27,47 @@ if(APPLE)
 endif()
 
 if(LINUX OR ANDROID)
-    list(APPEND CLIENT_SOURCES
-      crashpad_client_linux.cc
-      simulate_crash_linux.h
-      client_argv_handling.cc
-      client_argv_handling.h
-      crashpad_info_note.S
-      crash_report_database_generic.cc
+    target_sources(crashpad_client PRIVATE
+        crashpad_client_linux.cc
+        simulate_crash_linux.h
+        client_argv_handling.cc
+        client_argv_handling.h
+        crashpad_info_note.S
+        crash_report_database_generic.cc
     )
 endif()
 
 if(WIN32)
-    list(APPEND CLIENT_SOURCES
-      crash_report_database_win.cc
-      crashpad_client_win.cc
-      simulate_crash_win.h
+    target_sources(crashpad_client PRIVATE
+        crash_report_database_win.cc
+        crashpad_client_win.cc
+        simulate_crash_win.h
     )
 endif()
 
-add_library(crashpad_client STATIC ${CLIENT_SOURCES})
+target_include_directories(crashpad_client INTERFACE
+    "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>"
+    "$<INSTALL_INTERFACE:include/crashpad/client>"
+)
 target_link_libraries(crashpad_client
-    crashpad_compat
-    crashpad_util
-    mini_chromium
+    PRIVATE
+        $<BUILD_INTERFACE:crashpad_interface>
+    PUBLIC
+        crashpad_compat
+        crashpad_util
+        mini_chromium
 )
+target_compile_features(crashpad_client PUBLIC cxx_std_14)
+
+set_property(TARGET crashpad_client PROPERTY EXPORT_NAME client)
+add_library(crashpad::client ALIAS crashpad_client)
 
 if(WIN32)
-    target_link_libraries(crashpad_client "rpcrt4")
+    target_link_libraries(crashpad_client PRIVATE rpcrt4)
     if(MSVC)
-        target_compile_options(crashpad_client PUBLIC "/wd4201")
+        target_compile_options(crashpad_client PRIVATE "/wd4201")
     elseif(MINGW)
-        target_compile_options(crashpad_client PRIVATE 
+        target_compile_options(crashpad_client PUBLIC
             "-municode"
         )
     endif()
@@ -73,3 +83,9 @@ if(WIN32)
         )
     endif()
 endif()
+
+crashpad_install_target(crashpad_client)
+crashpad_install_dev(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/"
+    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/crashpad/client"
+    FILES_MATCHING PATTERN "*.h"
+)

compat/CMakeLists.txt

@@ -1,4 +1,4 @@
-list(APPEND COMPAT_SOURCES "")
+set(COMPAT_SOURCES)
 
 if(APPLE)
     list(APPEND COMPAT_SOURCES
@@ -83,13 +83,39 @@ endif()
 
 if(APPLE)
     add_library(crashpad_compat INTERFACE)
-    list(TRANSFORM COMPAT_SOURCES PREPEND "${CMAKE_CURRENT_SOURCE_DIR}/")
-    target_sources(crashpad_compat INTERFACE ${COMPAT_SOURCES})
+    set(TI_TYPE "INTERFACE")
 else()
     add_library(crashpad_compat STATIC ${COMPAT_SOURCES})
     set_target_properties(crashpad_compat PROPERTIES LINKER_LANGUAGE CXX)
+    set(TI_TYPE "PUBLIC")
+    target_link_libraries(crashpad_compat PRIVATE
+        $<BUILD_INTERFACE:crashpad_interface>
+    )
 endif()
 
 if(MSVC)
-    target_link_libraries(crashpad_compat getopt)
+    target_include_directories(crashpad_compat ${TI_TYPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/win>")
+elseif(MINGW)
+    target_include_directories(crashpad_compat ${TI_TYPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mingw>")
+else()
+    target_include_directories(crashpad_compat ${TI_TYPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/non_win>")
+endif()
+
+if(APPLE)
+    target_include_directories(crashpad_compat ${TI_TYPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mac>")
+else()
+    target_include_directories(crashpad_compat ${TI_TYPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/non_mac>")
 endif()
+
+if(LINUX OR ANDROID)
+    target_include_directories(crashpad_compat ${TI_YPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/linux>")
+endif()
+
+if(ANDROID)
+    target_include_directories(crashpad_compat ${TI_YPE} "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/android>")
+endif()
+
+set_property(TARGET crashpad_compat PROPERTY EXPORT_NAME compat)
+add_library(crashpad::compat ALIAS crashpad_compat)
+
+crashpad_install_target(crashpad_compat)

crashpad-config.cmake.in

@@ -0,0 +1,10 @@
+include("${CMAKE_CURRENT_LIST_DIR}/crashpad-targets.cmake")
+
+if(@CRASHPAD_ZLIB_SYSTEM@)
+    find_package(ZLIB REQUIRED)
+    target_include_directories(crashpad::zlib INTERFACE ${ZLIB_INCLUDE_DIRS})
+    target_compile_definitions(crashpad::zlib INTERFACE ${ZLIB_COMPILE_DEFINITIONS})
+    target_link_libraries(crashpad::zlib INTERFACE ${ZLIB_LIBRARIES})
+endif()
+
+@PACKAGE_INIT@