How would you apply the behind factor property to the Outline in the Selection effect.

[PhillipGenant]

I've been trying to figure out how to apply the behind factor properties effect to the Outline as well as the inner color and I wanted to see if anyone had any insight on how to do that.

[alelievr]

I think you can just multiply the behind factor by the outline value before outputting it to the color buffer: https://github.com/alelievr/HDRP-Custom-Passes/blob/master/Assets/CustomPasses/Selection/Shaders/02_Selection_Fullscreen.shader#LL121

[NathanYYVGProductions]

I've been trying to figure this out too, and simply multiplying the alphaFactor by the outlines alpha (like how it's done with the innerColor:

HDRP-Custom-Passes/Assets/CustomPasses/Selection/Shaders/02_Selection_Fullscreen.shader

Line 119 in 0c66c64

innerColor.a *= alphaFactor;

) doesn't work. It just makes the entire outline transparent if the Behind Factor is at 0. Is there another way this could be done?

[alelievr]

Indeed it's not enough to add that because the alpha factor is 0 when the pixel is not directly above the outlined objects, so to fix that you need to do the same as for the outline color: sample the depth buffer multiple times to find the max depth of the custom object and use that to check if the outline is behind something. I've modified the original selection fullscreen shader to achieve something similar:

    float4 FullScreenPass(Varyings varyings) : SV_Target
    {
        UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(varyings);

        float depth = LoadCameraDepth(varyings.positionCS.xy);
        PositionInputs posInput = GetPositionInput(varyings.positionCS.xy, _ScreenSize.zw, depth, UNITY_MATRIX_I_VP, UNITY_MATRIX_V);
        float3 viewDirection = GetWorldSpaceNormalizeViewDir(posInput.positionWS);
        
		float4 c = LoadCustomColor(posInput.positionSS);
        
        float obj = c.a;
        
        uint offset = 5;
        
        uint sampleCount = min( 2 * pow(2, _SamplePrecision ), MAXSAMPLES ) ;
        
        float4 outline = float4(0,0,0,0);
        float objectDepth = 0;
        
        float2 uvOffsetPerPixel = 1.0/_ScreenSize .xy;
        
        for (uint i=0 ; i<sampleCount ; ++i )
        {
            outline =  max( SampleCustomColor( posInput.positionNDC + uvOffsetPerPixel * _OutlineWidth * offsets[i] ), outline );
            objectDepth =  max( SampleCustomDepth( posInput.positionNDC + uvOffsetPerPixel * _OutlineWidth * offsets[i] ), objectDepth );
        }
        
        float db = LoadCameraDepth(posInput.positionSS);
        
        float alphaFactor = (objectDepth != 0 && db > objectDepth + 0.00001)?_BehindFactor:1;
        
        float4 o = float4(0,0,0,0);
        
        float4 innerColor = SAMPLE_TEXTURE2D( _Texture, s_trilinear_repeat_sampler, posInput.positionSS / _TextureSize) * _InnerColor;
        
        innerColor.a *= alphaFactor;
        outline.a *= alphaFactor;
        
        o = lerp(o, _OuterColor * float4(outline.rgb, 1), outline.a);
        o = lerp( o, innerColor * float4(c.rgb, 1), obj);
        
        return o;
    }

[NathanYYVGProductions]

This is fantastic! I'm still pretty new to shader coding, so I was struggling with this one a lot. Thanks for your help!