-
Notifications
You must be signed in to change notification settings - Fork 0
/
IrrigationMod_three_techniques_frequency_no_threshold.F90
1833 lines (1591 loc) · 81.9 KB
/
IrrigationMod_three_techniques_frequency_no_threshold.F90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
module IrrigationMod
!-----------------------------------------------------------------------
! !DESCRIPTION:
! Calculates irrigation flux.
!
! Usage:
!
! - Call CalcIrrigationNeeded in order to compute whether and how much irrigation is
! needed for the next call to CalcIrrigationFluxes. This should be called once per
! timestep.
!
! - Call CalcIrrigationFluxes in order to calculate irrigation withdrawal and
! application fluxes. It is acceptable for this to be called earlier in the timestep
! than CalcIrrigationNeeded.
!
! General design notes:
!
! In principle, CalcIrrigationFluxes and CalcIrrigationNeeded could be combined into a
! single routine. Their separation is largely for historical reasons: In the past,
! irrigation depended on btran, and qflx_irrig is needed earlier in the driver loop
! than when btran becomes available. (And qflx_irrig is also used late in the driver
! loop - so it wouldn't work, for example, to calculate qflx_irrig after btran is
! computed, and then save it on the restart file for the next iteration of the driver
! loop: then the uses of qflx_irrig early and late in the driver loop would be
! inconsistent.)
!
! Now that we no longer have a dependency on btran, we could call CalcIrrigationNeeded
! before the first time qflx_irrig is needed. Thus, there might be some advantage to
! combining CalcIrrigationFluxes and CalcIrrigationNeeded - or at least calling these
! two routines from the same place. In particular: this separation of the irrigation
! calculation into two routines that are done at different times in the driver loop
! makes it harder and less desirable to nest the irrigation object within some other
! object: Doing so might make it harder to do the two separate steps at the right
! time, and would lead to less clarity about how these two steps are ordered with
! respect to the rest of the driver loop. So if we start trying to create a hierarchy
! of objects in CLM, we may want to rework this design. And we may want to rework it
! to keep things simpler anyway, even if we aren't nesting objects. Note that this
! rework would change behavior slightly, because irrigation would be applied in the
! same time step that CalcIrrigationNeeded first determines it's needed, rather than
! waiting until the following time step.
!
! Design notes regarding where we calculate supply-based irrigation limitations:
!
! We compute supply-based irrigation limitations differently for rivers (volr) vs.
! groundwater.
!
! For volr-based limitation, we apply the limit in CalcIrrigationNeeded rather than in
! CalcIrrigationFluxes. This is to avoid problems that arise due to evolving volr -
! e.g., if we had calculated irrigation demand such that volr was just barely big
! enough, then we apply irrigation for some time steps, then we get an updated volr
! which is lower due to these irrigation withdrawals - if we applied the volr
! limitation in CalcIrrigationFluxes, this would impose an unnecessary limit on the
! irrigation to be applied for the rest of this day. It's hard to see a clean way
! around this problem, given that volr is updated in some but not all CLM time
! steps. So we impose the limit on irrigation deficit, rather than on the
! time step-by-time-step flux. The downside here is that it's somewhat more likely
! that irrigation would try to draw volr negative, if volr has been evolving for other
! reasons.
!
! For groundwater-based limitation, in contrast, we can rely on having an up-to-date
! view of available groundwater, so the argument against having the volr limitation
! in CalcIrrigationFluxes doesn't apply, and that seems like a more robust place to
! do this limitation.
!
! The key difference is that, for volr, we don't have an easy way to determine if this
! is a time step when we have an updated volr value, or if we still have volr from a
! few time steps ago (since ROF isn't coupled in every time step). So in that case,
! having the possibility that we'd exceed available volr seems like the lesser of
! evils.
!
! !USES:
#include "shr_assert.h"
use shr_kind_mod , only : r8 => shr_kind_r8
use decompMod , only : bounds_type, get_proc_global
use shr_log_mod , only : errMsg => shr_log_errMsg
use abortutils , only : endrun
use clm_instur , only : irrig_method
use pftconMod , only : pftcon
use clm_varctl , only : iulog
use clm_varcon , only : isecspday, denh2o, spval, ispval, namep, namec, nameg
use clm_varpar , only : nlevsoi, nlevgrnd
use clm_time_manager , only : get_step_size
use SoilHydrologyMod , only : CalcIrrigWithdrawals
use SoilHydrologyType, only : soilhydrology_type
use SoilStateType , only : soilstate_type
use SoilWaterRetentionCurveMod, only : soil_water_retention_curve_type
use WaterType , only : water_type
use WaterFluxBulkType, only : waterfluxbulk_type
use WaterFluxType , only : waterflux_type
use WaterStateBulkType, only : waterstatebulk_type
use WaterStateType , only : waterstate_type
use WaterTracerUtils , only : CalcTracerFromBulk, CalcTracerFromBulkFixedRatio
use GridcellType , only : grc
use ColumnType , only : col
use PatchType , only : patch
use subgridAveMod , only : p2c, c2g
use filterColMod , only : filter_col_type, col_filter_from_logical_array
!
implicit none
private
! !PUBLIC TYPES:
! This type is public (and its components are public, too) to aid unit testing
type, public :: irrigation_params_type
! Minimum LAI for irrigation
real(r8) :: irrig_min_lai
! Time of day to check whether we need irrigation, seconds (0 = midnight).
! We start applying the irrigation in the time step FOLLOWING this time,
! since we won't begin irrigating until the next call to CalcIrrigationFluxes
integer :: irrig_start_time
! Desired amount of time to irrigate per day (sec). Actual time may
! differ if this is not a multiple of dtime. Irrigation won't work properly
! if dtime > secsperday
integer :: irrig_length
! Target soil matric potential for irrigation (mm)
!
! When we irrigate, we aim to bring the total soil moisture in the top (irrig_depth)
! m of soil up to this level.
!
! (Note: When we convert this to a relative saturation, we ensure that the relative
! saturation target is bounded by [0,1].)
real(r8) :: irrig_target_smp
! Soil depth to which we measure for irrigation (m)
real(r8) :: irrig_depth
! Determines soil moisture threshold at which we irrigate. If
! h2osoi_liq_wilting_point is the soil moisture level at wilting point and
! h2osoi_liq_target is the soil moisture level at the target irrigation level (given
! by irrig_target_smp), then the threshold at which we irrigate is
! h2osoi_liq_wilting_point +
! irrig_threshold_fraction*(h2osoi_liq_target - h2osoi_liq_wilting_point)
! A value of 1 means that we irrigate whenever soil moisture falls below the target
! A value of 0 means that we only irrigate when soil moisture falls below the
! wilting point
real(r8) :: irrig_threshold_fraction
! Threshold for river water volume below which irrigation is shut off, if
! limit_irrigation is .true. (fraction of available river water). A threshold of 0
! means allow all river water to be used; a threshold of 0.1 means allow 90% of the
! river volume to be used; etc.
real(r8) :: irrig_river_volume_threshold
! Whether irrigation is limited based on river storage. This only applies if ROF is
! enabled (i.e., rof_prognostic is .true.) - otherwise we don't limit irrigation,
! regardless of the value of this flag.
logical :: limit_irrigation_if_rof_enabled
! use groundwater supply for irrigation (in addition to surface water)
logical :: use_groundwater_irrigation
! Irrigation method to use if not set on the surface dataset
! (This won't be needed once we can rely on irrig_method always being on the surface
! dataset, but it is useful until then - particularly for testing. See also
! https://github.com/ESCOMP/ctsm/issues/565.)
integer :: irrig_method_default
end type irrigation_params_type
type, public :: irrigation_type
private
! Private data members; set in initialization:
type(irrigation_params_type) :: params
integer :: dtime ! land model time step (sec)
integer :: irrig_nsteps_per_day ! number of time steps per day in which we irrigate
real(r8), pointer :: relsat_wilting_point_col(:,:) ! relative saturation at which smp = wilting point [col, nlevsoi]
real(r8), pointer :: relsat_target_col(:,:) ! relative saturation at which smp is at the irrigation target [col, nlevsoi]
integer , pointer :: irrig_method_patch (:) ! patch irrigation application method
! Private data members; time-varying:
real(r8), pointer :: sfc_irrig_rate_patch (:) ! current irrigation rate from surface water [mm/s]
real(r8), pointer :: irrig_rate_demand_patch (:) ! current irrigation rate, neglecting surface water source limitation [mm/s]
integer , pointer :: n_irrig_steps_left_patch (:) ! number of time steps for which we still need to irrigate today (if 0, ignore)
real(r8), pointer :: qflx_irrig_demand_patch (:) ! irrigation flux neglecting surface water source limitation [mm/s]
contains
! Public routines
! COMPILER_BUG(wjs, 2014-10-15, pgi 14.7) Add an "Irrigation" prefix to some generic routines like "Init"
! (without this workaround, pgi compilation fails in restFileMod)
procedure, public :: Init => IrrigationInit
procedure, public :: Restart
procedure, public :: CalcIrrigationFluxes
procedure, public :: CalcIrrigationNeeded
procedure, public :: UseGroundwaterIrrigation ! Returns true if groundwater irrigation enabled
procedure, public :: Clean => IrrigationClean ! deallocate memory
! Public simply to support unit testing; should not be used from CLM code
procedure, public :: InitForTesting ! version of Init meant for unit testing
procedure, public :: RelsatToH2osoi ! convert from relative saturation to kg/m2 water for a single column and layer
procedure, public :: WrapCalcIrrigWithdrawals ! Wrap the call to CalcIrrigWithdrawals
! Private routines
procedure, private :: ReadNamelist
procedure, private :: CheckNamelistValidity ! Check for validity of input parameters
procedure, private :: InitAllocate => IrrigationInitAllocate
procedure, private :: InitHistory => IrrigationInitHistory
procedure, private :: InitCold => IrrigationInitCold
procedure, private :: CalcBulkWithdrawals ! calculate irrigation withdrawals for bulk water
procedure, private :: CalcOneTracerWithdrawals ! calculate irrigation withdrawals for one water tracer
procedure, private :: CalcTotalGWUnconIrrig ! calculate total irrigation withdrawal flux from the unconfined aquifer, for either bulk or one water tracer
procedure, private :: CalcApplicationFluxes ! calculate irrigation application fluxes for either bulk water or a single tracer
procedure, private :: CalcIrrigNstepsPerDay ! given dtime, calculate irrig_nsteps_per_day
procedure, private :: SetIrrigMethod ! set irrig_method_patch based on surface dataset
procedure, private :: PointNeedsCheckForIrrig ! whether a given point needs to be checked for irrigation now
procedure, private :: CalcDeficitVolrLimited ! calculate deficit limited by river volume for each patch
end type irrigation_type
interface irrigation_params_type
module procedure irrigation_params_constructor
end interface irrigation_params_type
! Soil matric potential at wilting point (mm)
!
! There is no reason to make this a tunable parameter, because the behavior it governs
! (the trigger for irrigation) can be tuned via other parameters.
!
! TODO(wjs, 2016-09-08) It looks like there is other code in CLM that also uses an
! assumed wilting point (CNRootDynMod, maybe others). We should probably make this a
! shared parameter, e.g., in clm_varcon.
real(r8), parameter, private :: wilting_point_smp = -150000._r8
! Conversion factors
real(r8), parameter :: m3_over_km2_to_mm = 1.e-3_r8
! Irrigation methods
integer, parameter, public :: irrig_method_unset = 0
! Drip is defined here as irrigation applied directly to soil surface
integer, parameter, public :: irrig_method_drip = 1
! Sprinkler is applied directly to canopy
integer, parameter, public :: irrig_method_sprinkler = 2
integer, parameter, public :: irrig_method_flood = 3
character(len=*), parameter, private :: sourcefile = &
__FILE__
contains
! ========================================================================
! Constructors
! ========================================================================
!-----------------------------------------------------------------------
function irrigation_params_constructor(irrig_min_lai, &
irrig_start_time, irrig_length, &
irrig_target_smp, &
irrig_depth, irrig_threshold_fraction, irrig_river_volume_threshold, &
limit_irrigation_if_rof_enabled, use_groundwater_irrigation, &
irrig_method_default) &
result(this)
!
! !DESCRIPTION:
! Create an irrigation_params instance
!
! !USES:
!
! !ARGUMENTS:
type(irrigation_params_type) :: this ! function result
real(r8), intent(in) :: irrig_min_lai
integer , intent(in) :: irrig_start_time
integer , intent(in) :: irrig_length
real(r8), intent(in) :: irrig_target_smp
real(r8), intent(in) :: irrig_depth
real(r8), intent(in) :: irrig_threshold_fraction
real(r8), intent(in) :: irrig_river_volume_threshold
logical , intent(in) :: limit_irrigation_if_rof_enabled
logical , intent(in) :: use_groundwater_irrigation
integer , intent(in) :: irrig_method_default
!
! !LOCAL VARIABLES:
character(len=*), parameter :: subname = 'irrigation_params_constructor'
!-----------------------------------------------------------------------
this%irrig_min_lai = irrig_min_lai
this%irrig_start_time = irrig_start_time
this%irrig_length = irrig_length
this%irrig_depth = irrig_depth
this%irrig_target_smp = irrig_target_smp
this%irrig_threshold_fraction = irrig_threshold_fraction
this%irrig_river_volume_threshold = irrig_river_volume_threshold
this%limit_irrigation_if_rof_enabled = limit_irrigation_if_rof_enabled
this%use_groundwater_irrigation = use_groundwater_irrigation
this%irrig_method_default = irrig_method_default
end function irrigation_params_constructor
! ========================================================================
! Infrastructure routines (initialization, restart, etc.)
! ========================================================================
!------------------------------------------------------------------------
subroutine IrrigationInit(this, bounds, NLFilename, &
soilstate_inst, soil_water_retention_curve, &
use_aquifer_layer)
use SoilStateType , only : soilstate_type
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
character(len=*) , intent(in) :: NLFilename ! Namelist filename
type(soilstate_type) , intent(in) :: soilstate_inst
class(soil_water_retention_curve_type), intent(in) :: soil_water_retention_curve
logical , intent(in) :: use_aquifer_layer ! whether an aquifer layer is used in this run
call this%ReadNamelist(NLFilename, use_aquifer_layer)
call this%InitAllocate(bounds)
call this%InitHistory(bounds)
call this%InitCold(bounds, soilstate_inst, soil_water_retention_curve)
end subroutine IrrigationInit
!-----------------------------------------------------------------------
subroutine InitForTesting(this, bounds, params, dtime, &
relsat_wilting_point, relsat_target)
!
! !DESCRIPTION:
! Does initialization needed for unit testing. Allows caller to prescribe values of
! some internal variables.
!
! !USES:
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
type(irrigation_params_type) , intent(in) :: params
integer , intent(in) :: dtime ! model time step (sec)
real(r8) , intent(in) :: relsat_wilting_point( bounds%begc: , 1: ) ! relative saturation at which smp = irrig_wilting_point_smp [col, nlevsoi]
real(r8) , intent(in) :: relsat_target( bounds%begc: , 1: ) ! relative saturation at which smp = irrig_target_smp [col, nlevsoi]
!
! !LOCAL VARIABLES:
character(len=*), parameter :: subname = 'InitForTesting'
!-----------------------------------------------------------------------
SHR_ASSERT_ALL_FL((ubound(relsat_wilting_point) == (/bounds%endc, nlevsoi/)), sourcefile, __LINE__)
SHR_ASSERT_ALL_FL((ubound(relsat_target) == (/bounds%endc, nlevsoi/)), sourcefile, __LINE__)
call this%InitAllocate(bounds)
this%params = params
this%dtime = dtime
call this%SetIrrigMethod(bounds)
this%irrig_nsteps_per_day = this%CalcIrrigNstepsPerDay(dtime)
this%relsat_wilting_point_col(:,:) = relsat_wilting_point(:,:)
this%relsat_target_col(:,:) = relsat_target(:,:)
end subroutine InitForTesting
!-----------------------------------------------------------------------
subroutine ReadNamelist(this, NLFilename, use_aquifer_layer)
!
! !DESCRIPTION:
! Read the irrigation namelist
!
! !USES:
use fileutils , only : getavu, relavu, opnfil
use shr_nl_mod , only : shr_nl_find_group_name
use spmdMod , only : masterproc, mpicom
use shr_mpi_mod , only : shr_mpi_bcast
use shr_infnan_mod , only : nan => shr_infnan_nan, assignment(=)
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
character(len=*), intent(in) :: NLFilename ! Namelist filename
logical, intent(in) :: use_aquifer_layer ! whether an aquifer layer is used in this run
!
! !LOCAL VARIABLES:
! temporary variables corresponding to the components of irrigation_params_type
real(r8) :: irrig_min_lai
integer :: irrig_start_time
integer :: irrig_length
real(r8) :: irrig_target_smp
real(r8) :: irrig_depth
real(r8) :: irrig_threshold_fraction
real(r8) :: irrig_river_volume_threshold
logical :: limit_irrigation_if_rof_enabled
logical :: use_groundwater_irrigation
character(len=64) :: irrig_method_default
integer :: irrig_method_default_int
integer :: ierr ! error code
integer :: unitn ! unit for namelist file
character(len=*), parameter :: nmlname = 'irrigation_inparm'
character(len=*), parameter :: subname = 'ReadNamelist'
!-----------------------------------------------------------------------
namelist /irrigation_inparm/ irrig_min_lai, irrig_start_time, irrig_length, &
irrig_target_smp, irrig_depth, irrig_threshold_fraction, &
irrig_river_volume_threshold, limit_irrigation_if_rof_enabled, &
use_groundwater_irrigation, irrig_method_default
! Initialize options to garbage defaults, forcing all to be specified explicitly in
! order to get reasonable results
irrig_min_lai = nan
irrig_start_time = 0
irrig_length = 0
irrig_target_smp = nan
irrig_depth = nan
irrig_threshold_fraction = nan
irrig_river_volume_threshold = nan
limit_irrigation_if_rof_enabled = .false.
use_groundwater_irrigation = .false.
irrig_method_default = ' '
if (masterproc) then
unitn = getavu()
write(iulog,*) 'Read in '//nmlname//' namelist'
call opnfil (NLFilename, unitn, 'F')
call shr_nl_find_group_name(unitn, nmlname, status=ierr)
if (ierr == 0) then
read(unitn, nml=irrigation_inparm, iostat=ierr)
if (ierr /= 0) then
call endrun(msg="ERROR reading "//nmlname//"namelist"//errmsg(sourcefile, __LINE__))
end if
else
call endrun(msg="ERROR could NOT find "//nmlname//"namelist"//errmsg(sourcefile, __LINE__))
end if
call relavu( unitn )
end if
call shr_mpi_bcast(irrig_min_lai, mpicom)
call shr_mpi_bcast(irrig_start_time, mpicom)
call shr_mpi_bcast(irrig_length, mpicom)
call shr_mpi_bcast(irrig_target_smp, mpicom)
call shr_mpi_bcast(irrig_depth, mpicom)
call shr_mpi_bcast(irrig_threshold_fraction, mpicom)
call shr_mpi_bcast(irrig_river_volume_threshold, mpicom)
call shr_mpi_bcast(limit_irrigation_if_rof_enabled, mpicom)
call shr_mpi_bcast(use_groundwater_irrigation, mpicom)
call shr_mpi_bcast(irrig_method_default, mpicom)
call translate_irrig_method_default
this%params = irrigation_params_type( &
irrig_min_lai = irrig_min_lai, &
irrig_start_time = irrig_start_time, &
irrig_length = irrig_length, &
irrig_target_smp = irrig_target_smp, &
irrig_depth = irrig_depth, &
irrig_threshold_fraction = irrig_threshold_fraction, &
irrig_river_volume_threshold = irrig_river_volume_threshold, &
limit_irrigation_if_rof_enabled = limit_irrigation_if_rof_enabled, &
use_groundwater_irrigation = use_groundwater_irrigation, &
irrig_method_default = irrig_method_default_int)
if (masterproc) then
write(iulog,*) ' '
write(iulog,*) nmlname//' settings:'
! Write settings one-by-one rather than with a nml write because
! irrig_river_volume_threshold may be NaN
write(iulog,*) 'irrig_min_lai = ', irrig_min_lai
write(iulog,*) 'irrig_start_time = ', irrig_start_time
write(iulog,*) 'irrig_length = ', irrig_length
write(iulog,*) 'irrig_target_smp = ', irrig_target_smp
write(iulog,*) 'irrig_depth = ', irrig_depth
write(iulog,*) 'irrig_threshold_fraction = ', irrig_threshold_fraction
write(iulog,*) 'limit_irrigation_if_rof_enabled = ', limit_irrigation_if_rof_enabled
if (limit_irrigation_if_rof_enabled) then
write(iulog,*) 'irrig_river_volume_threshold = ', irrig_river_volume_threshold
end if
write(iulog,*) 'use_groundwater_irrigation = ', use_groundwater_irrigation
write(iulog,*) 'irrig_method_default = ', irrig_method_default
write(iulog,*) ' '
call this%CheckNamelistValidity(use_aquifer_layer)
end if
contains
subroutine translate_irrig_method_default
select case (irrig_method_default)
case ('drip')
irrig_method_default_int = irrig_method_drip
case ('sprinkler')
irrig_method_default_int = irrig_method_sprinkler
case ('flood')
irrig_method_default_int = irrig_method_flood
case default
write(iulog,*) 'ERROR: unknown irrig_method_default: ', trim(irrig_method_default)
call endrun('Unknown irrig_method_default')
end select
end subroutine translate_irrig_method_default
end subroutine ReadNamelist
!-----------------------------------------------------------------------
subroutine CheckNamelistValidity(this, use_aquifer_layer)
!
! !DESCRIPTION:
! Check for validity of input parameters.
!
! Assumes that the inputs have already been packed into 'this%params'.
!
! Only needs to be called by the master task, since parameters are the same for all
! tasks.
!
! !ARGUMENTS:
class(irrigation_type), intent(in) :: this
logical, intent(in) :: use_aquifer_layer ! whether an aquifer layer is used in this run
!
! !LOCAL VARIABLES:
character(len=*), parameter :: subname = 'CheckNamelistValidity'
!-----------------------------------------------------------------------
associate( &
irrig_min_lai => this%params%irrig_min_lai, &
irrig_start_time => this%params%irrig_start_time, &
irrig_length => this%params%irrig_length, &
irrig_target_smp => this%params%irrig_target_smp, &
irrig_depth => this%params%irrig_depth, &
irrig_threshold_fraction => this%params%irrig_threshold_fraction, &
irrig_river_volume_threshold => this%params%irrig_river_volume_threshold, &
use_groundwater_irrigation => this%params%use_groundwater_irrigation, &
limit_irrigation_if_rof_enabled => this%params%limit_irrigation_if_rof_enabled)
if (irrig_min_lai < 0._r8) then
write(iulog,*) ' ERROR: irrig_min_lai must be >= 0'
write(iulog,*) ' irrig_min_lai = ', irrig_min_lai
call endrun(msg=' ERROR: irrig_min_lai must be >= 0 ' // errMsg(sourcefile, __LINE__))
end if
if (irrig_start_time < 0 .or. irrig_start_time >= isecspday) then
write(iulog,*) ' ERROR: irrig_start_time must be >= 0 and < ', isecspday
write(iulog,*) ' irrig_start_time = ', irrig_start_time
call endrun(msg=' ERROR: irrig_start_time out of bounds ' // errMsg(sourcefile, __LINE__))
end if
if (irrig_length <= 0 .or. irrig_length > isecspday) then
write(iulog,*) ' ERROR: irrig_length must be > 0 and <= ', isecspday
write(iulog,*) ' irrig_length = ', irrig_length
call endrun(msg=' ERROR: irrig_length out of bounds ' // errMsg(sourcefile, __LINE__))
end if
if (irrig_target_smp >= 0._r8) then
write(iulog,*) ' ERROR: irrig_target_smp must be negative'
write(iulog,*) ' irrig_target_smp = ', irrig_target_smp
call endrun(msg=' ERROR: irrig_target_smp must be negative ' // errMsg(sourcefile, __LINE__))
end if
if (irrig_target_smp < wilting_point_smp) then
write(iulog,*) ' ERROR: irrig_target_smp must be >= wilting_point_smp'
write(iulog,*) ' irrig_target_smp (from namelist) = ', irrig_target_smp
write(iulog,*) ' wilting_point_smp (hard-coded) = ', wilting_point_smp
call endrun(msg=' ERROR: irrig_target_smp must be >= wilting_point_smp ' // errMsg(sourcefile, __LINE__))
end if
if (irrig_depth < 0._r8) then
write(iulog,*) ' ERROR: irrig_depth must be > 0'
write(iulog,*) ' irrig_depth = ', irrig_depth
call endrun(msg=' ERROR: irrig_depth must be > 0 ' // errMsg(sourcefile, __LINE__))
end if
if (irrig_threshold_fraction < 0._r8 .or. irrig_threshold_fraction > 1._r8) then
write(iulog,*) ' ERROR: irrig_threshold_fraction must be between 0 and 1'
write(iulog,*) ' irrig_threshold_fraction = ', irrig_threshold_fraction
call endrun(msg=' ERROR: irrig_threshold_fraction must be between 0 and 1 ' // &
errMsg(sourcefile, __LINE__))
end if
if (limit_irrigation_if_rof_enabled) then
if (irrig_river_volume_threshold < 0._r8 .or. irrig_river_volume_threshold > 1._r8) then
write(iulog,*) ' ERROR: irrig_river_volume_threshold must be between 0 and 1'
write(iulog,*) ' irrig_river_volume_threshold = ', irrig_river_volume_threshold
call endrun(msg=' ERROR: irrig_river_volume_threshold must be between 0 and 1 ' // &
errMsg(sourcefile, __LINE__))
end if
end if
if (use_groundwater_irrigation .and. .not. limit_irrigation_if_rof_enabled) then
write(iulog,*) ' ERROR: use_groundwater_irrigation only makes sense if limit_irrigation_if_rof_enabled is set.'
write(iulog,*) '(If limit_irrigation_if_rof_enabled is .false., then groundwater extraction will never be invoked.)'
call endrun(msg=' ERROR: use_groundwater_irrigation only makes sense if limit_irrigation_if_rof_enabled is set' // &
errMsg(sourcefile, __LINE__))
end if
if (use_aquifer_layer .and. use_groundwater_irrigation) then
write(iulog,*) ' ERROR: use_groundwater_irrigation and use_aquifer_layer may not be used simultaneously'
call endrun(msg=' ERROR: use_groundwater_irrigation and use_aquifer_layer cannot both be set to true' // &
errMsg(sourcefile, __LINE__))
end if
end associate
end subroutine CheckNamelistValidity
!-----------------------------------------------------------------------
subroutine IrrigationInitAllocate(this, bounds)
!
! !DESCRIPTION:
! Initialize irrigation data structure
!
! !USES:
use shr_infnan_mod , only : nan => shr_infnan_nan, assignment(=)
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
!
! !LOCAL VARIABLES:
integer :: begp, endp
integer :: begc, endc
character(len=*), parameter :: subname = 'InitAllocate'
!-----------------------------------------------------------------------
begp = bounds%begp; endp= bounds%endp
begc = bounds%begc; endc= bounds%endc
allocate(this%qflx_irrig_demand_patch (begp:endp)) ; this%qflx_irrig_demand_patch (:) = nan
allocate(this%relsat_wilting_point_col (begc:endc,nlevsoi)) ; this%relsat_wilting_point_col (:,:) = nan
allocate(this%relsat_target_col (begc:endc,nlevsoi)) ; this%relsat_target_col (:,:) = nan
allocate(this%sfc_irrig_rate_patch (begp:endp)) ; this%sfc_irrig_rate_patch (:) = nan
allocate(this%irrig_rate_demand_patch (begp:endp)) ; this%irrig_rate_demand_patch (:) = nan
allocate(this%irrig_method_patch (begp:endp)) ; this%irrig_method_patch (:) = ispval
allocate(this%n_irrig_steps_left_patch (begp:endp)) ; this%n_irrig_steps_left_patch (:) = 0
end subroutine IrrigationInitAllocate
!-----------------------------------------------------------------------
subroutine IrrigationInitHistory(this, bounds)
!
! !DESCRIPTION:
! Initialize irrigation history fields
!
! !USES:
use histFileMod , only : hist_addfld1d
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
!
! !LOCAL VARIABLES:
integer :: begp, endp
character(len=*), parameter :: subname = 'InitHistory'
!-----------------------------------------------------------------------
begp = bounds%begp; endp= bounds%endp
this%qflx_irrig_demand_patch(begp:endp) = spval
call hist_addfld1d (fname='QIRRIG_DEMAND', units='mm/s', &
avgflag='A', long_name='irrigation demand', &
ptr_patch=this%qflx_irrig_demand_patch, default='inactive')
end subroutine IrrigationInitHistory
!-----------------------------------------------------------------------
subroutine IrrigationInitCold(this, bounds, soilstate_inst, soil_water_retention_curve)
!
! !DESCRIPTION:
! Do cold-start initialization for irrigation data structure
!
! !USES:
use SoilStateType , only : soilstate_type
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
type(soilstate_type) , intent(in) :: soilstate_inst
class(soil_water_retention_curve_type), intent(in) :: soil_water_retention_curve
!
! !LOCAL VARIABLES:
integer :: c ! col index
integer :: j ! level index
character(len=*), parameter :: subname = 'InitCold'
!-----------------------------------------------------------------------
do j = 1, nlevsoi
do c = bounds%begc, bounds%endc
call soil_water_retention_curve%soil_suction_inverse( &
c = c, &
j = j, &
smp_target = wilting_point_smp, &
soilstate_inst = soilstate_inst, &
s_target = this%relsat_wilting_point_col(c,j))
call soil_water_retention_curve%soil_suction_inverse( &
c = c, &
j = j, &
smp_target = this%params%irrig_target_smp, &
soilstate_inst = soilstate_inst, &
s_target = this%relsat_target_col(c,j))
! Make sure relative saturation targets are bounded by [0,1]
!
! NOTE(wjs, 2016-11-17) These targets can be > 1 if smp_target is too small of
! a negative value; we want to force the target to a relative saturation of 1
! in that case. I don't see how these targets could end up negative, though I
! had a note that I saw negative values at one point. In practice, for
! reasonable parameter values, it seems that these min and max functions have
! no effect.
this%relsat_wilting_point_col(c,j) = min(this%relsat_wilting_point_col(c,j), 1._r8)
this%relsat_wilting_point_col(c,j) = max(this%relsat_wilting_point_col(c,j), 0._r8)
this%relsat_target_col(c,j) = min(this%relsat_target_col(c,j), 1._r8)
this%relsat_target_col(c,j) = max(this%relsat_target_col(c,j), 0._r8)
end do
end do
call this%SetIrrigMethod(bounds)
this%dtime = get_step_size()
this%irrig_nsteps_per_day = this%CalcIrrigNstepsPerDay(this%dtime)
this%qflx_irrig_demand_patch(bounds%begp:bounds%endp) = 0._r8
end subroutine IrrigationInitCold
!-----------------------------------------------------------------------
pure function CalcIrrigNstepsPerDay(this, dtime) result(irrig_nsteps_per_day)
!
! !DESCRIPTION:
! Given dtime (sec), determine number of irrigation steps per day
!
! !USES:
!
! !ARGUMENTS:
integer :: irrig_nsteps_per_day ! function result
class(irrigation_type) , intent(in) :: this
integer , intent(in) :: dtime ! model time step (sec)
!
! !LOCAL VARIABLES:
character(len=*), parameter :: subname = 'CalcIrrigNstepsPerDay'
!-----------------------------------------------------------------------
irrig_nsteps_per_day = ((this%params%irrig_length + (dtime - 1))/dtime) ! round up
end function CalcIrrigNstepsPerDay
!-----------------------------------------------------------------------
subroutine SetIrrigMethod(this, bounds)
!
! !DESCRIPTION:
! Set this%irrig_method_patch based on surface dataset
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
!
! !LOCAL VARIABLES:
integer :: p ! patch index
integer :: g ! gridcell index
integer :: m ! patch itype
character(len=*), parameter :: subname = 'SetIrrigMethod'
!-----------------------------------------------------------------------
do p = bounds%begp,bounds%endp
g = patch%gridcell(p)
m = patch%itype(p)
if (m >= lbound(irrig_method, 2) .and. m <= ubound(irrig_method, 2) &
.and. pftcon%irrigated(m) == 1._r8) then
this%irrig_method_patch(p) = irrig_method(g,m)
! ensure irrig_method is valid; if not set, use drip irrigation
if(irrig_method(g,m) == irrig_method_unset) then
this%irrig_method_patch(p) = this%params%irrig_method_default
else if (irrig_method(g,m) /= irrig_method_drip .and. irrig_method(g,m) /= irrig_method_sprinkler .and. irrig_method(g,m) /= irrig_method_flood) then
write(iulog,*) subname //' invalid irrigation method specified'
call endrun(decomp_index=g, clmlevel=nameg, msg='bad irrig_method '// &
errMsg(sourcefile, __LINE__))
end if
else
this%irrig_method_patch(p) = this%params%irrig_method_default
end if
end do
end subroutine SetIrrigMethod
!-----------------------------------------------------------------------
subroutine Restart(this, bounds, ncid, flag)
!
! !DESCRIPTION:
! Handle restart of irrigation variables
!
! !USES:
use ncdio_pio , only : file_desc_t, ncd_inqvdlen, ncd_double, ncd_int
use restUtilMod
!
! !ARGUMENTS:
class(irrigation_type) :: this
type(bounds_type), intent(in) :: bounds
type(file_desc_t), intent(inout) :: ncid ! netcdf id
character(len=*) , intent(in) :: flag ! 'read', 'write' or 'define'
!
! !LOCAL VARIABLES:
logical :: do_io
integer :: dimlen ! dimension length
integer :: nump_global ! total number of patchs, globally
integer :: err_code ! error code
logical :: readvar ! determine if variable is on initial file
character(len=*), parameter :: subname = 'Restart'
!-----------------------------------------------------------------------
! Get expected total number of points, for later error checks
call get_proc_global(np=nump_global)
do_io = .true.
readvar = .false.
if (flag == 'read') then
! BACKWARDS_COMPATIBILITY
! On a read, confirm that this variable has the expected size; if not, don't read
! it (instead give it a default value). This is needed to support older initial
! conditions for which this variable had a different size.
call ncd_inqvdlen(ncid, 'n_irrig_steps_left', 1, dimlen, err_code)
if (dimlen /= nump_global) then
do_io = .false.
end if
end if
if (do_io) then
call restartvar(ncid=ncid, flag=flag, varname='n_irrig_steps_left', xtype=ncd_int, &
dim1name='pft', &
long_name='number of irrigation time steps left', units='#', &
interpinic_flag='interp', readvar=readvar, data=this%n_irrig_steps_left_patch)
end if
if (flag=='read' .and. .not. readvar) then
this%n_irrig_steps_left_patch = 0
end if
do_io = .true.
readvar = .false.
if (flag == 'read') then
! BACKWARDS_COMPATIBILITY
! On a read, confirm that this variable has the expected size; if not, don't read
! it (instead give it a default value). This is needed to support older initial
! conditions for which this variable had a different size.
call ncd_inqvdlen(ncid, 'irrig_rate', 1, dimlen, err_code)
if (dimlen /= nump_global) then
do_io = .false.
end if
end if
if (do_io) then
call restartvar(ncid=ncid, flag=flag, varname='irrig_rate', xtype=ncd_double, &
dim1name='pft', &
long_name='surface irrigation rate', units='mm/s', &
interpinic_flag='interp', readvar=readvar, data=this%sfc_irrig_rate_patch)
end if
if (flag=='read' .and. .not. readvar) then
this%sfc_irrig_rate_patch = 0.0_r8
end if
! BACKWARDS_COMPATIBILITY(wjs, 2016-11-23) To support older restart files without an
! irrig_rate_demand field, get irrig_rate_demand from irrig_rate. I'm abusing the
! capability to specify multiple variable names here (even though irrig_rate isn't
! really an old version of irrig_rate_demand), rather than having code like 'if
! (.not. readvar) then ...', because the latter doesn't work when using init_interp.
call restartvar(ncid=ncid, flag=flag, varname='irrig_rate_demand:irrig_rate', &
xtype=ncd_double, &
dim1name='pft', &
long_name='irrigation rate demand, neglecting surface water source limitation', &
units='mm/s', &
interpinic_flag='interp', readvar=readvar, data=this%irrig_rate_demand_patch)
end subroutine Restart
!-----------------------------------------------------------------------
subroutine IrrigationClean(this)
!
! !DESCRIPTION:
! Deallocate memory
!
! !ARGUMENTS:
class(irrigation_type), intent(inout) :: this
!
! !LOCAL VARIABLES:
character(len=*), parameter :: subname = 'Clean'
!-----------------------------------------------------------------------
deallocate(this%qflx_irrig_demand_patch)
deallocate(this%relsat_wilting_point_col)
deallocate(this%relsat_target_col)
deallocate(this%sfc_irrig_rate_patch)
deallocate(this%irrig_rate_demand_patch)
deallocate(this%irrig_method_patch)
deallocate(this%n_irrig_steps_left_patch)
end subroutine IrrigationClean
! ========================================================================
! Science routines
! ========================================================================
!-----------------------------------------------------------------------
subroutine CalcIrrigationFluxes(this, bounds, num_soilc, &
filter_soilc, num_soilp, filter_soilp, &
soilhydrology_inst, soilstate_inst, &
water_inst)
!
! !DESCRIPTION:
! Apply the irrigation computed by CalcIrrigationNeeded in order to set various fluxes
!
! Sets irrigation withdrawal and application fluxes in the waterflux components of
! water_inst, for both bulk and tracers:
! - qflx_sfc_irrig_col
! - qflx_gw_uncon_irrig_lyr_col
! - qflx_gw_uncon_irrig_col
! - qflx_gw_con_irrig_col
! - qflx_irrig_drip_patch
! - qflx_irrig_sprinkler_patch
!
! Should be called once, AND ONLY ONCE, per time step.
!
! !ARGUMENTS:
class(irrigation_type) , intent(inout) :: this
type(bounds_type) , intent(in) :: bounds
! number of points in filter_soilc
integer, intent(in) :: num_soilc
! column filter for soil
integer, intent(in) :: filter_soilc(:)
! number of points in filter_soilp
integer, intent(in) :: num_soilp
! patch filter for soil
integer, intent(in) :: filter_soilp(:)
type(soilhydrology_type) , intent(in) :: soilhydrology_inst
type(soilstate_type) , intent(in) :: soilstate_inst
type(water_type) , intent(inout) :: water_inst
!
! !LOCAL VARIABLES:
integer :: p,fp ! patch indices
integer :: c,fc ! column indices
integer :: g ! grid cell index
integer :: j ! level index
integer :: i ! tracer index
real(r8) :: qflx_sfc_irrig_bulk_patch(bounds%begp:bounds%endp) ! patch surface irrigation flux for bulk water (mm H2O/s)
real(r8) :: qflx_gw_demand_bulk_patch(bounds%begp:bounds%endp) ! patch amount of irrigation groundwater demand for bulk water (mm H2O/s)
real(r8) :: qflx_gw_demand_bulk_col(bounds%begc:bounds%endc) ! col amount of irrigation groundwater demand for bulk water (mm H2O/s)
logical :: is_bulk
character(len=*), parameter :: subname = 'CalcIrrigationFluxes'
!-----------------------------------------------------------------------
! This should be called exactly once per time step, so that the counter decrease
! works correctly.
! Note that these associated variables refer to the bulk instance
associate( &
begp => bounds%begp, &
endp => bounds%endp, &
begc => bounds%begc, &
endc => bounds%endc &
)
call this%CalcBulkWithdrawals(bounds, num_soilc, filter_soilc, num_soilp, filter_soilp, &
soilhydrology_inst, soilstate_inst, water_inst%waterfluxbulk_inst, &
qflx_sfc_irrig_bulk_patch = qflx_sfc_irrig_bulk_patch(begp:endp), &
qflx_gw_demand_bulk_patch = qflx_gw_demand_bulk_patch(begp:endp), &
qflx_gw_demand_bulk_col = qflx_gw_demand_bulk_col(begc:endc))
do i = water_inst%tracers_beg, water_inst%tracers_end
call this%CalcOneTracerWithdrawals(bounds, num_soilc, filter_soilc, &
waterstatebulk_inst = water_inst%waterstatebulk_inst, &
waterfluxbulk_inst = water_inst%waterfluxbulk_inst, &
waterstate_tracer_inst = water_inst%bulk_and_tracers(i)%waterstate_inst, &
waterflux_tracer_inst = water_inst%bulk_and_tracers(i)%waterflux_inst)
end do
if (this%params%use_groundwater_irrigation) then
do i = water_inst%bulk_and_tracers_beg, water_inst%bulk_and_tracers_end
call this%CalcTotalGWUnconIrrig(num_soilc, filter_soilc, &
water_inst%bulk_and_tracers(i)%waterflux_inst)
end do
end if
do i = water_inst%bulk_and_tracers_beg, water_inst%bulk_and_tracers_end
is_bulk = (i == water_inst%i_bulk)
call this%CalcApplicationFluxes(bounds, num_soilc, filter_soilc, num_soilp, filter_soilp, &
waterflux_inst = water_inst%bulk_and_tracers(i)%waterflux_inst, &
is_bulk = is_bulk, &
qflx_sfc_irrig_bulk_patch = qflx_sfc_irrig_bulk_patch(begp:endp), &
qflx_sfc_irrig_bulk_col = water_inst%waterfluxbulk_inst%qflx_sfc_irrig_col(begc:endc), &
qflx_gw_demand_bulk_patch = qflx_gw_demand_bulk_patch(begp:endp), &
qflx_gw_demand_bulk_col = qflx_gw_demand_bulk_col(begc:endc))
end do
end associate
end subroutine CalcIrrigationFluxes
!-----------------------------------------------------------------------
subroutine CalcBulkWithdrawals(this, bounds, num_soilc, filter_soilc, num_soilp, filter_soilp, &
soilhydrology_inst, soilstate_inst, waterfluxbulk_inst, &
qflx_sfc_irrig_bulk_patch, qflx_gw_demand_bulk_patch, qflx_gw_demand_bulk_col)
!
! !DESCRIPTION:
! Calculate irrigation withdrawals for bulk water
!
! Sets / updates the following variables:
! - qflx_sfc_irrig_bulk_patch
! - qflx_gw_demand_bulk_patch