meta-xilinx-standalone: Rework embeddedsw integration

Introduce a new embeddedsw-source recipe that is a single point for unpack,
and patch of the sources.  This will allow someone to universally patch
(via a bbappend or similar) the esw sources.

As part of this work, we transfered the various patches for fsbl, pmu, plm,
and psm to the universe source recipe.

Most of this is transparent to any recipe using xlnx-embeddedsw.  The class
automaticaly detects if the recipe is a user our the special embeddedsw-source
recipe and enables the correct behavior.

Since the esw sources expect the S and B to be the same, the cmake objects
get written into S, we are not able to follow the gcc-source example.
Instead recipes that use the xlnx-embeddedsw class will hard link or copy
the source files to their working directory.  This avoid the penalty for
fetch, unpack and patch.  Note these recipes may also add their own
SRC_URI which WILL be processed as normal.  This is often used to
introduce special tcl scripts.  See the do_copy_shared_src task injected
by the xlnx-embeddedsw.bbclass for technical details.

Additionally, correct some of the existing patch Upstream-Status entries
to conform to current YP guidelines.

For 2024.2 introduce a special Xil_Assert fix for the current toolchain
which is more strict on type conversion..  See the patch itself for
more details.

Signed-off-by: Mark Hatle <mark.hatle@amd.com>

Author: mhatle

meta-xilinx-standalone-sdt/classes-recipe/esw.bbclass

@@ -8,8 +8,6 @@ OECMAKE_ARGS:remove = "-DCMAKE_EXPORT_COMPILE_COMMANDS:BOOL=ON"
 
 SRCREV_FORMAT = "src_decouple"
 
-S = "${UNPACKDIR}/git"
-B = "${WORKDIR}/build"
 OECMAKE_SOURCEPATH = "${S}/${ESW_COMPONENT_SRC}"
 LICFILENAME = "license.txt"
 

meta-xilinx-standalone-sdt/recipes-bsp/embeddedsw/esw-conf_2024.1.bb

@@ -1,9 +1,6 @@
 # Can't depend on esw since this is needed for setup!
 inherit xlnx-embeddedsw
 
-S = "${UNPACKDIR}/git"
-B = "${WORKDIR}/build"
-
 INHIBIT_DEFAULT_DEPS = "1"
 
 # Installing this recipe should install the lopper tools and such

meta-xilinx-standalone-sdt/recipes-bsp/embeddedsw/esw-conf_2024.2.bb

@@ -1,9 +1,6 @@
 # Can't depend on esw since this is needed for setup!
 inherit xlnx-embeddedsw
 
-S = "${UNPACKDIR}/git"
-B = "${WORKDIR}/build"
-
 INHIBIT_DEFAULT_DEPS = "1"
 
 # Installing this recipe should install the lopper tools and such

meta-xilinx-standalone-sdt/recipes-libraries/xilstandalone_2024.2.bb

@@ -5,17 +5,16 @@ ESW_COMPONENT_NAME = "libxilstandalone.a"
 
 DEPENDS += "libgloss"
 
+S = "${B}"
+
 do_configure:prepend() {
     # This script should also not rely on relative paths and such
-    (
-    cd ${S}
-    lopper ${DTS_FILE} -- baremetal_bspconfig_xlnx ${ESW_MACHINE} ${S}/${ESW_COMPONENT_SRC}
-    install -m 0755 MemConfig.cmake ${S}/${ESW_COMPONENT_SRC}/
-    install -m 0755 *.c ${S}/${ESW_COMPONENT_SRC}
-    lopper ${DTS_FILE} -- bmcmake_metadata_xlnx ${ESW_MACHINE} ${S}/${ESW_COMPONENT_SRC} hwcmake_metadata ${S}
-    install -m 0755 StandaloneExample.cmake ${S}/${ESW_COMPONENT_SRC}/common/
-    LOPPER_DTC_FLAGS="-b 0 -@" lopper ${DTS_FILE} -- baremetal_xparameters_xlnx.py ${ESW_MACHINE} ${S}
-    install -m 0755 xparameters.h ${S}/${ESW_COMPONENT_SRC}/common/
-    )
+    lopper ${DTS_FILE} -- baremetal_bspconfig_xlnx ${ESW_MACHINE} ${B}/${ESW_COMPONENT_SRC}
+    install -m 0755 MemConfig.cmake ${B}/${ESW_COMPONENT_SRC}/
+    install -m 0755 *.c ${B}/${ESW_COMPONENT_SRC}
+    lopper ${DTS_FILE} -- bmcmake_metadata_xlnx ${ESW_MACHINE} ${B}/${ESW_COMPONENT_SRC} hwcmake_metadata ${B}
+    install -m 0755 StandaloneExample.cmake ${B}/${ESW_COMPONENT_SRC}/common/
+    LOPPER_DTC_FLAGS="-b 0 -@" lopper ${DTS_FILE} -- baremetal_xparameters_xlnx.py ${ESW_MACHINE} ${B}
+    install -m 0755 xparameters.h ${B}/${ESW_COMPONENT_SRC}/common/
 
 }

meta-xilinx-standalone/classes/xlnx-embeddedsw.bbclass

@@ -35,7 +35,6 @@ LIC_FILES_CHKSUM[xlnx_rel_v2024.1] = '0dcabd3719e5ac33f7c03f0d77d473f2'
 LIC_FILES_CHKSUM[xlnx_rel_v2024.2] = '689662801a76c14d0cb57ae169cbec7c'
 LIC_FILES_CHKSUM ??= "file://license.txt;md5=${@d.getVarFlag('LIC_FILES_CHKSUM', d.getVar('BRANCH')) or '0'}"
 
-SRC_URI = "${EMBEDDEDSW_SRCURI}"
 PV .= "+git"
 
 python() {
@@ -47,3 +46,24 @@ python() {
         except:
             raise bb.parse.SkipRecipe('BB_NO_NETWORK is enabled, can not fetch SRCREV (%s)' % d.getVar('SRCREV'))
 }
+
+SHARED_S = "${TMPDIR}/work-shared/embeddedsw-${PV}-${PR}/source/git"
+S = "${WORKDIR}/source"
+B = "${WORKDIR}/build"
+
+ERROR_QA:remove = "buildpaths"
+
+# The following is for recipes that use the common sources
+python do_copy_shared_src() {
+    src = d.getVar('SHARED_S')
+    dest = d.getVar('S')
+    if src != dest:
+        oe.path.copyhardlinktree(src, dest)
+}
+
+python() {
+    if d.getVar('BPN') != "embeddedsw-source":
+        bb.build.addtask('do_copy_shared_src', 'do_configure do_populate_lic do_deploy_source_date_epoch', 'do_patch', d)
+
+        d.appendVarFlag('do_copy_shared_src', 'depends', ' embeddedsw-source-${PV}:do_patch')
+}

meta-xilinx-standalone/conf/distro/xilinx-standalone.inc

@@ -3,7 +3,6 @@ DISTRO_VERSION = "1.0"
 TARGET_VENDOR = "-xilinx"
 
 TCLIBC = "newlib"
-TCLIBCAPPEND =""
 
 # Change SDK name
 SDK_VERSION = "xilinx-standalone"

meta-xilinx-standalone/recipes-bsp/embeddedsw/embeddedsw-source.inc

@@ -0,0 +1,33 @@
+deltask do_configure
+deltask do_compile
+deltask do_install
+deltask do_populate_sysroot
+deltask do_populate_lic
+RM_WORK_EXCLUDE += "${PN}"
+
+inherit xlnx-embeddedsw nopackages
+
+COMPATIBLE_HOST = ".*"
+COMPATIBLE_MACHINE = ".*"
+
+PN = "embeddedsw-source-${PV}"
+WORKDIR = "${TMPDIR}/work-shared/embeddedsw-${PV}-${PR}"
+SSTATE_SWSPEC = "sstate:embeddedsw::${PV}:${PR}::${SSTATE_VERSION}:"
+
+STAMP = "${STAMPS_DIR}/work-shared/embeddedsw-${PV}-${PR}"
+STAMPCLEAN = "${STAMPS_DIR}/work-shared/embeddedsw-${PV}-*"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS = ""
+PACKAGES = ""
+TARGET_ARCH = "allarch"
+TARGET_AS_ARCH = "none"
+TARGET_CC_ARCH = "none"
+TARGET_LD_ARCH = "none"
+TARGET_OS = "linux"
+baselib = "lib"
+PACKAGE_ARCH = "all"
+
+UNPACKDIR = "${WORKDIR}/source"
+S = "${SHARED_S}"
+B = "${WORKDIR}/build"

meta-xilinx-standalone/recipes-bsp/embeddedsw/embeddedsw-source_2023.1.bb

@@ -0,0 +1,17 @@
+require recipes-bsp/embeddedsw/embeddedsw-source.inc
+
+
+BPN = "embeddedsw-source"
+EXCLUDE_FROM_WORLD = "1"
+
+FILESPATH .= ":${FILE_DIRNAME}/embeddedsw/${PV}:${FILE_DIRNAME}/embeddedsw"
+
+SRC_URI = " \
+	${EMBEDDEDSW_SRCURI} \
+	file://makefile-skip-copy_bsp.sh.patch \
+	file://fsbl-fixups.patch \
+	file://0001-versal_fw-Fixup-core-makefiles.patch \
+	"
+
+#	file://fix-xil-assert-filename.patch \
+#

meta-xilinx-standalone/recipes-bsp/embeddedsw/embeddedsw-source_2023.2.bb

@@ -0,0 +1,17 @@
+require recipes-bsp/embeddedsw/embeddedsw-source.inc
+
+
+BPN = "embeddedsw-source"
+EXCLUDE_FROM_WORLD = "1"
+
+FILESPATH .= ":${FILE_DIRNAME}/embeddedsw/${PV}:${FILE_DIRNAME}/embeddedsw"
+
+SRC_URI = " \
+	${EMBEDDEDSW_SRCURI} \
+	file://makefile-skip-copy_bsp.sh.patch \
+	file://fsbl-fixups.patch \
+	file://0001-versal_fw-Fixup-core-makefiles.patch \
+	"
+
+#	file://fix-xil-assert-filename.patch \
+#

meta-xilinx-standalone/recipes-bsp/embeddedsw/embeddedsw-source_2024.1.bb

@@ -0,0 +1,17 @@
+require recipes-bsp/embeddedsw/embeddedsw-source.inc
+
+
+BPN = "embeddedsw-source"
+EXCLUDE_FROM_WORLD = "1"
+
+FILESPATH .= ":${FILE_DIRNAME}/embeddedsw/${PV}:${FILE_DIRNAME}/embeddedsw"
+
+SRC_URI = " \
+	${EMBEDDEDSW_SRCURI} \
+	file://makefile-skip-copy_bsp.sh.patch \
+	file://fsbl-fixups.patch \
+	file://0001-versal_fw-Fixup-core-makefiles.patch \
+	"
+
+#	file://fix-xil-assert-filename.patch \
+#