-
Notifications
You must be signed in to change notification settings - Fork 18
/
Copy pathdlascl_dev.f90
383 lines (381 loc) · 10.3 KB
/
dlascl_dev.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
!> \brief \b DLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
!
! =========== DOCUMENTATION ===========
!
! Online html documentation available at
! http://www.netlib.org/lapack/explore-html/
!
!> \htmlonly
!> Download DLASCL + dependencies
!> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlascl.f">
!> [TGZ]</a>
!> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlascl.f">
!> [ZIP]</a>
!> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlascl.f">
!> [TXT]</a>
!> \endhtmlonly
!
! Definition:
! ===========
!
! SUBROUTINE DLASCL( TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO )
!
! .. Scalar Arguments ..
! CHARACTER TYPE
! INTEGER INFO, KL, KU, LDA, M, N
! DOUBLE PRECISION CFROM, CTO
! ..
! .. Array Arguments ..
! DOUBLE PRECISION A( LDA, * )
! ..
!
!
!> \par Purpose:
! =============
!>
!> \verbatim
!>
!> DLASCL multiplies the M by N real matrix A by the real scalar
!> CTO/CFROM. This is done without over/underflow as long as the final
!> result CTO*A(I,J)/CFROM does not over/underflow. TYPE specifies that
!> A may be full, upper triangular, lower triangular, upper Hessenberg,
!> or banded.
!> \endverbatim
!
! Arguments:
! ==========
!
!> \param[in] TYPE
!> \verbatim
!> TYPE is CHARACTER*1
!> TYPE indices the storage type of the input matrix.
!> = 'G': A is a full matrix.
!> = 'L': A is a lower triangular matrix.
!> = 'U': A is an upper triangular matrix.
!> = 'H': A is an upper Hessenberg matrix.
!> = 'B': A is a symmetric band matrix with lower bandwidth KL
!> and upper bandwidth KU and with the only the lower
!> half stored.
!> = 'Q': A is a symmetric band matrix with lower bandwidth KL
!> and upper bandwidth KU and with the only the upper
!> half stored.
!> = 'Z': A is a band matrix with lower bandwidth KL and upper
!> bandwidth KU. See DGBTRF for storage details.
!> \endverbatim
!>
!> \param[in] KL
!> \verbatim
!> KL is INTEGER
!> The lower bandwidth of A. Referenced only if TYPE = 'B',
!> 'Q' or 'Z'.
!> \endverbatim
!>
!> \param[in] KU
!> \verbatim
!> KU is INTEGER
!> The upper bandwidth of A. Referenced only if TYPE = 'B',
!> 'Q' or 'Z'.
!> \endverbatim
!>
!> \param[in] CFROM
!> \verbatim
!> CFROM is DOUBLE PRECISION
!> \endverbatim
!>
!> \param[in] CTO
!> \verbatim
!> CTO is DOUBLE PRECISION
!>
!> The matrix A is multiplied by CTO/CFROM. A(I,J) is computed
!> without over/underflow if the final result CTO*A(I,J)/CFROM
!> can be represented without over/underflow. CFROM must be
!> nonzero.
!> \endverbatim
!>
!> \param[in] M
!> \verbatim
!> M is INTEGER
!> The number of rows of the matrix A. M >= 0.
!> \endverbatim
!>
!> \param[in] N
!> \verbatim
!> N is INTEGER
!> The number of columns of the matrix A. N >= 0.
!> \endverbatim
!>
!> \param[in,out] A
!> \verbatim
!> A is DOUBLE PRECISION array, dimension (LDA,N)
!> The matrix to be multiplied by CTO/CFROM. See TYPE for the
!> storage type.
!> \endverbatim
!>
!> \param[in] LDA
!> \verbatim
!> LDA is INTEGER
!> The leading dimension of the array A.
!> If TYPE = 'G', 'L', 'U', 'H', LDA >= max(1,M);
!> TYPE = 'B', LDA >= KL+1;
!> TYPE = 'Q', LDA >= KU+1;
!> TYPE = 'Z', LDA >= 2*KL+KU+1.
!> \endverbatim
!>
!> \param[out] INFO
!> \verbatim
!> INFO is INTEGER
!> 0 - successful exit
!> <0 - if INFO = -i, the i-th argument had an illegal value.
!> \endverbatim
!
! Authors:
! ========
!
!> \author Univ. of Tennessee
!> \author Univ. of California Berkeley
!> \author Univ. of Colorado Denver
!> \author NAG Ltd.
!
!> \ingroup OTHERauxiliary
!
! =====================================================================
#if defined(__CUDA)
ATTRIBUTES(DEVICE) SUBROUTINE DLASCL_XG( TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO )
#else
SUBROUTINE DLASCL_XG( TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO )
#endif
#include<disnan_interf.f90>
#include<dlamch_interf.f90>
#include<lsame_interf.f90>
#include<xerbla_interf.f90>
!
! -- LAPACK auxiliary routine --
! -- LAPACK is a software package provided by Univ. of Tennessee, --
! -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
!
! .. Scalar Arguments ..
CHARACTER TYPE
INTEGER INFO, KL, KU, LDA, M, N
DOUBLE PRECISION CFROM, CTO
! ..
! .. Array Arguments ..
DOUBLE PRECISION A( LDA, * )
! ..
!
! =====================================================================
!
! .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
! ..
! .. Local Scalars ..
LOGICAL DONE
INTEGER I, ITYPE, J, K1, K2, K3, K4
DOUBLE PRECISION BIGNUM, CFROM1, CFROMC, CTO1, CTOC, MUL, SMLNUM
! ..
! .. External Functions ..
! LOGICAL LSAME_XG, DISNAN_XG
! DOUBLE PRECISION DLAMCH_XG
! EXTERNAL LSAME_XG, DLAMCH_XG, DISNAN_XG
! ..
! .. Intrinsic Functions ..
INTRINSIC ABS, MAX, MIN
! ..
! .. External Subroutines ..
! EXTERNAL XERBLA_XG
! ..
! .. Executable Statements ..
!
! Test the input arguments
#if defined(__CUDA)
ATTRIBUTES(VALUE) :: TYPE, KL, KU, CFROM, CTO, M, N, LDA
ATTRIBUTES(DEVICE) :: A, INFO
#endif
!
INFO = 0
!
IF( LSAME_XG( TYPE, 'G' ) ) THEN
ITYPE = 0
ELSE IF( LSAME_XG( TYPE, 'L' ) ) THEN
ITYPE = 1
ELSE IF( LSAME_XG( TYPE, 'U' ) ) THEN
ITYPE = 2
ELSE IF( LSAME_XG( TYPE, 'H' ) ) THEN
ITYPE = 3
ELSE IF( LSAME_XG( TYPE, 'B' ) ) THEN
ITYPE = 4
ELSE IF( LSAME_XG( TYPE, 'Q' ) ) THEN
ITYPE = 5
ELSE IF( LSAME_XG( TYPE, 'Z' ) ) THEN
ITYPE = 6
ELSE
ITYPE = -1
END IF
!
IF( ITYPE.EQ.-1 ) THEN
INFO = -1
ELSE IF( CFROM.EQ.ZERO .OR. DISNAN_XG(CFROM) ) THEN
INFO = -4
ELSE IF( DISNAN_XG(CTO) ) THEN
INFO = -5
ELSE IF( M.LT.0 ) THEN
INFO = -6
ELSE IF( N.LT.0 .OR. ( ITYPE.EQ.4 .AND. N.NE.M ) .OR. &
( ITYPE.EQ.5 .AND. N.NE.M ) ) THEN
INFO = -7
ELSE IF( ITYPE.LE.3 .AND. LDA.LT.MAX( 1, M ) ) THEN
INFO = -9
ELSE IF( ITYPE.GE.4 ) THEN
IF( KL.LT.0 .OR. KL.GT.MAX( M-1, 0 ) ) THEN
INFO = -2
ELSE IF( KU.LT.0 .OR. KU.GT.MAX( N-1, 0 ) .OR. &
( ( ITYPE.EQ.4 .OR. ITYPE.EQ.5 ) .AND. KL.NE.KU ) ) &
THEN
INFO = -3
ELSE IF( ( ITYPE.EQ.4 .AND. LDA.LT.KL+1 ) .OR. &
( ITYPE.EQ.5 .AND. LDA.LT.KU+1 ) .OR. &
( ITYPE.EQ.6 .AND. LDA.LT.2*KL+KU+1 ) ) THEN
INFO = -9
END IF
END IF
!
IF( INFO.NE.0 ) THEN
! CALL XERBLA_XG( 'DLASCL', -INFO )
CALL XERBLA_XG( '3', -INFO )
RETURN
END IF
!
! Quick return if possible
!
IF( N.EQ.0 .OR. M.EQ.0 ) &
RETURN
!
! Get machine parameters
!
SMLNUM = DLAMCH_XG( 'S' )
BIGNUM = ONE / SMLNUM
!
CFROMC = CFROM
CTOC = CTO
!
10 CONTINUE
CFROM1 = CFROMC*SMLNUM
IF( CFROM1.EQ.CFROMC ) THEN
! CFROMC is an inf. Multiply by a correctly signed zero for
! finite CTOC, or a NaN if CTOC is infinite.
MUL = CTOC / CFROMC
DONE = .TRUE.
CTO1 = CTOC
ELSE
CTO1 = CTOC / BIGNUM
IF( CTO1.EQ.CTOC ) THEN
! CTOC is either 0 or an inf. In both cases, CTOC itself
! serves as the correct multiplication factor.
MUL = CTOC
DONE = .TRUE.
CFROMC = ONE
ELSE IF( ABS( CFROM1 ).GT.ABS( CTOC ) .AND. CTOC.NE.ZERO ) THEN
MUL = SMLNUM
DONE = .FALSE.
CFROMC = CFROM1
ELSE IF( ABS( CTO1 ).GT.ABS( CFROMC ) ) THEN
MUL = BIGNUM
DONE = .FALSE.
CTOC = CTO1
ELSE
MUL = CTOC / CFROMC
DONE = .TRUE.
IF (MUL .EQ. ONE) &
RETURN
END IF
END IF
!
IF( ITYPE.EQ.0 ) THEN
!
! Full matrix
!
DO 30 J = 1, N
DO 20 I = 1, M
A( I, J ) = A( I, J )*MUL
20 CONTINUE
30 CONTINUE
!
ELSE IF( ITYPE.EQ.1 ) THEN
!
! Lower triangular matrix
!
DO 50 J = 1, N
DO 40 I = J, M
A( I, J ) = A( I, J )*MUL
40 CONTINUE
50 CONTINUE
!
ELSE IF( ITYPE.EQ.2 ) THEN
!
! Upper triangular matrix
!
DO 70 J = 1, N
DO 60 I = 1, MIN( J, M )
A( I, J ) = A( I, J )*MUL
60 CONTINUE
70 CONTINUE
!
ELSE IF( ITYPE.EQ.3 ) THEN
!
! Upper Hessenberg matrix
!
DO 90 J = 1, N
DO 80 I = 1, MIN( J+1, M )
A( I, J ) = A( I, J )*MUL
80 CONTINUE
90 CONTINUE
!
ELSE IF( ITYPE.EQ.4 ) THEN
!
! Lower half of a symmetric band matrix
!
K3 = KL + 1
K4 = N + 1
DO 110 J = 1, N
DO 100 I = 1, MIN( K3, K4-J )
A( I, J ) = A( I, J )*MUL
100 CONTINUE
110 CONTINUE
!
ELSE IF( ITYPE.EQ.5 ) THEN
!
! Upper half of a symmetric band matrix
!
K1 = KU + 2
K3 = KU + 1
DO 130 J = 1, N
DO 120 I = MAX( K1-J, 1 ), K3
A( I, J ) = A( I, J )*MUL
120 CONTINUE
130 CONTINUE
!
ELSE IF( ITYPE.EQ.6 ) THEN
!
! Band matrix
!
K1 = KL + KU + 2
K2 = KL + 1
K3 = 2*KL + KU + 1
K4 = KL + KU + 1 + M
DO 150 J = 1, N
DO 140 I = MAX( K1-J, K2 ), MIN( K3, K4-J )
A( I, J ) = A( I, J )*MUL
140 CONTINUE
150 CONTINUE
!
END IF
!
IF( .NOT.DONE ) &
GO TO 10
!
RETURN
!
! End of DLASCL_XG
!
END
! =====================================================================