introduce native api to access RuntimeExecutor (#42758)

Summary:

Changelog: [Added][iOS] introduce native api to access RuntimeExecutor

The goal of this API is to provide a safe way to access the `jsi::runtime` in bridgeless mode. The decision to limit access to the runtime in bridgeless was a conscious one - the runtime pointer is not thread-safe and its lifecycle must be managed correctly by owners.

However, interacting with the runtime is an advanced use case we would want to support. Our recommended ways to access the runtime in bridgeless mode is either 1) via the RuntimeExecutor, or 2) via a C++ TurboModule.

This diff introduces the API that would allow for 1). The integration consists of these parts:
- Wrapper objects for RuntimeExecutor access. These are `RCTRuntimeExecution` and `RCTRuntimeExecutionWrapper`. RCTRuntimeExecutionWrapper is a C++ free wrapper of RCTRuntimeExecution to be reliably used in Swift modules.
- The new API on RCTBridgeModule, following a similar pattern to other decoration APIs, and integration with our module infrastructure.

Differential Revision: D53256188

Author: philIip

packages/react-native/React/Base/RCTBridgeModule.h

@@ -22,6 +22,7 @@
 @class RCTModuleRegistry;
 @class RCTViewRegistry;
 @class RCTCallableJSModules;
+@class RCTRuntimeExecutionWrapper;
 
 /**
  * The type of a block that is capable of sending a response to a bridged
@@ -150,6 +151,11 @@ RCT_EXTERN_C_END
  */
 @property (nonatomic, weak, readonly) RCTBridge *bridge RCT_DEPRECATED;
 
+/**
+ * A way to reference the RuntimeExecutor.
+ */
+@property (nonatomic, readonly) RCTRuntimeExecutionWrapper *runtimeExecutionWrapper;
+
 /**
  * This property is deprecated. This selector used to support two functionalities.
  *

packages/react-native/React/Base/RCTRuntimeExecutionWrapper.h

@@ -0,0 +1,24 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+@class RCTRuntimeExecution;
+
+NS_ASSUME_NONNULL_BEGIN
+
+/**
+ Swift friendly wrapper of RCTRuntimeExecution.
+ */
+@interface RCTRuntimeExecutionWrapper : NSObject
+
+- (instancetype)init NS_UNAVAILABLE;
+- (instancetype)initWithRuntimeExecution:(RCTRuntimeExecution *)runtimeExecution;
+
+- (RCTRuntimeExecution *)getRuntimeExecution;
+
+@end
+
+NS_ASSUME_NONNULL_END

packages/react-native/React/Base/RCTRuntimeExecutionWrapper.m

@@ -0,0 +1,32 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "RCTRuntimeExecutionWrapper.h"
+
+@implementation RCTRuntimeExecutionWrapper {
+  RCTRuntimeExecution *_runtimeExecution;
+}
+
+#pragma mark - Initializer
+
+- (instancetype)initWithRuntimeExecution:(RCTRuntimeExecution *)runtimeExecution
+{
+  if (self = [super init]) {
+    _runtimeExecution = runtimeExecution;
+  }
+
+  return self;
+}
+
+#pragma mark - Public API
+
+- (RCTRuntimeExecution *)getRuntimeExecution
+{
+  return _runtimeExecution;
+}
+
+@end

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTRuntimeExecution.h

@@ -0,0 +1,36 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import <jsi/jsi.h>
+
+#import <ReactCommon/CallInvoker.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+typedef void (^RCTJSIRuntimeHandlingBlock)(facebook::jsi::Runtime &runtime);
+typedef void (^RCTRuntimeExecutorBlock)(RCTJSIRuntimeHandlingBlock);
+
+@interface RCTRuntimeExecution : NSObject
+
+- (instancetype)init NS_UNAVAILABLE;
+
+/**
+ Initializes an object that wraps ways to access the RuntimeExecutor.
+
+ @param callInvoker A native-to-JS call invoker.
+ @param runtimeExecutorBlock A block that provides thread-safe access to jsi::runtime.
+ */
+- (instancetype)initWithCallInvoker:(std::shared_ptr<facebook::react::CallInvoker>)callInvoker
+               runtimeExecutorBlock:(RCTRuntimeExecutorBlock)runtimeExecutorBlock NS_DESIGNATED_INITIALIZER;
+
+- (std::shared_ptr<facebook::react::CallInvoker>)callInvoker;
+
+- (RCTRuntimeExecutorBlock)runtimeExecutorBlock;
+
+@end
+
+NS_ASSUME_NONNULL_END

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTRuntimeExecution.mm

@@ -0,0 +1,40 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "RCTRuntimeExecution.h"
+
+@implementation RCTRuntimeExecution {
+  std::shared_ptr<facebook::react::CallInvoker> _callInvoker;
+  RCTRuntimeExecutorBlock _runtimeExecutorBlock;
+}
+
+#pragma mark - Initializer
+
+- (instancetype)initWithCallInvoker:(std::shared_ptr<facebook::react::CallInvoker>)callInvoker
+               runtimeExecutorBlock:(RCTRuntimeExecutorBlock)runtimeExecutorBlock
+{
+  if (self = [super init]) {
+    _callInvoker = callInvoker;
+    _runtimeExecutorBlock = [runtimeExecutorBlock copy];
+  }
+
+  return self;
+}
+
+#pragma mark - Public API
+
+- (std::shared_ptr<facebook::react::CallInvoker>)callInvoker
+{
+  return _callInvoker;
+}
+
+- (RCTRuntimeExecutorBlock)runtimeExecutorBlock
+{
+  return _runtimeExecutorBlock;
+}
+
+@end

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTTurboModuleManager.h

@@ -15,8 +15,12 @@
 #import <React/RCTTurboModuleRegistry.h>
 #import <ReactCommon/RuntimeExecutor.h>
 #import <ReactCommon/TurboModuleBinding.h>
+
+#import "RCTRuntimeExecution.h"
 #import "RCTTurboModule.h"
 
+@class RCTTurboModuleManager;
+
 @protocol RCTTurboModuleManagerDelegate <NSObject>
 
 /**
@@ -50,6 +54,9 @@
 - (NSArray<id<RCTBridgeModule>> *)extraModulesForBridge:(RCTBridge *)bridge
     __attribute((deprecated("Please make all native modules returned from this method TurboModule-compatible.")));
 
+- (void)turboModuleManager:(RCTTurboModuleManager *)turboModuleManager
+        handleRuntimeBlock:(RCTJSIRuntimeHandlingBlock)block;
+
 @end
 
 @interface RCTTurboModuleManager : NSObject <RCTTurboModuleRegistry>

packages/react-native/ReactCommon/react/nativemodule/core/platform/ios/ReactCommon/RCTTurboModuleManager.mm

@@ -24,6 +24,7 @@
 #import <React/RCTLog.h>
 #import <React/RCTModuleData.h>
 #import <React/RCTPerformanceLogger.h>
+#import <React/RCTRuntimeExecutionWrapper.h>
 #import <React/RCTUtils.h>
 #import <ReactCommon/RuntimeExecutor.h>
 #import <ReactCommon/TurboCxxModule.h>
@@ -676,6 +677,21 @@ - (BOOL)_shouldCreateObjCModule:(Class)moduleClass
     }
   }
 
+  if ([module respondsToSelector:@selector(runtimeExecutionWrapper)]) {
+    __weak __typeof(self) weakSelf = self;
+    RCTRuntimeExecution *runtimeExecution =
+        [[RCTRuntimeExecution alloc] initWithCallInvoker:_jsInvoker
+                                    runtimeExecutorBlock:^void(RCTJSIRuntimeHandlingBlock block) {
+                                      __strong __typeof(self) strongSelf = weakSelf;
+                                      if (strongSelf) {
+                                        [strongSelf->_delegate turboModuleManager:strongSelf handleRuntimeBlock:block];
+                                      }
+                                    }];
+    RCTRuntimeExecutionWrapper *runtimeExecutionWrapper =
+        [[RCTRuntimeExecutionWrapper alloc] initWithRuntimeExecution:runtimeExecution];
+    [(id)module setValue:runtimeExecutionWrapper forKey:@"runtimeExecutionWrapper"];
+  }
+
   /**
    * Some modules need their own queues, but don't provide any, so we need to create it for them.
    * These modules typically have the following:

packages/react-native/ReactCommon/react/runtime/platform/ios/ReactCommon/RCTInstance.mm

@@ -208,6 +208,15 @@ - (Class)getModuleClassFromName:(const char *)name
   return nullptr;
 }
 
+- (void)turboModuleManager:(RCTTurboModuleManager *)turboModuleManager
+        handleRuntimeBlock:(RCTJSIRuntimeHandlingBlock)block;
+{
+  if (_valid) {
+    RuntimeExecutor bufferedRuntimeExecutor = _reactInstance->getBufferedRuntimeExecutor();
+    bufferedRuntimeExecutor([=](jsi::Runtime &runtime) { block(runtime); });
+  }
+}
+
 #pragma mark - Private
 
 - (void)_start