build.gradle

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile

buildscript {
	apply from: 'dependencies.gradle'

	dependencies {
		classpath deps.kotlinGradlePlugin
		// We don't use this dependency directly. However, we reference a type from the Kotlin Gradle
		// plugin whose classloading causes com.android.build.gradle.api.BaseVariant to also be loaded.
		classpath 'com.android.tools.build:gradle:7.2.2'
		classpath 'com.vanniktech:gradle-maven-publish-plugin:0.13.0'
		classpath 'org.jetbrains.dokka:dokka-gradle-plugin:1.7.10'
	}
	repositories {
		mavenCentral()
		google()
	}
}

apply plugin: 'org.jetbrains.dokka'
dokkaHtmlMultiModule {
}

allprojects {
	group = GROUP
	version = VERSION_NAME

	repositories {
		mavenCentral()
		google()
	}

	tasks.withType(JavaCompile).configureEach {
		sourceCompatibility = JavaVersion.VERSION_1_8
		targetCompatibility = JavaVersion.VERSION_1_8
	}

	tasks.withType(KotlinCompile).configureEach { task ->
		task.kotlinOptions {
			freeCompilerArgs += [
				'-Xjvm-default=all',
				'-opt-in=kotlin.RequiresOptIn',
			]
		}
	}

	plugins.withId('com.vanniktech.maven.publish') {
		mavenPublish {
			targets {
				installArchives {
					def url = file("${rootProject.buildDir}/localMaven").toURI().toString()
					releaseRepositoryUrl = url
					snapshotRepositoryUrl = url
				}
			}
		}
	}
}