-
Notifications
You must be signed in to change notification settings - Fork 6
/
documentation.gradle.kts
103 lines (87 loc) · 2.56 KB
/
documentation.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
import org.gradle.util.GradleVersion
plugins {
`java-library-conventions`
alias(libs.plugins.spotless)
alias(libs.plugins.asciidoctorJvmConvert)
alias(libs.plugins.gitPublish)
}
description = "CXF Codegen documentation"
val snapshot = rootProject.version.toString().contains("SNAPSHOT")
val docsVersion = if (snapshot) "snapshot" else rootProject.version.toString()
val docsDir = layout.buildDirectory.dir("ghpages-docs")
val replaceCurrentDocs = project.hasProperty("replaceCurrentDocs")
gitPublish {
repoUri.set("https://github.com/ciscoo/cxf-codegen-gradle.git")
branch.set("gh-pages")
contents {
from(docsDir)
into("docs")
}
preserve {
include("**/*")
exclude("docs/$docsVersion/**")
if (replaceCurrentDocs) {
exclude("docs/current/**")
}
}
}
val pluginApiDocsClasspath by configurations.registering {
isCanBeConsumed = false
isCanBeResolved = true
}
dependencies {
"pluginApiDocsClasspath"(
project(
mapOf(
"path" to ":cxf-codegen-gradle",
"configuration" to "apiDocs",
),
),
)
}
tasks {
listOf(jar, javadocJar, sourcesJar).forEach { it { enabled = false } }
val copyPluginApiDocs by registering(Copy::class) {
from(pluginApiDocsClasspath) {
exclude("**/*.jar")
}
into(layout.buildDirectory.dir("plugin-api-docs"))
}
asciidoctor {
baseDirFollowsSourceDir()
setOutputDir(layout.buildDirectory.dir("user-guide"))
attributes(
mapOf(
"revnumber" to version,
"current-gradle-version" to GradleVersion.current().version,
"plugin-version" to version,
"outdir" to outputDir.absolutePath,
"cxf-version" to libs.versions.cxf.get(),
),
)
}
val prepareDocsForGitHubPages by registering(Copy::class) {
from(copyPluginApiDocs) {
into("api")
}
from(asciidoctor) {
into("user-guide")
}
into(docsDir.map { it.dir(docsVersion) })
includeEmptyDirs = false
}
val createCurrentDocsFolder by registering(Copy::class) {
from(prepareDocsForGitHubPages)
into(docsDir.map { it.dir("current") })
onlyIf { replaceCurrentDocs }
}
build {
dependsOn(createCurrentDocsFolder)
}
gitPublishCopy {
dependsOn(createCurrentDocsFolder)
}
gitPublishCommit {
dependsOn(createCurrentDocsFolder)
}
}