[project] setup for initial stage

lispyclouds · lispyclouds · commit bee38d6bcb9e · 2023-02-19T08:29:00.000Z
diff --git a/.github/workflows/ci.yml b/.github/workflows/ci.yml
@@ -0,0 +1,37 @@
+name: Tests
+
+on:
+  push:
+    paths-ignore:
+      - "**.md"
+
+jobs:
+  build:
+    runs-on: "ubuntu-latest"
+
+    steps:
+      - name: "Checkout code"
+        uses: "actions/checkout@v3"
+
+      - name: "Setup Java"
+        uses: "actions/setup-java@v3"
+        with:
+          distribution: "temurin"
+          java-version: "19"
+
+      - name: "Setup Clojure"
+        uses: "DeLaGuardo/setup-clojure@master"
+        with:
+          cli: "latest"
+
+      - name: "Apply Cache"
+        uses: "actions/cache@v3"
+        with:
+          path: |
+            ~/.m2/repository
+            ~/.gitlibs
+          key: "todos-${{ hashFiles('deps.edn') }}"
+          restore-keys: "$todos-"
+
+      - name: "Run tests"
+        run: "make test"
diff --git a/.gitignore b/.gitignore
@@ -1,2 +1,8 @@
-.clj-kondo/
-.lsp/
+.cache
+.clj-kondo
+.cpcache
+.lsp
+.nrepl-port
+todos.sqlite
+target/
+*.jar
diff --git a/Dockerfile b/Dockerfile
@@ -0,0 +1,7 @@
+FROM docker.io/eclipse-temurin:19-jre
+
+WORKDIR /opt
+
+COPY todos.jar .
+
+ENTRYPOINT ["java", "-jar", "todos.jar"]
diff --git a/Makefile b/Makefile
@@ -0,0 +1,13 @@
+.PHONY: test
+
+test:
+	clojure -X:test
+
+start:
+	clojure -M -m todos.main
+
+uberjar:
+	clojure -T:build uber
+
+image: uberjar
+	podman build -t docker.io/workshop/todo .
diff --git a/README.md b/README.md
@@ -1,23 +1,31 @@
 # Babashka Workshop
 
+A simple TODO app backed by SQLite3 and a CLI intended for the workshop demonstrating the various features and aspects of Babashka.
+
 ## System Requirements
 
-- [Babashka][babashka]
+Latest versions recommended for the following
+
+- [Babashka][babashka].
+- Clojure [CLI][cli]
+- JDK 11+.
+- Docker or Podman.
+- [Gum][gum].
 
 To verify things are set up properly, you can run this:
 ```
 bb --version
 
-babashka v<version-installed>
+clojure --version
 ```
 
 ## Run
 
-```
-git clone https://github.com/clojurestream/babashka-workshop
+### Server
 
-cd babashka-workshop/exercies/00-run
-```
+- Run tests: `make test`.
+- Start app locally: `make start`. Set the env vars `TODOS_HOST` and `TODOS_PORT` to customise.
+- Build container image: `make image`.
 
 ## Workshop Feedback
 
@@ -26,3 +34,5 @@ At the end of the workshop, please [provide short feedback][feedback-form].
 
 [babashka]: https://github.com/babashka/babashka#installation
 [feedback-form]: https://forms.gle/iZ8YMfftWdu3MsSPA
+[gum]: https://github.com/charmbracelet/gum#installation
+[cli]: https://clojure.org/guides/install_clojure
diff --git a/build.clj b/build.clj
@@ -0,0 +1,32 @@
+(ns build
+  (:require [clojure.tools.build.api :as b]))
+
+(def uber-file "todos.jar")
+
+(defn clean
+  [_]
+  (b/delete {:path "target"})
+  (b/delete {:path uber-file}))
+
+(defn uber
+  [_]
+  (let [basis     (b/create-basis {:project "deps.edn"})
+        class-dir "target/classes"
+        src-dirs  ["src"]]
+    (clean nil)
+    (b/write-pom {:class-dir class-dir
+                  :lib       'workshop/todos
+                  :version   "1.0.0"
+                  :basis     basis
+                  :src-dirs  src-dirs})
+    (b/copy-dir {:src-dirs   src-dirs
+                 :target-dir class-dir})
+    (b/compile-clj {:basis        basis
+                    :src-dirs     src-dirs
+                    :class-dir    class-dir
+                    :ns-compile   '[todos.main]
+                    :compile-opts {:direct-linking true}})
+    (b/uber {:class-dir class-dir
+             :uber-file uber-file
+             :basis     basis
+             :main      'todos.main})))
diff --git a/deps.edn b/deps.edn
@@ -0,0 +1,12 @@
+{:paths ["src"]
+ :deps {org.clojars.askonomm/ruuter {:mvn/version "1.3.2"}
+        com.github.seancorfield/next.jdbc {:mvn/version "1.2.659"}
+        org.xerial/sqlite-jdbc {:mvn/version "3.40.1.0"}
+        cheshire/cheshire {:mvn/version "5.11.0"}
+        http-kit/http-kit {:mvn/version "2.6.0"}}
+ :aliases {:test {:extra-paths ["test" "fetch_api"]
+                  :extra-deps {io.github.cognitect-labs/test-runner {:git/tag "v0.5.1" :git/sha "dfb30dd"}}
+                  :main-opts ["-m" "cognitect.test-runner"]
+                  :exec-fn cognitect.test-runner.api/test}
+           :build {:deps {io.github.clojure/tools.build {:git/tag "v0.9.3" :git/sha "e537cd1"}}
+                   :ns-default build}}}
diff --git a/exercises/00-run/README.md b/exercises/00-run/README.md
diff --git a/exercises/00-run/script.clj b/exercises/00-run/script.clj
diff --git a/src/todos/handlers.clj b/src/todos/handlers.clj
@@ -0,0 +1,36 @@
+(ns todos.handlers
+  (:require
+   [cheshire.core :as json]
+   [clojure.java.io :as io]
+   [next.jdbc :as jdbc]
+   [next.jdbc.result-set :as rs]))
+
+(defn respond
+  ([msg]
+   (respond msg 200))
+  ([msg status]
+   {:status status
+    :headers {"Content-Type" "application/json"}
+    :body (json/generate-string {:message msg})}))
+
+(defn hello
+  [_]
+  (respond "Hello!"))
+
+(defn ls
+  [{db :db}]
+  (let [todos (jdbc/execute! db ["SELECT * FROM todos"] {:builder-fn rs/as-unqualified-lower-maps})]
+    (respond todos)))
+
+(defn todo
+  [{:keys [db body]}]
+  (let [{:keys [title due]} (json/parse-stream (io/reader body) true)
+        id (random-uuid)]
+    (jdbc/execute-one! db ["INSERT INTO todos (id, title, due) VALUES (?, ?, ?)" id title due])
+    (respond {:id id})))
+
+(defn done
+  [{db :db
+    {:keys [id]} :params}]
+  (jdbc/execute-one! db ["DELETE FROM todos WHERE id = ?" id])
+  (respond "Ok"))
diff --git a/src/todos/main.clj b/src/todos/main.clj
@@ -0,0 +1,49 @@
+(ns todos.main
+  (:require
+   [next.jdbc :as jdbc]
+   [org.httpkit.server :as http]
+   [ruuter.core :as ruuter]
+   [todos.handlers :as handlers])
+  (:gen-class))
+
+(def db {:dbtype "sqlite" :dbname "todos.sqlite"})
+
+(def routes
+  [{:path "/"
+    :method :get
+    :response #(handlers/hello %)}
+   {:path "/todos"
+    :method :get
+    :response #(handlers/ls (assoc % :db db))}
+   {:path "/todos"
+    :method :post
+    :response #(handlers/todo (assoc % :db db))}
+   {:path "/todos/:id"
+    :method :delete
+    :response #(handlers/done (assoc % :db db))}])
+
+(defn migrate
+  [db]
+  (jdbc/execute! db ["CREATE TABLE IF NOT EXISTS todos (id TEXT PRIMARY KEY, title TEXT, due TEXT)"]))
+
+(defn -main
+  [& _]
+  (migrate db)
+  (let [port (parse-long (or (System/getenv "TODOS_PORT") "8080"))
+        host (or (System/getenv "TODOS_HOST") "0.0.0.0")]
+    (http/run-server #(ruuter/route routes %)
+                     {:port port
+                      :host host
+                      :legacy-return-value? false})
+    (println (format "Listening on %s:%d" host port))
+    @(promise)))
+
+(comment
+  (migrate db)
+
+  (do
+    @(http/server-stop! server)
+    (def server
+      (http/run-server #(ruuter/route routes %)
+                       {:port 8080
+                        :legacy-return-value? false}))))
diff --git a/test/payload.json b/test/payload.json
@@ -0,0 +1,4 @@
+{
+  "title": "run the bb workshop",
+  "due": "2023-03-11 13:00:00.000"
+}
diff --git a/test/todos/handlers_test.clj b/test/todos/handlers_test.clj
@@ -0,0 +1,49 @@
+(ns todos.handlers-test
+  (:require
+   [cheshire.core :as json]
+   [clojure.java.io :as io]
+   [clojure.test :refer [deftest is testing]]
+   [todos.handlers :as h]
+   [todos.main :as main]))
+
+(deftest response-test
+  (testing "default response"
+    (is (= {:status 200
+            :headers {"Content-Type" "application/json"}
+            :body "{\"message\":\"Ok\"}"}
+           (h/respond "Ok"))))
+  (testing "custom response"
+    (is (= {:status 202
+            :headers {"Content-Type" "application/json"}
+            :body "{\"message\":\"Could be Ok\"}"}
+           (h/respond "Could be Ok" 202)))))
+
+(deftest handlers-test
+  (testing "hello-handler"
+    (is (= {:status 200
+            :headers {"Content-Type" "application/json"}
+            :body "{\"message\":\"Hello!\"}"}
+           (h/hello {}))))
+  (testing "todo-handler"
+    (let [db-file "todos-test.sqlite"
+          db {:dbtype "sqlite" :dbname db-file}
+          _ (main/migrate db)
+          {:keys [status body]} (h/todo {:db db
+                                         :body (io/input-stream "test/payload.json")})]
+      (is (= 200 status))
+      (is (contains? (:message (json/parse-string body true)) :id))
+      (io/delete-file db-file)))
+  (testing "done-handler"
+    (let [db-file "todos-test.sqlite"
+          db {:dbtype "sqlite" :dbname db-file}
+          _ (main/migrate db)
+          {:keys [body]} (h/todo {:db db
+                                  :body (io/input-stream "test/payload.json")})
+          {:keys [status body]} (h/done {:db db
+                                         :params {:id (-> body
+                                                          (json/parse-string true)
+                                                          :message
+                                                          :id)}})]
+      (is (= 200 status))
+      (is (= "Ok" (:message (json/parse-string body true))))
+      (io/delete-file db-file))))
