Add demo showcasing styling the titlebar in your dialogs

Author: code-kungfu

Demos/Using_IDE_TitleBar_Theming/OTAPISDK.Sample.UseIDETitleBarStyling.dpk

@@ -0,0 +1,42 @@
+package OTAPISDK.Sample.UseIDETitleBarStyling;
+
+{$R *.res}
+{$IFDEF IMPLICITBUILDING This IFDEF should not be used by users}
+{$ALIGN 8}
+{$ASSERTIONS ON}
+{$BOOLEVAL OFF}
+{$DEBUGINFO OFF}
+{$EXTENDEDSYNTAX ON}
+{$IMPORTEDDATA ON}
+{$IOCHECKS ON}
+{$LOCALSYMBOLS ON}
+{$LONGSTRINGS ON}
+{$OPENSTRINGS ON}
+{$OPTIMIZATION OFF}
+{$OVERFLOWCHECKS ON}
+{$RANGECHECKS ON}
+{$REFERENCEINFO ON}
+{$SAFEDIVIDE OFF}
+{$STACKFRAMES ON}
+{$TYPEDADDRESS OFF}
+{$VARSTRINGCHECKS ON}
+{$WRITEABLECONST OFF}
+{$MINENUMSIZE 1}
+{$IMAGEBASE $400000}
+{$DEFINE DEBUG}
+{$ENDIF IMPLICITBUILDING}
+{$DESCRIPTION 'OpenToolsAPI SDK Samples - Using IDE Styling'}
+{$LIBSUFFIX AUTO}
+{$IMPLICITBUILD ON}
+
+requires
+  rtl,
+  designide,
+  vcl;
+
+contains
+  OTAPISample.UseThemeBarStyling.Forms.Main in 'src\OTAPISample.UseThemeBarStyling.Forms.Main.pas' {frmMainForm},
+  OTAPISample.UseThemeBarStyling.Expert in 'src\OTAPISample.UseThemeBarStyling.Expert.pas',
+  OTAPISample.UseThemeBarStyling.ThemeNotifier in 'src\OTAPISample.UseThemeBarStyling.ThemeNotifier.pas';
+
+end.

Demos/Using_IDE_TitleBar_Theming/OTAPISDK.Sample.UseIDETitleBarStyling.dproj

@@ -0,0 +1,7 @@
+## Styling your forms according to the current IDE Style
+
+This demo showcases how you can check if the IDE supports styling, register an notify event so you can respond to theme changes and safely handling destruction of the form.
+
+When compiling and installing this package, the demo form will be registered under Help -> Help Wizards.
+
+Written and tested with Delphi 11.3 Alexandria.

Demos/Using_IDE_TitleBar_Theming/README.md

@@ -0,0 +1,72 @@
+unit OTAPISample.UseThemeBarStyling.Expert;
+
+interface
+
+uses
+  ToolsAPI;
+
+type
+  TOTAPISampleStyledFormExpert = class(TNotifierObject, IOTANotifier, IOTAWizard, IOTAMenuWizard)
+  public
+    { IOTAMenuWizard }
+    function GetMenuText: string;
+    { IOTAWizard }
+    procedure Execute;
+    function GetIDString: string;
+    function GetName: string;
+    function GetState: TWizardState;
+    { IOTANotifier }
+    procedure Destroyed;
+  end;
+
+  procedure Register;
+
+implementation
+
+uses
+  OTAPISample.UseThemeBarStyling.Forms.Main;
+
+procedure Register;
+begin
+  RegisterPackageWizard(TOTAPISampleStyledFormExpert.Create as IOTAMenuWizard);
+end;
+
+{ TOTAPISampleStyledFormExpert }
+
+procedure TOTAPISampleStyledFormExpert.Destroyed;
+begin
+  TfrmMainForm.DestroyForm;
+end;
+
+procedure TOTAPISampleStyledFormExpert.Execute;
+begin
+  TfrmMainForm.CreateSampleStyledForm;
+end;
+
+function TOTAPISampleStyledFormExpert.GetIDString: string;
+begin
+  Result := 'OTAPISamples.StyledFormThemeBarExpert';
+end;
+
+function TOTAPISampleStyledFormExpert.GetMenuText: string;
+begin
+  Result := 'OTAPI Sample - Show Styled ThemeBar Form';
+end;
+
+function TOTAPISampleStyledFormExpert.GetName: string;
+begin
+  Result := 'OTAPI Samples - Show Styled ThemeBar Form';
+end;
+
+function TOTAPISampleStyledFormExpert.GetState: TWizardState;
+begin
+  Result := [wsEnabled];
+end;
+
+initialization
+  // Do nothing
+
+finalization
+  TfrmMainForm.DestroyForm;
+
+end.

Demos/Using_IDE_TitleBar_Theming/assets/Example1.png

@@ -0,0 +1,65 @@
+object frmMainForm: TfrmMainForm
+  Left = 0
+  Top = 0
+  Caption = 'OpenToolsAPI Samples - Use IDE Styling'
+  ClientHeight = 442
+  ClientWidth = 532
+  Color = clBtnFace
+  Font.Charset = DEFAULT_CHARSET
+  Font.Color = clWindowText
+  Font.Height = -12
+  Font.Name = 'Segoe UI'
+  Font.Style = []
+  Position = poScreenCenter
+  OnCreate = FormCreate
+  TextHeight = 15
+  object CheckBox1: TCheckBox
+    Left = 88
+    Top = 84
+    Width = 97
+    Height = 17
+    Caption = 'CheckBox1'
+    TabOrder = 0
+  end
+  object Button1: TButton
+    Left = 276
+    Top = 112
+    Width = 75
+    Height = 25
+    Caption = 'Button1'
+    TabOrder = 1
+  end
+  object Panel1: TPanel
+    Left = 60
+    Top = 176
+    Width = 405
+    Height = 85
+    Caption = 'Panel1'
+    TabOrder = 2
+    object RadioButton1: TRadioButton
+      Left = 56
+      Top = 28
+      Width = 113
+      Height = 17
+      Caption = 'RadioButton1'
+      TabOrder = 0
+    end
+  end
+  object Edit1: TEdit
+    Left = 72
+    Top = 284
+    Width = 221
+    Height = 23
+    TabOrder = 3
+    Text = 'Edit1'
+  end
+  object btnClose: TButton
+    Left = 8
+    Top = 8
+    Width = 75
+    Height = 25
+    Caption = 'Close'
+    TabOrder = 4
+    OnClick = btnCloseClick
+  end
+end

Demos/Using_IDE_TitleBar_Theming/src/OTAPISample.UseThemeBarStyling.Expert.pas

@@ -0,0 +1,123 @@
+unit OTAPISample.UseThemeBarStyling.Forms.Main;
+
+interface
+
+uses
+  Winapi.Windows,
+  Winapi.Messages,
+  System.SysUtils,
+  System.Variants,
+  System.Classes,
+  Vcl.Graphics,
+  Vcl.Controls,
+  Vcl.Forms,
+  Vcl.Dialogs,
+  Vcl.StdCtrls,
+  Vcl.ExtCtrls;
+
+type
+  TfrmMainForm = class(TForm)
+    CheckBox1: TCheckBox;
+    Button1: TButton;
+    Panel1: TPanel;
+    RadioButton1: TRadioButton;
+    Edit1: TEdit;
+    btnClose: TButton;
+    procedure FormCreate(Sender: TObject);
+    procedure btnCloseClick(Sender: TObject);
+  private
+    FStyleServicesNotifierID: Integer;
+    class var FCreationID: Integer;
+    procedure UpdateFormTheme(Sender: TObject);
+  public
+    class procedure CreateSampleStyledForm;
+    class procedure DestroyForm;
+    destructor Destroy; override;
+  end;
+
+var
+  frmMainForm: TfrmMainForm;
+
+implementation
+
+{$R *.dfm}
+
+uses
+  OTAPISample.UseThemeBarStyling.ThemeNotifier,
+  IDETheme.Utils,
+  ToolsAPI;
+
+{ TfrmMainForm }
+
+class procedure TfrmMainForm.CreateSampleStyledForm;
+begin
+  if not Assigned(frmMainForm) then
+    frmMainForm := TfrmMainForm.Create(Application.MainForm)
+  else
+    frmMainForm.UpdateFormTheme(nil);
+
+  //FCreationID := frmMainForm.ShowModal;
+  frmMainForm.Show;
+end;
+
+destructor TfrmMainForm.Destroy;
+var
+  LThemingServices: IOTAIDEThemingServices;
+begin
+  if (FStyleServicesNotifierID <> -1) and (Supports(BorlandIDEServices, IOTAIDEThemingServices, LThemingServices)) then
+    LThemingServices.RemoveNotifier(FStyleServicesNotifierID);
+
+  inherited;
+end;
+
+class procedure TfrmMainForm.DestroyForm;
+begin
+  if Assigned(frmMainForm) then
+    FreeAndNil(frmMainForm);
+end;
+
+procedure TfrmMainForm.btnCloseClick(Sender: TObject);
+begin
+  //Self.ModalResult := mrOK;
+  Self.Close;
+end;
+
+procedure TfrmMainForm.FormCreate(Sender: TObject);
+var
+  LThemingServices: IOTAIDEThemingServices;
+begin
+
+  FStyleServicesNotifierID := -1;
+  if Supports(BorlandIDEServices, IOTAIDEThemingServices, LThemingServices) then
+  begin
+    if LThemingServices.IDEThemingEnabled then
+    begin
+      FStyleServicesNotifierID := LThemingServices.AddNotifier(TThemingServicesNotifier.Create(UpdateFormTheme));
+      Self.UpdateFormTheme(nil);
+    end;
+    TIDETitleBarService.AddTitleBar(Self, nil, True);
+  end;
+end;
+
+procedure TfrmMainForm.UpdateFormTheme(Sender: TObject);
+var
+  LThemingServices: IOTAIDEThemingServices;
+begin
+  if Supports(BorlandIDEServices, IOTAIDEThemingServices250, LThemingServices) then
+  begin
+    if LThemingServices.IDEThemingEnabled then
+    begin
+      LThemingServices.RegisterFormClass(TfrmMainForm);
+      LThemingServices.ApplyTheme(Self);
+    end;
+  end;
+end;
+
+initialization
+  // Do nothing here
+
+finalization
+  if Assigned(frmMainForm) then
+    FreeAndNil(frmMainForm);
+
+end.

Demos/Using_IDE_TitleBar_Theming/src/OTAPISample.UseThemeBarStyling.Forms.Main.dfm

@@ -0,0 +1,67 @@
+unit OTAPISample.UseThemeBarStyling.ThemeNotifier;
+
+interface
+
+uses
+  System.Classes,
+  ToolsAPI;
+
+type
+  TThemingServicesNotifier = class(TInterfacedObject, IOTANotifier, INTAIDEThemingServicesNotifier)
+  private
+    FNotifyEvent: TNotifyEvent;
+  public
+    { IOTANotifier }
+    procedure AfterSave;
+    procedure BeforeSave;
+    procedure Destroyed;
+    procedure Modified;
+    { INTAIDEThemingServicesNotifier }
+    procedure ChangedTheme;
+    procedure ChangingTheme;
+    { TThemingServicesNotifier }
+    constructor Create(const ANotifyProc: TNotifyEvent);
+  end;
+
+implementation
+
+{ TThemingServicesNotifier }
+
+procedure TThemingServicesNotifier.AfterSave;
+begin
+  // Do Nothing
+end;
+
+procedure TThemingServicesNotifier.BeforeSave;
+begin
+  // Do Nothing
+end;
+
+procedure TThemingServicesNotifier.ChangedTheme;
+begin
+  if @FNotifyEvent <> nil then
+    FNotifyEvent(nil);
+end;
+
+procedure TThemingServicesNotifier.ChangingTheme;
+begin
+  // Do Nothing
+end;
+
+constructor TThemingServicesNotifier.Create(const ANotifyProc: TNotifyEvent);
+begin
+  if (not Assigned(FNotifyEvent)) and (Assigned(ANotifyProc)) then
+    FNotifyEvent := ANotifyProc;
+end;
+
+procedure TThemingServicesNotifier.Destroyed;
+begin
+  // Do Nothing
+end;
+
+procedure TThemingServicesNotifier.Modified;
+begin
+  // Do Nothing
+end;
+
+end.