-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathtea_leaf_cg.f90
315 lines (274 loc) · 11.7 KB
/
tea_leaf_cg.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
!cROWn Copyright 2014 AWE.
!
! This file is part of TeaLeaf.
!
! TeaLeaf is free software: you can redistribute it and/or modify it under
! the terms of the GNU General Public License as published by the
! Free Software Foundation, either version 3 of the License, or (at your option)
! any later version.
!
! TeaLeaf is distributed in the hope that it will be useful, but
! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
! FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
! details.
!
! You should have received a copy of the GNU General Public License along with
! TeaLeaf. If not, see http://www.gnu.org/licenses/.
!> @brief Fortran heat conduction kernel
!> @author Michael Boulton, Wayne Gaudin
!> @details Implicitly calculates the change in temperature using CG method
MODULE tea_leaf_kernel_cg_module
USE tea_leaf_kernel_common_module
USE definitions_module, only: tl_ppcg_active ! added for ppcg init
CONTAINS
SUBROUTINE tea_leaf_kernel_init_cg_fortran(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth, &
p, &
r, &
Mi, &
z, &
Kx, &
Ky, &
Kz, &
cp, &
bfp, &
rx, &
ry, &
rz, &
rro, &
preconditioner_type)
IMPLICIT NONE
INTEGER :: preconditioner_type
INTEGER(KIND=4):: x_min,x_max,y_min,y_max, z_min, z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: r, Kx, Ky, Kz, z, Mi, p
REAL(KIND=8), DIMENSION(x_min:x_max,y_min:y_max,z_min:z_max) :: cp, bfp
INTEGER(KIND=4) :: j,k,l
REAL(kind=8) :: rro
REAL(KIND=8) :: rx, ry, rz
rro = 0.0_8
!$OMP PARALLEL
!$OMP DO
DO l=z_min,z_max
DO k=y_min, y_max
DO j=x_min, x_max
p(j, k, l) = 0.0_8
z(j, k, l) = 0.0_8
ENDDO
ENDDO
ENDDO
!$OMP END DO
IF (preconditioner_type .NE. TL_PREC_NONE) THEN
! Call a block Jacobi preconditioner
IF (preconditioner_type .EQ. TL_PREC_JAC_BLOCK) THEN
CALL tea_block_solve(x_min, x_max, y_min, y_max, z_min, z_max,halo_exchange_depth, r, z, cp,&
bfp, Kx, Ky, Kz, rx, ry, rz)
! Call a point diagonal Jacobi preconditioner
ELSE IF (preconditioner_type .EQ. TL_PREC_JAC_DIAG) THEN
CALL tea_diag_solve(x_min, x_max, y_min, y_max, z_min, z_max, halo_exchange_depth, r, z, Mi)
ENDIF
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
p(j, k, l) = z(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO NOWAIT
ELSE
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
p(j, k, l) = r(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO NOWAIT
ENDIF
!$OMP DO REDUCTION(+:rro)
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
rro = rro + r(j, k, l)*p(j, k, l);
ENDDO
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_kernel_init_cg_fortran
SUBROUTINE tea_leaf_kernel_solve_cg_fortran_calc_w(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
p, &
w, &
Kx, &
Ky, &
Kz, &
rx, &
ry, &
rz, &
pw)
IMPLICIT NONE
INTEGER(KIND=4):: x_min,x_max,y_min,y_max, z_min, z_max, halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: Kx, Ky, Kz, p, w
REAL(KIND=8) :: rx, ry, rz
INTEGER(KIND=4) :: j,k,l
REAL(kind=8) :: pw
pw = 0.0_8
!$OMP PARALLEL
!$OMP DO REDUCTION(+:pw)
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
w(j, k, l) = (1.0_8 &
+ rx*(Kx(j+1, k, l) + Kx(j, k, l)) &
+ ry*(Ky(j, k+1, l) + Ky(j, k, l)) &
+ rz*(Kz(j, k, l+1) + Kz(j, k, l)))*p(j, k, l) &
- rx*(Kx(j+1, k, l)*p(j+1, k, l) + Kx(j, k, l)*p(j-1, k, l))&
- ry*(Ky(j, k+1, l)*p(j, k+1, l) + Ky(j, k, l)*p(j, k-1, l))&
- rz*(Kz(j, k, l+1)*p(j, k, l+1) + Kz(j, k, l)*p(j, k, l-1))
pw = pw + w(j, k, l)*p(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_kernel_solve_cg_fortran_calc_w
SUBROUTINE tea_leaf_kernel_solve_cg_fortran_calc_ur(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
u, &
p, &
r, &
Mi, &
w, &
z, &
cp, &
bfp, &
Kx, &
Ky, &
Kz, &
rx, &
ry, &
rz, &
alpha, &
rrn, &
preconditioner_type)
IMPLICIT NONE
INTEGER :: preconditioner_type
INTEGER(KIND=4):: x_min,x_max,y_min,y_max,z_min,z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: u , p , r , Mi , w , z, Kx, Ky, Kz
REAL(KIND=8), DIMENSION(x_min:x_max,y_min:y_max,z_min:z_max) :: cp, bfp
REAL(KIND=8) :: rx, ry, rz
INTEGER(KIND=4) :: j,k,l
REAL(kind=8) :: alpha, rrn
rrn = 0.0_8
!$OMP PARALLEL
IF (preconditioner_type .NE. TL_PREC_NONE) THEN
!$OMP DO
DO l=z_min,z_max
DO k=y_min, y_max
DO j=x_min,x_max
u(j, k, l) = u(j, k, l) + alpha*p(j, k, l)
r(j, k, l) = r(j, k, l) - alpha*w(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
! Call a block Jacobi preconditioner
IF (preconditioner_type .EQ. TL_PREC_JAC_BLOCK) THEN
CALL tea_block_solve(x_min, x_max, y_min, y_max, z_min, z_max, halo_exchange_depth, r, z, cp,&
bfp, Kx, Ky, Kz, rx, ry, rz)
! Call a block Jacobi preconditioner
ELSE IF (preconditioner_type .EQ. TL_PREC_JAC_DIAG) THEN
CALL tea_diag_solve(x_min, x_max, y_min, y_max, z_min, z_max, halo_exchange_depth, r, z, Mi)
ENDIF
!$OMP DO REDUCTION(+:rrn)
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
rrn = rrn + r(j, k, l)*z(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
ELSE
!$OMP DO REDUCTION(+:rrn)
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
u(j, k, l) = u(j, k, l) + alpha*p(j, k, l)
r(j, k, l) = r(j, k, l) - alpha*w(j, k, l)
rrn = rrn + r(j, k, l)*r(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO
ENDIF
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_kernel_solve_cg_fortran_calc_ur
SUBROUTINE tea_leaf_kernel_solve_cg_fortran_calc_p(x_min, &
x_max, &
y_min, &
y_max, &
z_min, &
z_max, &
halo_exchange_depth,&
p, &
r, &
z, &
beta, &
preconditioner_type)
IMPLICIT NONE
INTEGER :: preconditioner_type
INTEGER(KIND=4):: x_min,x_max,y_min,y_max, z_min, z_max,halo_exchange_depth
REAL(KIND=8), DIMENSION(x_min-halo_exchange_depth:x_max+halo_exchange_depth,&
y_min-halo_exchange_depth:y_max+halo_exchange_depth,&
z_min-halo_exchange_depth:z_max+halo_exchange_depth) :: p, r, z
INTEGER(KIND=4) :: j,k,l
REAL(kind=8) :: beta
!$OMP PARALLEL
IF (preconditioner_type .NE. TL_PREC_NONE .OR. tl_ppcg_active) THEN
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
p(j, k, l) = z(j, k, l) + beta*p(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO NOWAIT
ELSE
!$OMP DO
DO l=z_min,z_max
DO k=y_min,y_max
DO j=x_min,x_max
p(j, k, l) = r(j, k, l) + beta*p(j, k, l)
ENDDO
ENDDO
ENDDO
!$OMP END DO NOWAIT
ENDIF
!$OMP END PARALLEL
END SUBROUTINE tea_leaf_kernel_solve_cg_fortran_calc_p
END MODULE