ppc64le build (envoyproxy#4183) - skip luajit (AArch64 too)

Build for Linux on Power (ppc64le). There is no luajit support for ppc64le, so
this PR puts in logic to not add that recipe to the sandbox speedup that
envoy uses for its build.

There were already some differences taken into account for Windows, so
hopefully this isn't too far out there.

Description: Build for Linux on Power (ppc64le).
Risk Level: low
Testing: manual + have built this into istio/proxy for a few releases now
Docs Changes: Would need to add a bit about Power support
Release Notes: same

[Alexandru.Avadanii@enea.com]
- rebase for whitespaces changes;
- extend the same mechanism to also apply to AArch64;

Signed-off-by: Christy Norman <christy@linux.vnet.ibm.com>
Signed-off-by: Alexandru Avadanii <Alexandru.Avadanii@enea.com>

Author: clnperez

bazel/BUILD

@@ -35,6 +35,16 @@ genrule(
     stamp = 1,
 )
 
+config_setting(
+    name = "linux_ppc",
+    values = {"cpu": "ppc"},
+)
+
+config_setting(
+    name = "linux_aarch64",
+    values = {"cpu": "aarch64"},
+)
+
 config_setting(
     name = "opt_build",
     values = {"compilation_mode": "opt"},

bazel/repositories.bzl

@@ -8,6 +8,9 @@ load(":patched_http_archive.bzl", "patched_http_archive")
 load(":repository_locations.bzl", "REPOSITORY_LOCATIONS")
 load(":target_recipes.bzl", "TARGET_RECIPES")
 
+# dict of {build recipe name: longform extension name,}
+PPC_SKIP_TARGETS = {"luajit": "envoy.filters.http.lua"}
+
 def _repository_impl(name, **kwargs):
     # `existing_rule_keys` contains the names of repositories that have already
     # been defined in the Bazel workspace. By skipping repos with existing keys,
@@ -60,13 +63,16 @@ def _repository_impl(name, **kwargs):
                 **kwargs)
 
 def _build_recipe_repository_impl(ctxt):
+    # modify the recipes list based on the build context
+    recipes = _apply_dep_blacklist(ctxt, ctxt.attr.recipes)
+
     # Setup the build directory with links to the relevant files.
     ctxt.symlink(Label("//bazel:repositories.sh"), "repositories.sh")
     ctxt.symlink(Label("//ci/build_container:build_and_install_deps.sh"),
                  "build_and_install_deps.sh")
     ctxt.symlink(Label("//ci/build_container:recipe_wrapper.sh"), "recipe_wrapper.sh")
     ctxt.symlink(Label("//ci/build_container:Makefile"), "Makefile")
-    for r in ctxt.attr.recipes:
+    for r in recipes:
         ctxt.symlink(Label("//ci/build_container/build_recipes:" + r + ".sh"),
                      "build_recipes/" + r + ".sh")
     ctxt.symlink(Label("//ci/prebuilt:BUILD"), "BUILD")
@@ -75,7 +81,7 @@ def _build_recipe_repository_impl(ctxt):
     environment = {}
     print("Fetching external dependencies...")
     result = ctxt.execute(
-        ["./repositories.sh"] + ctxt.attr.recipes,
+        ["./repositories.sh"] + recipes,
         environment = environment,
         quiet = False,
     )
@@ -208,6 +214,7 @@ def envoy_dependencies(path = "@envoy_deps//", skip_targets = []):
         name = "envoy_deps",
         recipes = recipes.to_list(),
     )
+
     for t in TARGET_RECIPES:
         if t not in skip_targets:
             native.bind(
@@ -464,3 +471,19 @@ def _com_github_google_jwt_verify():
       name = "jwt_verify_lib",
       actual = "@com_github_google_jwt_verify//:jwt_verify_lib",
     )
+
+def _apply_dep_blacklist(ctxt, recipes):
+    newlist = []
+    skip_list = dict()
+    if _is_linux_ppc_or_aarch64(ctxt):
+        skip_list = PPC_SKIP_TARGETS
+    for t in recipes:
+        if t not in skip_list.keys():
+            newlist.append(t)
+    return newlist
+
+def _is_linux_ppc_or_aarch64(ctxt):
+    if ctxt.os.name != "linux":
+        return False
+    res = ctxt.execute(["uname", "-m"])
+    return "ppc" in res.stdout or "aarch64" in res.stdout

source/exe/BUILD

@@ -10,6 +10,7 @@ load(
     "//source/extensions:all_extensions.bzl",
     "envoy_all_extensions",
 )
+load("//bazel:repositories.bzl", "PPC_SKIP_TARGETS")
 
 envoy_package()
 
@@ -37,7 +38,11 @@ envoy_cc_library(
         "//source/server:options_lib",
         "//source/server:server_lib",
         "//source/server:test_hooks_lib",
-    ] + envoy_all_extensions(),
+    ] + select({
+        "//bazel:linux_ppc": envoy_all_extensions(PPC_SKIP_TARGETS),
+        "//bazel:linux_aarch64": envoy_all_extensions(PPC_SKIP_TARGETS),
+        "//conditions:default": envoy_all_extensions(),
+    }),
 )
 
 envoy_cc_library(

source/extensions/all_extensions.bzl

@@ -1,16 +1,17 @@
 load("@envoy_build_config//:extensions_build_config.bzl", "EXTENSIONS")
 
 # Return all extensions to be compiled into Envoy.
-def envoy_all_extensions():
-  # These extensions are registered using the extension system but are required for the core
-  # Envoy build.
-  all_extensions = [
-    "//source/extensions/transport_sockets/raw_buffer:config",
-    "//source/extensions/transport_sockets/ssl:config",
-  ]
+def envoy_all_extensions(blacklist = dict()):
+    # These extensions are registered using the extension system but are required for the core
+    # Envoy build.
+    all_extensions = [
+        "//source/extensions/transport_sockets/raw_buffer:config",
+        "//source/extensions/transport_sockets/ssl:config",
+    ]
 
-  # These extensions can be removed on a site specific basis.
-  for path in EXTENSIONS.values():
-    all_extensions.append(path)
+    # These extensions can be removed on a site specific basis.
+    for name, path in EXTENSIONS.items():
+        if not name in blacklist.values():
+            all_extensions.append(path)
 
-  return all_extensions
+    return all_extensions