-
-
Notifications
You must be signed in to change notification settings - Fork 198
/
Copy pathreloc9.asm
80 lines (64 loc) · 2.28 KB
/
reloc9.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
; a PE using relocation type 9 (different results under XP and W7, unsupported under W8)
; Ange Albertini, BSD LICENCE 2013
%include 'consts.inc'
IMAGEBASE equ 0ffff0000h ; <==
org IMAGEBASE
bits 32
SECTIONALIGN equ 1000h
FILEALIGN equ 200h
istruc IMAGE_DOS_HEADER
at IMAGE_DOS_HEADER.e_magic, db 'MZ'
at IMAGE_DOS_HEADER.e_lfanew, dd NT_Headers - IMAGEBASE
iend
%include "nthd_std.inc"
istruc IMAGE_DATA_DIRECTORY_16
at IMAGE_DATA_DIRECTORY_16.ImportsVA, dd Import_Descriptor - IMAGEBASE
at IMAGE_DATA_DIRECTORY_16.FixupsVA, dd Directory_Entry_Basereloc - IMAGEBASE
at IMAGE_DATA_DIRECTORY_16.FixupsSize, dd DIRECTORY_ENTRY_BASERELOC_SIZE
iend
%include 'section_1fa.inc'
;*******************************************************************************
EntryPoint:
relocbase:
reloc02:
push dword [relocme]
reloc12:
push dword [relocme + 4]
reloc22:
push dword [relocme + 8]
reloc32:
push dword [relocme + 0ch]
reloc41:
push msg
reloc52:
call [__imp__printf]
add esp, 3 * 4
push 0
reloc62:
call [__imp__ExitProcess]
align 16, db 90h
relocme
dq 00000000000000000h
dq 00000000000000000h
msg db " * relocation type 9: %08X%08X%08X%08X", 0ah, 0
_d
%include 'imports_printfexitprocess.inc'
Directory_Entry_Basereloc: ;****************************************************
block_start0:
.VirtualAddress dd relocbase - IMAGEBASE
.SizeOfBlock dd BASE_RELOC_SIZE_OF_BLOCK0
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc02 + 2 - relocbase)
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc12 + 2 - relocbase)
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc22 + 2 - relocbase)
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc32 + 2 - relocbase)
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc41 + 1 - relocbase)
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc52 + 2 - relocbase)
dw (IMAGE_REL_BASED_HIGHLOW << 12) | (reloc62 + 2 - relocbase)
BASE_RELOC_SIZE_OF_BLOCK0 equ $ - block_start0
block_start1:
.VirtualAddress dd relocme - IMAGEBASE
.SizeOfBlock dd BASE_RELOC_SIZE_OF_BLOCK1
dw (IMAGE_REL_BASED_MIPS_JMPADDR16 << 12) | 0
BASE_RELOC_SIZE_OF_BLOCK1 equ $ - block_start1
DIRECTORY_ENTRY_BASERELOC_SIZE equ $ - Directory_Entry_Basereloc
align FILEALIGN, db 0