cics-java-liberty-springboot-link/build.gradle at main · cicsdev/cics-java-liberty-springboot-link · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
plugins
{
	id 'org.springframework.boot' version '3.5.13'
	id 'io.spring.dependency-management' version '1.0.11.RELEASE'
	id 'java'
	id 'eclipse'
	id 'idea'
	id 'war'
}

group = 'com.ibm.cicsdev.springboot'
archivesBaseName='cics-java-liberty-springboot-link'
version = '0.1.0'

// ============================================================================
// Java Configuration
// ============================================================================
java {
    sourceCompatibility = JavaVersion.toVersion(java_version)
    targetCompatibility = JavaVersion.toVersion(java_version)
}

// If in Eclipse, add Javadoc to the local project classpath
eclipse
{
    classpath
    {
        downloadJavadoc = true
    }
}

repositories
{
    mavenCentral()
}

dependencies
{
    // Spring Boot web starter dependency
    implementation("org.springframework.boot:spring-boot-starter-web")

    // Validation anotation support, for validating Web input forms
    implementation("jakarta.validation:jakarta.validation-api");

    // Spring Boot thymeleaf view dependency
    implementation("org.springframework.boot:spring-boot-starter-thymeleaf")

    // Don't include TomCat in the runtime build, but put it in lib-provided so it can run standalone as well as embedded
    providedRuntime("org.springframework.boot:spring-boot-starter-tomcat")

	// CICS TS V6.1 Maven BOM (as of Sept 2024)
	   def bom = "com.ibm.cics:com.ibm.cics.ts.bom:6.1-20250812133513-PH63856"

    compileOnly enforcedPlatform(bom)
    annotationProcessor enforcedPlatform(bom)

    annotationProcessor("com.ibm.cics:com.ibm.cics.server.invocation")

    // Don't include JCICS components in the final build (no need for version because we have BOM)
    compileOnly("com.ibm.cics:com.ibm.cics.server")
    compileOnly("com.ibm.cics:com.ibm.cics.server.invocation.annotations")

    //Add tiles-el dependency if using JSF, see READ for more details
    implementation ("org.apache.tiles:tiles-el:3.0.8")
}