expand-snippet: indent according to the line where snippet is expanded

Author: kiennq

lsp-mode.el

@@ -72,6 +72,7 @@
 (defvar c-basic-offset)
 (defvar yas-inhibit-overlay-modification-protection)
 (defvar yas-indent-line)
+(defvar yas-also-auto-indent-first-line)
 (defvar dap-auto-configure-mode)
 
 (defconst lsp--message-type-face
@@ -3759,21 +3760,45 @@ The method uses `replace-buffer-contents'."
                                     beg (+ beg (length new-text))
                                     length)))))))))
 
-(defun lsp--indent-snippets? ()
-  "Enable indenting of snippets for everything but `org-mode'.
+(defun lsp--to-yasnippet-snippet (snippet)
+  "Convert LSP SNIPPET to yasnippet snippet."
+  ;; LSP snippet doesn't escape "{", but yasnippet requires escaping it.
+  (replace-regexp-in-string (rx (or bos (not (any "$" "\\"))) (group "{"))
+                            (rx "\\" (backref 1))
+                            snippet
+                            nil nil 1))
 
-Indending snippets is extremely slow in `org-mode' buffers since
-it has to calculate identation based on SRC block position."
-  (unless (derived-mode-p 'org-mode)
-    'auto))
+(defun lsp--expand-snippet (snippet &optional start end expand-env keep-whitespace)
+  "Wrapper of `yas-expand-snippet' with all of it arguments.
+The snippet will be convert to LSP style and indent according to
+LSP server result."
+  (let* ((inhibit-field-text-motion t)
+         (offset (save-excursion
+                   (goto-char start)
+                   (back-to-indentation)
+                   (buffer-substring-no-properties
+                    (line-beginning-position)
+                    (point))))
+         (yas-indent-line (unless keep-whitespace 'auto))
+         (yas-also-auto-indent-first-line nil)
+         (indent-line-function (if (or (and lsp-enable-indentation
+                                            (or (lsp-feature? "textDocument/rangeFormatting")
+                                                (lsp-feature? "textDocument/formatting")))
+                                       (derived-mode-p 'org-mode))
+                                   (lambda () (save-excursion
+                                                (forward-line 0)
+                                                (insert offset)))
+                                 indent-line-function)))
+    (yas-expand-snippet
+     (lsp--to-yasnippet-snippet snippet)
+     start end expand-env)))
 
 (defun lsp--apply-text-edits (edits)
-  "Apply the edits described in the TextEdit[] object."
+  "Apply the EDITS described in the TextEdit[] object."
   (unless (seq-empty-p edits)
     (atomic-change-group
       (run-hooks 'lsp-before-apply-edits-hook)
-      (let* ((change-group (when (functionp 'undo-amalgamate-change-group)
-                             (prepare-change-group)))
+      (let* ((change-group (prepare-change-group))
              (howmany (length edits))
              (message (format "Applying %s edits to `%s' ..." howmany (current-buffer)))
              (_ (lsp--info message))
@@ -3796,9 +3821,7 @@ it has to calculate identation based on SRC block position."
                            (-when-let ((&SnippetTextEdit :range (&RangeToPoint :start)
                                                          :insert-text-format? :new-text) edit)
                              (when (eq insert-text-format? lsp/insert-text-format-snippet)
-                               (let ((yas-indent-line (lsp--indent-snippets?)))
-                                 (yas-expand-snippet (lsp--to-yasnippet-snippet new-text)
-                                                     start (+ start (length new-text))))))))))
+                               (lsp--expand-snippet new-text start (+ start (length new-text)))))))))
           (undo-amalgamate-change-group change-group)
           (progress-reporter-done reporter))))))
 
@@ -4574,7 +4597,8 @@ Others: TRIGGER-CHARS"
                        'lsp-completion-markers markers
                        'lsp-completion-prefix prefix)
                (text-properties-at 0 candidate))
-              ((&CompletionItem :label :insert-text? :text-edit? :insert-text-format? :additional-text-edits?)
+              ((&CompletionItem :label :insert-text? :text-edit? :insert-text-format?
+                                :additional-text-edits? :keep-whitespace?)
                item))
         (cond
          (text-edit?
@@ -4587,12 +4611,12 @@ Others: TRIGGER-CHARS"
           (delete-region start-point (point))
           (insert (or insert-text? label))))
 
-        (when (eq insert-text-format? 2)
-          (let ((yas-indent-line (lsp--indent-snippets?)))
-            (yas-expand-snippet
-             (lsp--to-yasnippet-snippet (buffer-substring start-point (point)))
-             start-point
-             (point))))
+        (when (equal insert-text-format? lsp/insert-text-format-snippet)
+          (lsp--expand-snippet (buffer-substring start-point (point))
+                               start-point
+                               (point)
+                               nil
+                               keep-whitespace?))
 
         (when lsp-completion-enable-additional-text-edit
           (if (or (get-text-property 0 'lsp-completion-resolved candidate)
@@ -4616,14 +4640,6 @@ Others: TRIGGER-CHARS"
           (setq this-command 'self-insert-command)))
     (lsp--capf-clear-cache)))
 
-(defun lsp--to-yasnippet-snippet (text)
-  "Convert LSP snippet TEXT to yasnippet snippet."
-  ;; LSP snippet doesn't escape "{", but yasnippet requires escaping it.
-  (replace-regexp-in-string (rx (or bos (not (any "$" "\\"))) (group "{"))
-                            (rx "\\" (backref 1))
-                            text
-                            nil nil 1))
-
 (defun lsp--regex-fuzzy (str)
   "Build a regex sequence from STR. Insert .* between each char."
   (apply #'concat

lsp-protocol.el

@@ -403,7 +403,7 @@ See `-let' for a description of the destructuring mechanism."
  (Command (:title :command) (:arguments))
  (CompletionCapabilities nil (:completionItem :completionItemKind :contextSupport :dynamicRegistration))
  (CompletionContext (:triggerKind) (:triggerCharacter))
- (CompletionItem (:label) (:additionalTextEdits :command :commitCharacters :data :deprecated :detail :documentation :filterText :insertText :insertTextFormat :kind :preselect :sortText :tags :textEdit :score))
+ (CompletionItem (:label) (:additionalTextEdits :command :commitCharacters :data :deprecated :detail :documentation :filterText :insertText :insertTextFormat :kind :preselect :sortText :tags :textEdit :score :keepWhitespace))
  (CompletionItemCapabilities nil (:commitCharactersSupport :deprecatedSupport :documentationFormat :preselectSupport :snippetSupport :tagSupport))
  (CompletionItemKindCapabilities nil (:valueSet))
  (CompletionItemTagSupportCapabilities (:valueSet) nil)