-
Notifications
You must be signed in to change notification settings - Fork 22
/
Copy pathgram.f90
295 lines (275 loc) · 9.15 KB
/
gram.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
!
! Copyright (C) 2002-2007 Quantum ESPRESSO group
! This file is distributed under the terms of the
! GNU General Public License. See the file `License'
! in the root directory of the present distribution,
! or http://www.gnu.org/copyleft/gpl.txt .
!
!-------------------------------------------------------------------------
SUBROUTINE gram_bgrp( betae, bec_bgrp, nkbx, cp_bgrp, ngwx )
!-----------------------------------------------------------------------
! gram-schmidt orthogonalization of the set of wavefunctions cp
!
USE uspp, ONLY : nkb, nhsavb=> nkbus
USE gvecw, ONLY : ngw
USE electrons_base, ONLY : nbspx_bgrp, ibgrp_g2l, nupdwn, iupdwn, nbspx, iupdwn_bgrp, nspin
USE kinds, ONLY : DP
USE mp_global, ONLY : inter_bgrp_comm
USE mp, ONLY : mp_sum
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: nkbx, ngwx
REAL(DP) :: bec_bgrp( nkbx, nbspx_bgrp )
COMPLEX(DP) :: cp_bgrp( ngwx, nbspx_bgrp ), betae( ngwx, nkb )
!
REAL(DP) :: anorm
REAL(DP), ALLOCATABLE :: csc( : )
COMPLEX(DP), ALLOCATABLE :: ctmp( : )
INTEGER :: i,k,j, ig, ibgrp_k, ibgrp_i, nbgrp_im1, iss
REAL(DP), PARAMETER :: one = 1.d0
REAL(DP), PARAMETER :: mone = -1.d0
!
CALL start_clock( 'gram' )
ALLOCATE( csc( nbspx ) )
ALLOCATE( ctmp( ngwx ) )
!
DO iss = 1, nspin
DO i = iupdwn(iss), iupdwn(iss) + nupdwn(iss) - 1
!
ibgrp_i = ibgrp_g2l( i )
!
CALL gracsc_bgrp( bec_bgrp, betae, cp_bgrp, i, csc, iss, nbgrp_im1 )
!
! calculate orthogonalized cp(i) : |cp(i)>=|cp(i)>-\sum_k<i csc(k)|cp(k)>
!
IF( ibgrp_i > 0 ) THEN
ctmp = cp_bgrp( :, ibgrp_i )
ELSE
ctmp = 0.0d0
END IF
!
IF( nbgrp_im1 > 0 ) &
CALL dgemv( 'N', 2*ngw, nbgrp_im1, mone, cp_bgrp(1,iupdwn_bgrp(iss)), 2*ngwx, csc, 1, one, ctmp, 1 )
CALL mp_sum( ctmp, inter_bgrp_comm )
IF( ibgrp_i > 0 ) THEN
cp_bgrp( :, ibgrp_i ) = ctmp
anorm = cscnorm( bec_bgrp, cp_bgrp, ibgrp_i, nbspx_bgrp )
CALL dscal( 2*ngw, 1.0d0/anorm, cp_bgrp(1,ibgrp_i), 1 )
CALL dscal( nkbx, 1.0d0/anorm, bec_bgrp(1,ibgrp_i), 1 )
END IF
END DO
END DO
!
DEALLOCATE( ctmp )
DEALLOCATE( csc )
CALL stop_clock( 'gram' )
!
RETURN
CONTAINS
!-----------------------------------------------------------------------
FUNCTION cscnorm( bec, cp, i, n )
!-----------------------------------------------------------------------
!
! Compute the norm of the i-th electronic state = (<c|S|c>)^(1/2)
! requires in input the updated bec(i)
!
USE ions_base, ONLY: na
USE gvecw, ONLY: ngw
USE gvect, ONLY: gstart
USE uspp_param, ONLY: nh, ish, nvb
USE uspp, ONLY: qq
USE mp, ONLY: mp_sum
USE mp_global, ONLY: intra_bgrp_comm
USE kinds, ONLY: DP
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: i, n
REAL(DP), INTENT(IN) :: bec( :, : )
COMPLEX(DP), INTENT(IN) :: cp( :, : )
!
REAL(DP) :: cscnorm
!
INTEGER ig, is, iv, jv, ia, inl, jnl
REAL(DP) rsum
REAL(DP), ALLOCATABLE:: temp(:)
!
!
ALLOCATE(temp(ngw))
DO ig=1,ngw
temp(ig)=DBLE(CONJG(cp(ig,i))*cp(ig,i))
END DO
rsum=2.d0*SUM(temp)
IF (gstart == 2) rsum=rsum-temp(1)
CALL mp_sum( rsum, intra_bgrp_comm )
DEALLOCATE(temp)
!
DO is=1,nvb
DO iv=1,nh(is)
DO jv=1,nh(is)
IF(ABS(qq(iv,jv,is)).GT.1.e-5) THEN
DO ia=1,na(is)
inl=ish(is)+(iv-1)*na(is)+ia
jnl=ish(is)+(jv-1)*na(is)+ia
rsum = rsum + &
& qq(iv,jv,is)*bec(inl,i)*bec(jnl,i)
END DO
ENDIF
END DO
END DO
END DO
!
cscnorm=SQRT(rsum)
!
RETURN
END FUNCTION cscnorm
!
!
!-------------------------------------------------------------------------
SUBROUTINE gracsc_bgrp( bec_bgrp, betae, cp_bgrp, i, csc, iss, nk )
!-----------------------------------------------------------------------
! requires in input the updated bec(k) for k<i
! on output: bec(i) is recalculated
!
USE ions_base, ONLY: na
USE uspp, ONLY : nkb, nhsavb=>nkbus, qq
USE uspp_param, ONLY: nh, nvb, ish
USE electrons_base, ONLY: ispin, ispin_bgrp, nbspx_bgrp, ibgrp_g2l, iupdwn, nupdwn, nbspx
USE gvecw, ONLY: ngw
USE mp, ONLY: mp_sum
USE mp_global, ONLY: intra_bgrp_comm, inter_bgrp_comm
USE kinds, ONLY: DP
USE gvect, ONLY: gstart
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: i, iss
INTEGER, INTENT(OUT) :: nk
COMPLEX(DP) :: betae( :, : )
REAL(DP) :: bec_bgrp( :, : )
COMPLEX(DP) :: cp_bgrp( :, : )
REAL(DP) :: csc( : )
INTEGER :: k, kmax,ig, is, iv, jv, ia, inl, jnl, ibgrp_k, ibgrp_i
REAL(DP) :: rsum
REAL(DP), ALLOCATABLE :: temp(:)
COMPLEX(DP), ALLOCATABLE :: cp_tmp(:)
REAL(DP), ALLOCATABLE :: bec_tmp(:)
REAL(DP), ALLOCATABLE :: csc2( : )
!
! calculate csc(k)=<cp(i)|cp(k)>, k<i
!
kmax = i - 1
!
ALLOCATE( cp_tmp( ngwx ) )
ALLOCATE( bec_tmp( nkbx ) )
ALLOCATE( csc2( SIZE( csc ) ) )
cp_tmp = 0.0d0
csc = 0.0d0
ibgrp_i = ibgrp_g2l( i )
IF( ibgrp_i > 0 ) cp_tmp = cp_bgrp( :, ibgrp_i )
CALL mp_sum( cp_tmp, inter_bgrp_comm )
!$omp parallel default(none), &
!$omp shared(iupdwn,kmax,ispin,ibgrp_g2l,ngw,cp_bgrp,cp_tmp,csc,nhsavb,betae,bec_bgrp,i,iss,gstart), &
!$omp private( temp, k, ig, inl, ibgrp_k, ibgrp_i )
ALLOCATE( temp( ngw ) )
!$omp do
DO k = iupdwn( iss ), kmax
IF ( ispin(i) .EQ. ispin(k) ) THEN
ibgrp_k = ibgrp_g2l( k )
IF( ibgrp_k > 0 ) THEN
DO ig = 1, ngw
!temp(ig) = cp_bgrp(1,ig,ibgrp_k) * cp_tmp(1,ig) + cp_bgrp(2,ig,ibgrp_k) * cp_tmp(2,ig)
temp(ig) = DBLE( cp_bgrp(ig,ibgrp_k) * CONJG(cp_tmp(ig)) )
END DO
csc(k) = 2.0d0 * SUM(temp)
IF (gstart == 2) csc(k) = csc(k) - temp(1)
END IF
ENDIF
END DO
!$omp end do
!
!
! calculate bec(i)=<cp(i)|beta>
!
ibgrp_i = ibgrp_g2l( i )
!
IF( ibgrp_i > 0 ) THEN
!$omp do
DO inl=1,nhsavb
DO ig=1,ngw
temp(ig) = DBLE( cp_bgrp(ig,ibgrp_i) * CONJG(betae(ig,inl)) )
! temp(ig)=cp_bgrp(1,ig,ibgrp_i)* DBLE(betae(ig,inl))+ &
! & cp_bgrp(2,ig,ibgrp_i)*AIMAG(betae(ig,inl))
END DO
bec_bgrp(inl,ibgrp_i)=2.d0*SUM(temp)
IF (gstart == 2) bec_bgrp(inl,ibgrp_i)= bec_bgrp(inl,ibgrp_i)-temp(1)
END DO
!$omp end do
END IF
DEALLOCATE( temp )
!$omp end parallel
CALL mp_sum( csc, intra_bgrp_comm )
CALL mp_sum( csc, inter_bgrp_comm )
IF( ibgrp_i > 0 ) THEN
CALL mp_sum( bec_bgrp( 1:nhsavb, ibgrp_i ), intra_bgrp_comm )
END IF
bec_tmp = 0.0d0
IF( ibgrp_i > 0 ) bec_tmp = bec_bgrp(:,ibgrp_i )
CALL mp_sum( bec_tmp, inter_bgrp_comm )
!
! calculate csc(k)=<cp(i)|S|cp(k)>, k<i
!
csc2 = 0.0d0
!$omp parallel do default(shared), private( k, is, iv, jv, ia, inl, jnl, rsum, ibgrp_k )
DO k=iupdwn(iss), kmax
IF (ispin(i).EQ.ispin(k)) THEN
rsum=0.d0
ibgrp_k = ibgrp_g2l( k )
IF( ibgrp_k > 0 ) THEN
DO is=1,nvb
DO iv=1,nh(is)
DO jv=1,nh(is)
IF(ABS(qq(iv,jv,is)).GT.1.e-5) THEN
DO ia=1,na(is)
inl=ish(is)+(iv-1)*na(is)+ia
jnl=ish(is)+(jv-1)*na(is)+ia
rsum = rsum + qq(iv,jv,is)*bec_tmp(inl)*bec_bgrp(jnl,ibgrp_k)
END DO
ENDIF
END DO
END DO
END DO
END IF
csc2(k)=csc2(k)+rsum
ENDIF
END DO
!$omp end parallel do
!
! orthogonalized cp(i) : |cp(i)>=|cp(i)>-\sum_k<i csc(k)|cp(k)>
!
! corresponing bec: bec(i)=<cp(i)|beta>-csc(k)<cp(k)|beta>
!
CALL mp_sum( csc2, inter_bgrp_comm )
csc = csc + csc2
bec_tmp = 0.0d0
nk = 0
DO k = iupdwn(iss), kmax
ibgrp_k = ibgrp_g2l( k )
IF( ibgrp_k > 0 ) THEN
nk = nk + 1
DO inl=1,nkbx
bec_tmp(inl)=bec_tmp(inl)-csc(k)*bec_bgrp(inl,ibgrp_k)
END DO
csc( nk ) = csc( k )
END IF
END DO
CALL mp_sum( bec_tmp, inter_bgrp_comm )
IF( ibgrp_i > 0 ) bec_bgrp(:,ibgrp_i ) = bec_bgrp(:,ibgrp_i ) + bec_tmp
DEALLOCATE( csc2 )
DEALLOCATE( bec_tmp )
DEALLOCATE( cp_tmp )
!
RETURN
END SUBROUTINE gracsc_bgrp
END SUBROUTINE gram_bgrp