build.gradle

buildscript {
    repositories {
        maven { url "https://repo.spring.io/plugins-release" }
    }
    dependencies {
        classpath("io.spring.gradle:dependency-management-plugin:1.0.10.RELEASE")
    }
}

ext {
    springCloudAppBrokerVersion = project.findProperty("springCloudAppBrokerVersion") ?: "1.1.1.RELEASE"
    springBootVersion = project.findProperty("springBootVersion") ?: "2.2.7.RELEASE"
}

configure(allprojects) {
    group = "org.springframework.cloud"

    apply plugin: "java"
    apply plugin: "idea"
    apply plugin: "io.spring.dependency-management"

    repositories {
        mavenCentral()
        maven { url "https://repo.spring.io/libs-release" }
        maven { url "https://repo.spring.io/libs-snapshot" }
        maven { url "https://repo.spring.io/milestone" }
    }

}

configure(subprojects) {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    [compileJava, compileTestJava]*.options*.encoding = "UTF-8"

    [compileJava, compileTestJava]*.options*.compilerArgs = [
            "-Xlint:serial",
            "-Xlint:varargs",
            "-Xlint:cast",
            "-Xlint:classfile",
            "-Xlint:dep-ann",
            "-Xlint:divzero",
            "-Xlint:empty",
            "-Xlint:finally",
            "-Xlint:overrides",
            "-Xlint:path",
            "-Xlint:-processing",
            "-Xlint:static",
            "-Xlint:try",
            "-Xlint:fallthrough",
            "-Xlint:rawtypes",
            "-Xlint:deprecation",
            "-Xlint:unchecked",
            "-Xlint:-options",
            "-Werror"
    ]

    configurations {
        // exclude JUnit 4 globally, in favor of JUnit 5
        testImplementation.exclude group: "junit", module: "junit"
    }
}