Guessing a package for a given documented name

[olexandr-konovalov]

Inspired by #1135, I've modified a bit IsDocumentedWord, and now I can do the following:

gap> GuessPackage("PcNormalizedUnitGroup");
[ "laguna" ]
gap> GuessPackage("Set");
[ "reference" ]
gap> GuessPackage("set");
[  ]
gap> GuessPackage("set",false);
[ "reference" ]
gap> GuessPackage("AutomorphismGroup");
[ "reference", "autpgrp", "fga", "gpd not loaded", "guava", "loops not loaded", "sophus" ]
gap> GuessPackage("Centralizer");
[ "fga", "polycyclic", "polycyclic", "wedderga", "xmod not loaded" ]

The code does this:

GuessPackage := function( arg ) 

  local inid, word, case, simple, cword, book, matches, a, match, res;

  inid:= Union( CHARS_DIGITS, CHARS_UALPHA, "_", CHARS_LALPHA );
  word := arg[1];
  if Length( arg ) > 1 and arg[2] = false then
    case:= LowercaseString;
  else
    case:= IdFunc;
  fi;
  res:=[];
  simple:= SIMPLE_STRING( word );
  cword:= case( word );
  for book in HELP_KNOWN_BOOKS[1] do
    matches:= HELP_GET_MATCHES( [ book ], simple, true );
    for a in Concatenation( matches ) do
      match:= case( StripEscapeSequences( a[1].entries[ a[2] ][1] ) );
      if match = cword then
        Append(res,[book]);
      fi;
    od;
  od;
  return res;
end;

Recording this as an issue, as it needs more testing.

By the way, we have

gap> ?IsDocumentedWord
Help: no matching entry found
Help: 'IsDocumentedWord' is currently undocumented.
      For details, try ?Undocumented Variables

and

gap> IsDocumentedWord("a",true);
true
gap> IsDocumentedWord("the",true);
true
gap> IsDocumentedWord("over",true);
true