Usage of printf() xTaskGetTickCount() vTaskDelay()

[nopnop2002]

My environment:
Arduino-IDE 1.8.5 + ATMEGA2560

There is 2 issues.
#1 xTaskGetTickCount() makes a system crash.
#2 printf() not work.

Source Code:

#include <Arduino_FreeRTOS.h>

// Task Body
void task(void *pvParameters)
{
#if 1
  Serial.print("xTaskGetTickCount=");
  Serial.println(xTaskGetTickCount());
#endif

  printf("pcTaskGetName=[%s]\n",pcTaskGetName(NULL));
  Serial.print("pcTaskGetName=");
  Serial.println(pcTaskGetName(NULL));
  pinMode(LED_BUILTIN, OUTPUT);
  for (;;) // A Task shall never return or exit.
  {
    digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
  vTaskDelete( NULL );
}


//------------------------------------------------------------------------------
void setup() {
  portBASE_TYPE xTask1, xTask2;

  Serial.begin(115200);
  Serial.println("setup() start");
  Serial.print("configTICK_RATE_HZ:");
  Serial.println(configTICK_RATE_HZ);
  Serial.print("portTICK_PERIOD_MS:");
  Serial.println(portTICK_PERIOD_MS);
  Serial.print("freeRTOS version:");
  Serial.println(tskKERNEL_VERSION_NUMBER);

  xTask1 = xTaskCreate(task, "Task1", configMINIMAL_STACK_SIZE, NULL, 2, NULL);
//  xTask2 = xTaskCreate(task, "Task2", configMINIMAL_STACK_SIZE, NULL, 2, NULL);

  /* Check everything was created. */
  configASSERT( xTask1 );
//  configASSERT( xTask2 );

// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

//------------------------------------------------------------------------------
// WARNING loop() called from vApplicationIdleHook(), so don't use this function.
// loop must never block
void loop() {
  // Not used.
}

[feilipu]

It is likely that both these issues are caused by a Stack overflow.

The printf(), and more particularly Serial.print(), functions require large amounts of Stack.
The initialisation of Serial requires 64 Bytes for each of the Tx and Rx buffers. Calling Serial.print() in each Task may allocate buffers on the stack each time it is initialised.

Given you're using a ATmega2560, try using 512 bytes of Stack for each Task, for example.

If that doesn't work, add a comment here.

[nopnop2002]

OK
I'll try this weekend.

[nopnop2002]

I give 2048 byte of stack for each task.
But it don't work.

#include <Arduino_FreeRTOS.h>

// Task Body
void task(void *pvParameters)
{
  Serial.print("pcTaskGetName=");
  Serial.println(pcTaskGetName(NULL));
  Serial.print("xTaskGetTickCount=");
  Serial.println(xTaskGetTickCount());

  printf("pcTaskGetName=[%s]\n",pcTaskGetName(NULL));

  pinMode(LED_BUILTIN, OUTPUT);
  for (;;) // A Task shall never return or exit.
  {
    Serial.print("xTaskGetTickCount=");
    Serial.println(xTaskGetTickCount());
    digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
  vTaskDelete( NULL );
}


//------------------------------------------------------------------------------
void setup() {
  portBASE_TYPE xTask1, xTask2;

  Serial.begin(115200);
  Serial.println("setup() start");
  Serial.print("configTICK_RATE_HZ:");
  Serial.println(configTICK_RATE_HZ);
  Serial.print("portTICK_PERIOD_MS:");
  Serial.println(portTICK_PERIOD_MS);
  Serial.print("freeRTOS version:");
  Serial.println(tskKERNEL_VERSION_NUMBER);

  xTask1 = xTaskCreate(task, "Task1", 2048, NULL, 2, NULL);
//  xTask2 = xTaskCreate(task, "Task2", configMINIMAL_STACK_SIZE, NULL, 2, NULL);

  /* Check everything was created. */
  configASSERT( xTask1 );
//  configASSERT( xTask2 );

// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

//------------------------------------------------------------------------------
// WARNING loop() called from vApplicationIdleHook(), so don't use this function.
// loop must never block
void loop() {
  // Not used.
}

[feilipu]

Tested working with below code.
xTaskGetTickCount() is not causing a crash.

The printf() statement was stopping things working, otherwise.
I didn't bother to test, but usually it needs the #include <stdio.h> to work.

#include <Arduino_FreeRTOS.h>

static void task( void *pvParameters );

// Task Body
void task(void *pvParameters)
{
  Serial.print("pcTaskGetName=");
  Serial.println(pcTaskGetName(NULL));

  pinMode(LED_BUILTIN, OUTPUT);
  for (;;) // A Task shall never return or exit.
  {
    Serial.print(F("xTaskGetTickCount="));
    Serial.println(xTaskGetTickCount());
    digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
  vTaskDelete( NULL );
}

//------------------------------------------------------------------------------
void setup() {
  portBASE_TYPE xTask1, xTask2;

  Serial.begin(38400);
  Serial.println(F("setup() start"));

  Serial.print(F("configTICK_RATE_HZ:"));
  Serial.println(configTICK_RATE_HZ);
  Serial.print(F("portTICK_PERIOD_MS:"));
  Serial.println(portTICK_PERIOD_MS);
  Serial.print(F("freeRTOS version:"));
  Serial.println(tskKERNEL_VERSION_NUMBER);

  xTask1 = xTaskCreate(task, "Task1", 256, NULL, 2, NULL);
//  xTask2 = xTaskCreate(task, "Task2", 256, NULL, 2, NULL);

  /* Check everything was created. */
 configASSERT( xTask1 );
//  configASSERT( xTask2 );

// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

//------------------------------------------------------------------------------
// WARNING loop() called from vApplicationIdleHook(), so don't use this function.
// loop must never block
void loop() {
  // Not used.
}

[nopnop2002]

printf() crashes the system.
And vTaskDelay() also crashes the system.

#include <Arduino_FreeRTOS.h>
#include <task.h>

void ConsumptionTick(int delay) {
    TickType_t startTick;
    TickType_t endTick;
    TickType_t nowTick;
    startTick = xTaskGetTickCount();
    endTick = startTick + delay;
    //printf("startTick=%d endTick=%d\n",startTick,endTick);
    while(1) {
      nowTick = xTaskGetTickCount();
      if (nowTick > endTick) break;
    }
}

// Task Body
void task(void *pvParameters)
{
  UBaseType_t prio;
  TickType_t nowTick;

  Serial.print("start pcTaskGetName=");
  Serial.print(pcTaskGetName(NULL));
  Serial.print(" uxTaskPriorityGet=");
  Serial.print(uxTaskPriorityGet(NULL));
  Serial.print(" xTaskGetTickCount=");
  Serial.println(xTaskGetTickCount());

  ConsumptionTick(200);

  Serial.print("end pcTaskGetName=");
  Serial.print(pcTaskGetName(NULL));
  Serial.print(" xTaskGetTickCount=");
  Serial.println(xTaskGetTickCount());

  vTaskDelete( NULL );
}


//------------------------------------------------------------------------------
void setup() {
  TaskHandle_t xHandle1 = NULL;
  TaskHandle_t xHandle2 = NULL;
  BaseType_t xReturned;
  
  Serial.begin(115200);
  Serial.println("setup() start");
  Serial.print("configTICK_RATE_HZ:");
  Serial.println(configTICK_RATE_HZ);
  Serial.print("portTICK_PERIOD_MS:");
  Serial.println(portTICK_PERIOD_MS);
  Serial.print("configMAX_PRIORITIES:");
  Serial.println(configMAX_PRIORITIES);
  Serial.print("freeRTOS version:");
  Serial.println(tskKERNEL_VERSION_NUMBER);

  xReturned = xTaskCreate(task, "myTask1", 256, NULL, 2, &xHandle1);
  if( xReturned != pdPASS ) {
    Serial.println("myTask1 xTaskCreate fail");
  }

  // delay 16mSec
  //vTaskDelay(16 / portTICK_PERIOD_MS);
  vTaskDelay(10);

  xReturned = xTaskCreate(task, "myTask2", 256, NULL, 3, &xHandle2);
  if( xReturned != pdPASS ) {
    Serial.println("myTask2 xTaskCreate fail");
  }


// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

//------------------------------------------------------------------------------
// WARNING loop() called from vApplicationIdleHook(), so don't use this function.
// loop must never block
void loop() {
  // Not used.
}

[feilipu]

I mentioned above that if you want to use printf() you need to include the stdio.h header in your code, or it won't work.

Also, vTaskDelay() is not "crashing the system". I demonstrated it working in the code above.

Please, read the instructions on how to use the library from the FreeRTOS web site, and use working examples as a tutorial.

[nopnop2002]

In my environment, printf() crashes even if I include stdio.h.

#include <Arduino_FreeRTOS.h>
#include <stdio.h>

I tried the code you provided.
This code work fine.

#include <Arduino_FreeRTOS.h>

static void task( void *pvParameters );

// Task Body
void task(void *pvParameters)
{
  Serial.print("pcTaskGetName=");
  Serial.println(pcTaskGetName(NULL));

  pinMode(LED_BUILTIN, OUTPUT);
  for (;;) // A Task shall never return or exit.
  {
    Serial.print(F("xTaskGetTickCount="));
    Serial.println(xTaskGetTickCount());
    digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
  vTaskDelete( NULL );
}

//------------------------------------------------------------------------------
void setup() {
  portBASE_TYPE xTask1, xTask2;

  Serial.begin(38400);
  Serial.println(F("setup() start"));

  Serial.print(F("configTICK_RATE_HZ:"));
  Serial.println(configTICK_RATE_HZ);
  Serial.print(F("portTICK_PERIOD_MS:"));
  Serial.println(portTICK_PERIOD_MS);
  Serial.print(F("freeRTOS version:"));
  Serial.println(tskKERNEL_VERSION_NUMBER);

  xTask1 = xTaskCreate(task, "Task1", 256, NULL, 2, NULL);
  xTask2 = xTaskCreate(task, "Task2", 256, NULL, 2, NULL);

  /* Check everything was created. */
  configASSERT( xTask1 );
  configASSERT( xTask2 );

// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

//------------------------------------------------------------------------------
// WARNING loop() called from vApplicationIdleHook(), so don't use this function.
// loop must never block
void loop() {
  // Not used.
}

This code don't work.

#include <Arduino_FreeRTOS.h>

static void task( void *pvParameters );

// Task Body
void task(void *pvParameters)
{
  Serial.print("pcTaskGetName=");
  Serial.println(pcTaskGetName(NULL));

  pinMode(LED_BUILTIN, OUTPUT);
  for (;;) // A Task shall never return or exit.
  {
    Serial.print(F("xTaskGetTickCount="));
    Serial.println(xTaskGetTickCount());
    digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
  vTaskDelete( NULL );
}

//------------------------------------------------------------------------------
void setup() {
  portBASE_TYPE xTask1, xTask2;

  Serial.begin(38400);
  Serial.println(F("setup() start"));

  Serial.print(F("configTICK_RATE_HZ:"));
  Serial.println(configTICK_RATE_HZ);
  Serial.print(F("portTICK_PERIOD_MS:"));
  Serial.println(portTICK_PERIOD_MS);
  Serial.print(F("freeRTOS version:"));
  Serial.println(tskKERNEL_VERSION_NUMBER);

  xTask1 = xTaskCreate(task, "Task1", 256, NULL, 2, NULL);

  vTaskDelay(10);

  xTask2 = xTaskCreate(task, "Task2", 256, NULL, 2, NULL);

  /* Check everything was created. */
  configASSERT( xTask1 );
  configASSERT( xTask2 );

// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

//------------------------------------------------------------------------------
// WARNING loop() called from vApplicationIdleHook(), so don't use this function.
// loop must never block
void loop() {
  // Not used.
}

My environment:
Arduino-IDE 1.8.12 + ATMega2560

name=FreeRTOS
version=10.3.0-1
author=Richard Barry <info@freertos.org>
maintainer=Phillip Stevens <phillip.stevens@gmail.com>
sentence=Real Time Operating System implemented for AVR (Uno, Leonardo, Mega).
paragraph=The primary design goals are: Easy to use, Small footprint, Robust. Uses Watchdog Timer for 15ms resolution. Slow blink = stack overflow. Fast blink = heap malloc() failure.
category=Timing
url=https://github.com/feilipu/Arduino_FreeRTOS_Library
architectures=avr
license=MIT
includes=Arduino_FreeRTOS.h

[feilipu]

I'd note that a quick Google search would inform that printf()doesn't work at all in the Arduino IDE.
Apologies that I didn't do that for you earlier.

Open the File/Examples/FreeRTOS/Blink_AnalogRead example. Compile and upload it. Note the LED is flashing. Note that analogue samples are printed on the serial port. Note that vTaskDelay() doesn't crash. Therefore, note that there's something you need to fix with your sketch.

[feilipu]

You can't do a delay depending on the scheduler, before the scheduler has been started...

  xTask1 = xTaskCreate(task, "Task1", 256, NULL, 2, NULL);
  vTaskDelay(10); // <--- NO
  xTask2 = xTaskCreate(task, "Task2", 256, NULL, 2, NULL);

Read the comment at the bottom of the setup...

// Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.

[nopnop2002]

OK!!

I understood everything.
Thank you for your support.