diffuse/build.gradle at trunk · XZQ/diffuse · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

buildscript {
  dependencies {
    classpath libs.kotlinPlugin
    classpath libs.dokkaPlugin
    classpath libs.mavenPublishPlugin
    classpath libs.spotlessPlugin
    classpath libs.buildConfigPlugin
    classpath libs.pokoPlugin
  }
  repositories {
    mavenCentral()
    gradlePluginPortal()
  }
}

subprojects {
  group = GROUP
  version = VERSION_NAME

  apply plugin: 'com.diffplug.spotless'
  spotless {
    kotlin {
      ktfmt(libs.ktfmt.get().version).googleStyle()
      target('src/**/*.kt')
    }
  }

  plugins.withId('org.jetbrains.kotlin.jvm') {
    kotlin {
      plugins.withId('com.vanniktech.maven.publish') {
        abiValidation {
          enabled = true
        }
      }
      compilerOptions {
        allWarningsAsErrors = true
        jvmTarget = JvmTarget.JVM_11
        freeCompilerArgs = [
            "-progressive",
            '-opt-in=kotlin.contracts.ExperimentalContracts',
            '-Xjdk-release=11',
        ]
      }
    }
  }

  tasks.withType(JavaCompile).configureEach {
    options.release = 11
  }
}