build.gradle

plugins {
    id 'groovy'
    id 'jacoco'
    id 'com.github.kt3k.coveralls' version '2.12.2'
    id 'com.diffplug.spotless' version '6.18.0'
}

repositories {
    mavenCentral()
}

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

dependencies {
    def groovyVersion = '3.0.9'

    implementation group: 'org.codehaus.groovy', name: 'groovy-cli-commons', version: groovyVersion

    testImplementation group: 'org.spockframework', name: 'spock-core', version: '2.3-groovy-3.0'
    testImplementation group: 'cglib', name: 'cglib-nodep', version: '3.3.0'
    testImplementation group: 'org.objenesis', name: 'objenesis', version: '3.1'
}

sourceSets {
    main {
        groovy {
            srcDirs = ['.']
            exclude([
                '**/test/**',
                'gradle/**',
                'build/**',
                'docker/**',
                'bin/**',
                'git-sync-test/**'
            ])
        }
    }
}

compileGroovy {
    groovyOptions.configurationScript = file('gradle/config.groovy')
}

test {
    useJUnitPlatform()
    
    systemProperty 'skip.pull', System.properties['skip.pull']
}

ext.jacoco = [
    exclusions: [
        'SyncGitRepos$_run_closure*'
    ],
    coverageThresholds: [
        'SyncGitRepos': [
            'BRANCH': 0.42,
            'COMPLEXITY': 0.33,
            'INSTRUCTION': 0.61,
            'LINE': 0.71
        ]
    ]
]
apply from: 'https://raw.githubusercontent.com/devatherock/gradle-includes/master/checks.gradle'