build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.1.0'
    id 'org.beryx.jlink' version '2.25.0'
    id "org.gradlex.extra-java-module-info" version "1.2"
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

group 'dipole.rf.calculator'
version '1.0'

repositories {
    mavenCentral()
}

ext {
    junitVersion = '5.5.1'
}


tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}


application {
    mainModule = 'dipole.rf.calculator'
    mainClass = 'dipole.rf.calculator.CalculatorApplication'
}

javafx {
    version = '22'
    modules = ['javafx.controls', 'javafx.fxml']
}

extraJavaModuleInfo {
    automaticModule( "org.osgi.core-6.0.0.jar", "org.osgi.core")
}


dependencies {
    implementation 'org.apache.commons:commons-numbers-complex:1.1'
    testImplementation 'org.testfx:testfx-junit5:4.0.18'
    testImplementation 'org.assertj:assertj-core:3.13.2'
    testImplementation 'org.hamcrest:hamcrest:2.1'
    testImplementation("org.junit.jupiter:junit-jupiter-api:${junitVersion}")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:${junitVersion}")
}


test {
    useJUnitPlatform()
}

jlink {
    imageZip = project.file("${buildDir}/distributions/app-${javafx.platform.classifier}.zip")
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    launcher {
        name = 'app'
    }
}

jlinkZip {
    group = 'distribution'
}