|
| 1 | +defmodule ExICE.MDNS.Resolver do |
| 2 | + @moduledoc false |
| 3 | + # This is based on https://datatracker.ietf.org/doc/html/draft-ietf-mmusic-mdns-ice-candidates#section-3.2.1 |
| 4 | + |
| 5 | + use GenServer, restart: :transient |
| 6 | + |
| 7 | + require Logger |
| 8 | + |
| 9 | + @mdns_port 5353 |
| 10 | + @multicast_addr {{224, 0, 0, 251}, @mdns_port} |
| 11 | + @response_timeout_ms 300 |
| 12 | + |
| 13 | + @spec start_link(module()) :: GenServer.on_start() |
| 14 | + def start_link(transport_module \\ :gen_udp) do |
| 15 | + GenServer.start_link(__MODULE__, transport_module, name: __MODULE__) |
| 16 | + end |
| 17 | + |
| 18 | + @spec gethostbyname(String.t()) :: {:ok, :inet.ip_address()} | {:error, term()} |
| 19 | + def gethostbyname(addr) do |
| 20 | + try do |
| 21 | + GenServer.call(__MODULE__, {:gethostbyname, addr}) |
| 22 | + catch |
| 23 | + :exit, {:timeout, _} -> |
| 24 | + {:error, :timeout} |
| 25 | + end |
| 26 | + end |
| 27 | + |
| 28 | + @impl true |
| 29 | + def init(transport_module) do |
| 30 | + Logger.debug("Starting MDNS Resolver") |
| 31 | + {:ok, %{transport_module: transport_module}, {:continue, nil}} |
| 32 | + end |
| 33 | + |
| 34 | + @impl true |
| 35 | + def handle_continue(_, state) do |
| 36 | + ret = |
| 37 | + state.transport_module.open( |
| 38 | + # Listen on the port specific to mDNS traffic. |
| 39 | + # `add_membership` option only defines an address. |
| 40 | + @mdns_port, |
| 41 | + mode: :binary, |
| 42 | + reuseaddr: true, |
| 43 | + active: true, |
| 44 | + # Allow other apps to bind to @mdns_port. |
| 45 | + # If there are multiple sockets, bound to the same port, |
| 46 | + # and subscribed to the same group (in fact, if one socket |
| 47 | + # subscribes to some group, all other sockets bound to |
| 48 | + # the same port also join this gorup), all those sockets |
| 49 | + # will receive every message. In other words, `reuseport` for |
| 50 | + # multicast works differently than for casual sockets. |
| 51 | + reuseport: true, |
| 52 | + # Support running two ICE agents on a single machine. |
| 53 | + # In other case, our request won't be delivered to the mDNS address owner |
| 54 | + # running on the same machine (e.g., a web browser). |
| 55 | + multicast_loop: true, |
| 56 | + # Receive responses - they are sent to the multicast address. |
| 57 | + # The second argument specifies interfaces where we should listen |
| 58 | + # for multicast traffic. |
| 59 | + # This option works on interfaces i.e. it affects all sockets |
| 60 | + # bound to the same port. |
| 61 | + add_membership: {{224, 0, 0, 251}, {0, 0, 0, 0}} |
| 62 | + ) |
| 63 | + |
| 64 | + case ret do |
| 65 | + {:ok, socket} -> |
| 66 | + state = Map.merge(state, %{socket: socket, queries: %{}}) |
| 67 | + {:noreply, state} |
| 68 | + |
| 69 | + {:error, reason} -> |
| 70 | + Logger.warning(""" |
| 71 | + Couldn't start MDNS resolver, reason: #{reason}. MDNS candidates won't be resolved. |
| 72 | + """) |
| 73 | + |
| 74 | + {:stop, {:shutdown, reason}, state} |
| 75 | + end |
| 76 | + end |
| 77 | + |
| 78 | + @impl true |
| 79 | + def handle_call({:gethostbyname, addr}, from, state) do |
| 80 | + query = |
| 81 | + %ExICE.DNS.Message{ |
| 82 | + question: [ |
| 83 | + %{ |
| 84 | + qname: addr, |
| 85 | + qtype: :a, |
| 86 | + qclass: :in, |
| 87 | + unicast_response: true |
| 88 | + } |
| 89 | + ] |
| 90 | + } |
| 91 | + |> ExICE.DNS.Message.encode() |
| 92 | + |
| 93 | + case state.transport_module.send(state.socket, @multicast_addr, query) do |
| 94 | + :ok -> |
| 95 | + state = put_in(state, [:queries, addr], from) |
| 96 | + Process.send_after(self(), {:response_timeout, addr}, @response_timeout_ms) |
| 97 | + {:noreply, state} |
| 98 | + |
| 99 | + {:error, reason} -> |
| 100 | + {:reply, {:error, reason}, state} |
| 101 | + end |
| 102 | + end |
| 103 | + |
| 104 | + @impl true |
| 105 | + def handle_info({:udp, _socket, _ip, _port, packet}, state) do |
| 106 | + case ExICE.DNS.Message.decode(packet) do |
| 107 | + # Only accept query response with one resource record. |
| 108 | + # See https://datatracker.ietf.org/doc/html/draft-ietf-mmusic-mdns-ice-candidates#section-3.2.2 |
| 109 | + {:ok, %{qr: true, aa: true, answer: [%{type: :a, class: :in, rdata: <<a, b, c, d>>} = rr]}} -> |
| 110 | + {from, state} = pop_in(state, [:queries, rr.name]) |
| 111 | + |
| 112 | + if from do |
| 113 | + addr = {a, b, c, d} |
| 114 | + GenServer.reply(from, {:ok, addr}) |
| 115 | + end |
| 116 | + |
| 117 | + {:noreply, state} |
| 118 | + |
| 119 | + _other -> |
| 120 | + {:noreply, state} |
| 121 | + end |
| 122 | + end |
| 123 | + |
| 124 | + @impl true |
| 125 | + def handle_info({:response_timeout, addr}, state) do |
| 126 | + case pop_in(state, [:queries, addr]) do |
| 127 | + {nil, state} -> |
| 128 | + {:noreply, state} |
| 129 | + |
| 130 | + {from, state} -> |
| 131 | + GenServer.reply(from, {:error, :timeout}) |
| 132 | + {:noreply, state} |
| 133 | + end |
| 134 | + end |
| 135 | +end |
0 commit comments