ACU info

[llandyw]

I'd written an archive lister way back when and have the directory structure for ACU in 6502 assembly.

Here's the code for the ACU portion of the lister.

*=================================================
* ACU  (APPLE)                                   *
*                                                *
*              Copyright 1988-2017               *
*                 Andrew Wells                   *
*=================================================
* FILE FORMAT
*-------------------------------------------------
*
*  Archive Header
*      File1 Header
*          Resource Fork Of File1
*          Data Fork Of File1
*              .
*              .
*      Filen Header
*          Resource Fork Of Filen
*          Data Fork Of Filen
*
*-------------------------------------------------
* Master Header
*-------------------------------------------------
*
	DUM	HDRBUF
ACU_RECS	DA	0	; * Records In Archive
ACU_OS	DA	0	; * Files Operating System
*
* ACU_OS	0	ProDOS Or SOS
*	1	DOS 3.3
*	2	Reserved
*	3	DOS 3.2 Or DOS 3.1
*	4	Apple II Pascal
*	5	Macintosh MFS
*	6	Macintosh HFS
*	7	Macintosh XL
*	8	Apple CP/M
*	9	Reserved
*	A	MS-DOS
*	B	High Sierra (CD-ROM)
*	C	ISO 9660 (CD-ROM)
*	D	AppleShare
*
	ASC	'fZink'	; * ACU ID String
ACU_VER	DB	0	; * ACU Version Number
ACU_HLEN	DA	0	;   ACU Header Length
	DS	8	; Reserved
			; Total Length Of 20 Bytes
*
*-------------------------------------------------
* File Header
*-------------------------------------------------
*
ACU_RCMP	DB	0	; * Resource Fork Compression Method
	DB	0	;   Data Fork Compression Method
*
* ACUFxCMP	0	Stored
*	1
*	2
*	3	Huffman
*
	DA	0	;   Resource Fork CRC-16
	DA	0	;   Data Fork CRC-16
	ADRL	0	;   Resource Fork Blocks Used
	ADRL	0	;   Data Fork Blocks Used
ACU_RSIZ	ADRL	0	; * Resource Fork Compressed Size
ACU_DSIZ	ADRL	0	; * Data Fork Compressed Size
ACU_ACS	DA	0	; * File Access Flags
ACU_FTYP	DA	0	; * File Type
ACU_AUX	ADRL	0	; * File Aux Type
	DA	0	;   Reserved
	DA	0	;   File Storage Type
ACU_REOF	ADRL	0	; * Resource Fork Uncompressed Size
ACU_DEOF	ADRL	0	; * Data Fork Uncompressed Size
ACU_MDAT	DA	0	; * File Modified Date, P8 Format
ACU_MTIM	DA	0	; * File Modified Time, P8 Format
	DA	0	;   File Create Date, P8 Format
	DA	0	;   File Create Time, P8 Format
ACU_FNLN	DA	0	; * Length Of File Name
	DA	0	;   CRC Of Header
ACU_FNAM	DS	1	; * Filename
	DEND
*
*-------------------------------------------------
* POSITIONING IN FILE
*-------------------------------------------------
*
* First File Header = Beginning Of File + 20
*
* Beginning Of File Data = Beginning Of File Header
*                          + 54 + ACU_FNLN
*
* Next File Header      = Beginning Of File Header
*                          + 54 + ACU_FNLN
*                          + ACU_RSIZ + ACU_DSIZ
*       Or
*		= Beginning Of File Data
*		+ ACU_RSIZ + ACU_DSIZ
*
*=================================================
*
*AppleLink Conversion Utility, Version: Xxxx
*
*OS, X Records
*
DO_ACU	JSR	MARKZERO
DO_ACU2	JSR	SHOWSTR
	DCI	'AppleLink Conversion Utility, V'
	JSR	DO_DEC
	DB	$80
	DB	0-1
	DA	ACU_VER
	JSR	DO_CROUT
	JSR	DO_CROUT
	LDA	ACU_OS
	JSR	ZINKOS
	JSR	SHOWSTR
	DCI	', '
	JSR	DO_DEC
	DB	$80
	DB	1-1
	DA	ACU_RECS
	JSR	SHOWSTR	; Print number of records
	DCI	' Records'
	LDA	#$80	; Show List Header
	JSR	APLHDR
	LDY	#20	; Skip Master Header
	JSR	DO_READ
	DA	ACU_FNAM
	JSR	GET_MARK	; Get Starting Mark
	STX	LASTMARK
	STA	LASTMARK+1
	STY	LASTMARK+2
:ACULOOP	LDY	#54	; Read In Header
	JSR	DO_READ
	DA	ACU_RCMP
	LDY	ACU_FNLN	; Read in filename
	JSR	DO_READ
	DA	ACU_FNAM
	JSR	PD_ACCES	; Print File Access Flag
	DA	ACU_ACS
	LDA	#0	; Print File Name
	LDY	ACU_FNLN
	JSR	DO_PSTR
	DA	ACU_FNAM
	JSR	PRTYPE	; Print File Type
	DA	ACU_FTYP
	JSR	PDOSDATE	; Print Prodos Date
	DA	ACU_MDAT
	JSR	PDOSTIME	; Print Prodos Time
	DA	ACU_MTIM
	JSR	DO_AUX	; Print Aux Type
	DA	ACU_AUX
	JSR	DO_ADD	; Add Uncompressed EOF's
	DB	LONG
	DA	ACU_REOF
	DB	LONG
	DA	ACU_DEOF
	DB	LONG
	DA	RDEOF
	JSR	DO_DEC	; Print File Size
	DB	8
	DB	3-1
	DA	RDEOF
	JSR	DO_TWOSP
	LDX	#0
	LDA	ACU_DSIZ
	ORA	ACU_DSIZ+1
	ORA	ACU_DSIZ+2
	ORA	ACU_DSIZ+3
	BEQ	:USEFORK

	INX
:USEFORK	LDA	ACU_RCMP,X	; Print The Format
	CMP	#3+1	; Valid format?
	BLT	:FMTOK	; Yes
	LDA	#1	; Make it unknown
:FMTOK	ASL
	TAY
	LDX	:FORMATS,Y
	LDA	:FORMATS+1,Y
	JSR	PRINTFMT
	JSR	DO_ADD	; Add Compressed EOF's
	DB	LADR
	DA	ACU_RSIZ
	DB	LADR
	DA	ACU_DSIZ
	DB	LADR
	DA	RDSIZ
	JSR	DO_PER	; Print Compression Percent
	DB	LADR-1
	DA	RDSIZ
	DB	LADR-1
	DA	RDEOF
	JSR	DO_CROUT
	BIT	INTOUT
	BMI	:ACUDONE

	LDA	ACU_RECS
	BNE	:DECREC
	DEC	ACU_RECS+1
:DECREC	DEC	ACU_RECS
	LDA	ACU_RECS
	ORA	ACU_RECS+1
	BEQ	:ACUDONE

	JSR	DO_ADD	; Add In Header Length
	DB	LADR
	DA	LASTMARK
	DB	WORD
	DA	ACU_HLEN
	DB	LADR
	DA	LASTMARK
	JSR	DO_ADD	; Add In Filename Length
	DB	LADR
	DA	LASTMARK
	DB	WORD
	DA	ACU_FNLN
	DB	LADR
	DA	LASTMARK
	JSR	DO_ADD	; Add In Compressed EOF's
	DB	LADR
	DA	LASTMARK
	DB	LADR
	DA	RDSIZ
	DB	LADR
	DA	LASTMARK
	LDX	LASTMARK
	LDA	LASTMARK+1
	LDY	LASTMARK+2
	JSR	SET_POS
	JMP	:ACULOOP

:ACUDONE	RTS

:FORMATS	DA	STORE
	DA	UNK
	DA	UNK
	DA	HUFF

[fadden]

Thanks, this is helpful. My reverse-engineering for the original CiderPress was incomplete (https://github.com/fadden/ciderpress/blob/master/app/ACUArchive.cpp). Apparently I hadn't found an archive with resource forks.

[fadden]

I added a notes file for the format: https://github.com/fadden/CiderPress2/blob/main/DiskArc/Arc/AppleLink-notes.md

[fadden]

The implementation is checked in. Seems to work, though I wasn't able to find an algorithm that matched the checksum fields. Tried the usual CRC-16 algorithms and a simple checksum. I dug through CD-ROMs and the old "ground" FTP site and found a few dozen archives, but none of them held a forked file, so that's officially still untested.

A working copy of ACU would be helpful. Computing the checksum on a couple of files with known contents might be revealing (https://reveng.sourceforge.io/crc-catalogue/16.htm has a list of algorithms and check values).

[fadden]

Antoine Vignau found a copy of ACU v1.06 and put it online (see note here). Some experimentation revealed that the CRCs are being generated incorrectly for files larger than 256 bytes, and ACU doesn't notice bad checksums on files larger than 256 bytes.