build.gradle

import com.airbnb.mvrx.JacocoReportTask
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: 'kotlin-parcelize'
apply plugin: "jacoco"
apply plugin: "com.vanniktech.maven.publish"

tasks.withType(KotlinCompile).all {
    kotlinOptions {
        freeCompilerArgs += [
                '-Xopt-in=com.airbnb.mvrx.InternalMavericksApi',
        ]
    }
}

android {
    resourcePrefix 'mvrx_'

    defaultConfig {
        consumerProguardFiles 'proguard-rules.pro'
    }

    testOptions {
        unitTests {
            includeAndroidResources = true
            all {
                jacoco {
                    includeNoLocationClasses = true
                    jacoco.excludes = ['jdk.internal.*']
                }
            }
        }
    }
}

jacoco {
    toolVersion = "0.8.2"
}

dependencies {
    implementation Libraries.kotlinReflect
    implementation Libraries.appcompat
    api project(':mvrx')

    testImplementation project(':testing')
    testImplementation TestLibraries.mockito
    testImplementation TestLibraries.junit
    testImplementation TestLibraries.roboeletric
    testImplementation TestLibraries.kotlinCoroutinesTest

    // Including autovalue just for the AutoValue type printer test
    testImplementation Libraries.autoValue
    kaptTest AnnotationProcessors.autoValue
}

tasks.register("coverage", JacocoReportTask.class) {
    coverage.dependsOn("testDebugUnitTest")
}