Use the launcher_maker toolchain if available

This avoids an unnecessary dependency on a C++ toolchain matching the target platform when not building for Windows.

Author: fmeum

.bazelci/presubmit.yml

@@ -60,7 +60,7 @@ tasks:
     build_targets: *build_targets
     test_targets: *test_targets
     test_flags:
-      - "--test_tag_filters=-min_bazel_8"
+      - "--test_tag_filters=-min_bazel_8,-min_bazel_9"
 # Bazel 8+
   build_and_test:
     name: "Bazel {modern_bazel}"
@@ -76,7 +76,7 @@ tasks:
     build_targets: *build_targets_bazel6
     test_targets: *test_targets_bazel6
     test_flags:
-      - "--test_tag_filters=-min_bazel_7,-min_bazel_8"
+      - "--test_tag_filters=-min_bazel_7,-min_bazel_8,-min_bazel_9"
   ubuntu2004_integration_bazel6:
     name: "Integration w/ Bazel 6.5.0"
     bazel: 6.5.0

MODULE.bazel

@@ -7,13 +7,7 @@ module(
 
 bazel_dep(name = "platforms", version = "0.0.11")
 bazel_dep(name = "rules_cc", version = "0.0.15")
-bazel_dep(name = "bazel_features", version = "1.28.0")
-archive_override(
-    module_name = "bazel_features",
-    integrity = "sha256-SOPLvKDy+RN7GHKN8eFjQ+58Wx4Isj+vcXoUluBqxLo=",
-    strip_prefix = "bazel_features-59915eb2ca215c7b2266c83c49bb7522a5b6737f",
-    urls = ["https://github.com/bazel-contrib/bazel_features/archive/59915eb2ca215c7b2266c83c49bb7522a5b6737f.zip"],
-)
+bazel_dep(name = "bazel_features", version = "1.30.0")
 
 bazel_dep(name = "bazel_skylib", version = "1.6.1")
 bazel_dep(name = "protobuf", version = "27.0", repo_name = "com_google_protobuf")

java/bazel/rules/bazel_java_binary.bzl

@@ -13,6 +13,7 @@
 # limitations under the License.
 """Bazel java_binary rule"""
 
+load("@bazel_features//:features.bzl", "bazel_features")
 load("@bazel_skylib//lib:paths.bzl", "paths")
 load("@rules_cc//cc:find_cc_toolchain.bzl", "use_cc_toolchain")
 load("//java/common:java_semantics.bzl", "semantics")
@@ -202,6 +203,14 @@ def _get_executable(ctx):
 
     return ctx.actions.declare_file(executable_name)
 
+_LAUNCHER_MAKER_TOOLCHAIN_TYPE = "@bazel_tools//tools/launcher:launcher_maker_toolchain_type"
+_LAUNCHER_MAKER_TOOLCHAIN = config_common.toolchain_type(_LAUNCHER_MAKER_TOOLCHAIN_TYPE, mandatory = True)
+
+def _find_launcher_maker(ctx):
+    if bazel_features.rules._has_launcher_maker_toolchain:
+        return ctx.toolchains[_LAUNCHER_MAKER_TOOLCHAIN_TYPE].binary
+    return ctx.attr._windows_launcher_maker
+
 def _create_stub(ctx, java_attrs, launcher, executable, jvm_flags, main_class, coverage_main_class):
     java_runtime_toolchain = semantics.find_java_runtime_toolchain(ctx)
     java_executable = helper.get_java_executable(ctx, java_runtime_toolchain, launcher)
@@ -282,7 +291,7 @@ def _create_windows_exe_launcher(ctx, java_executable, classpath, main_class, jv
     # TODO(b/295221112): Change to use the "launcher" attribute (only windows use a fixed _launcher attribute)
     launcher_artifact = ctx.executable._launcher
     ctx.actions.run(
-        executable = ctx.executable._windows_launcher_maker,
+        executable = _find_launcher_maker(ctx),
         inputs = [launcher_artifact],
         outputs = [executable],
         arguments = [launcher_artifact.path, launch_info, executable.path],
@@ -308,6 +317,8 @@ def make_binary_rule(implementation, *, doc, attrs, executable = False, test = F
         provides = [JavaInfo],
         toolchains = [semantics.JAVA_TOOLCHAIN] + use_cc_toolchain() + (
             [semantics.JAVA_RUNTIME_TOOLCHAIN] if executable or test else []
+        ) + (
+            [_LAUNCHER_MAKER_TOOLCHAIN] if bazel_features.rules._has_launcher_maker_toolchain else []
         ),
         # TODO(hvd): replace with filegroups?
         outputs = {
@@ -340,16 +351,18 @@ logic as the Java package of source files. For example, a source file at
         ),
         "_test_support": attr.label(default = _compute_test_support),
         "_launcher": attr.label(
-            cfg = "exec",
+            cfg = "target",
             executable = True,
             default = "@bazel_tools//tools/launcher:launcher",
         ),
+    },
+    {
         "_windows_launcher_maker": attr.label(
             default = "@bazel_tools//tools/launcher:launcher_maker",
             cfg = "exec",
             executable = True,
         ),
-    },
+    } if not bazel_features.rules._has_launcher_maker_toolchain else {},
 )
 
 def make_java_binary(executable):

test/java/common/rules/java_binary_tests.bzl

@@ -171,6 +171,45 @@ def _test_java_binary_propagates_direct_native_libraries_impl(env, target):
         matching.str_matches("-Djava.library.path=${JAVA_RUNFILES}/*/test_java_binary_propagates_direct_native_libraries"),
     )
 
+def _test_java_binary_cross_compilation_to_unix(name):
+    # A Unix platform that:
+    # - has a JDK
+    # - does not require a launcher
+    # - is not supported by the default C++ toolchain
+    util.helper_target(
+        native.platform,
+        name = name + "/platform",
+        constraint_values = [
+            "@platforms//os:linux",
+            "@platforms//cpu:s390x",
+        ],
+    )
+
+    util.helper_target(
+        java_binary,
+        name = name + "/bin",
+        srcs = ["java/C.java"],
+        main_class = "C",
+    )
+
+    analysis_test(
+        name = name,
+        impl = _test_java_binary_cross_compilation_to_unix_impl,
+        target = name + "/bin",
+        config_settings = {
+            "//command_line_option:platforms": [Label(name + "/platform")],
+        },
+        # Requires the launcher_maker toolchain.
+        attr_values = {"tags": ["min_bazel_9"]},
+    )
+
+def _test_java_binary_cross_compilation_to_unix_impl(env, target):
+    # The main assertion is that analysis succeeds, but verify the absence of a
+    # binary launcher for good measure.
+    executable = target[DefaultInfo].files_to_run.executable.short_path
+    assert_action = env.expect.that_target(target).action_generating(executable)
+    assert_action.substitutions().keys().contains("%jvm_flags%")
+
 def java_binary_tests(name):
     test_suite(
         name = name,
@@ -179,5 +218,6 @@ def java_binary_tests(name):
             _test_stamp_conversion_does_not_override_int,
             _test_java_binary_attributes,
             _test_java_binary_propagates_direct_native_libraries,
+            _test_java_binary_cross_compilation_to_unix,
         ],
     )