mavencentral.gradle

task enabledSourcesJar(type: Jar) {
    archiveClassifier.set('sources')
    from android.sourceSets.main.java.srcDirs
    from android.sourceSets.enabled.java.srcDirs
}

artifacts {
    archives enabledSourcesJar
}

apply plugin: 'maven-publish'
apply plugin: 'signing'

ext {
    PUBLISH_GROUP_ID = 'com.telefonica'
    PUBLISH_ARTIFACT_ID = 'tweaks'
    PUBLISH_VERSION = version

    PUBLISH_RELEASE_NAME = 'Tweaks for Android'
    PUBLISH_DESCRIPTION = 'A customizable debug screen to view and edit flags that can be used for development in Jetpack Compose applications'
    PUBLISH_REPO_URL = 'https://github.com/Telefonica/tweaks'
}

publishing {
    publications {
        release(MavenPublication) {
            groupId PUBLISH_GROUP_ID
            artifactId PUBLISH_ARTIFACT_ID
            version PUBLISH_VERSION

            artifact("$buildDir/outputs/aar/${project.getName()}-enabled-release.aar")
            artifact enabledSourcesJar

            pom {
                name = PUBLISH_RELEASE_NAME
                description = PUBLISH_DESCRIPTION
                url = PUBLISH_REPO_URL
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'android-team-telefonica'
                        name = 'Android Team'
                        email = 'cto-android@telefonica.com'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/Telefonica/tweaks.git'
                    developerConnection = 'scm:git:ssh://https://github.com/Telefonica/tweaks.git'
                    url = 'https://github.com/Telefonica/tweaks/tree/main'
                }
                withXml {
                    def dependenciesNode = asNode().appendNode('dependencies')

                    project.configurations.getByName("implementation").allDependencies.each {
                        def dependencyNode = dependenciesNode.appendNode('dependency')
                        dependencyNode.appendNode('groupId', it.group)
                        dependencyNode.appendNode('artifactId', it.name)
                        dependencyNode.appendNode('version', it.version)
                    }
                    project.configurations.getByName("enabledImplementation").allDependencies.each {
                        def dependencyNode = dependenciesNode.appendNode('dependency')
                        dependencyNode.appendNode('groupId', it.group)
                        dependencyNode.appendNode('artifactId', it.name)
                        dependencyNode.appendNode('version', it.version)
                    }
                }
            }
        }
        noop(MavenPublication) {
            groupId PUBLISH_GROUP_ID
            artifactId "$PUBLISH_ARTIFACT_ID-no-op"
            version PUBLISH_VERSION

            artifact("$buildDir/outputs/aar/${project.getName()}-noop-release.aar")

            pom {
                name = "$PUBLISH_RELEASE_NAME-no-op"
                description = PUBLISH_DESCRIPTION
                url = PUBLISH_REPO_URL
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'android-team-telefonica'
                        name = 'Android Team'
                        email = 'cto-android@telefonica.com'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/Telefonica/tweaks.git'
                    developerConnection = 'scm:git:ssh://https://github.com/Telefonica/tweaks.git'
                    url = 'https://github.com/Telefonica/tweaks/tree/main'
                }
                withXml {
                    def dependenciesNode = asNode().appendNode('dependencies')

                    project.configurations.getByName("implementation").allDependencies.each {
                        def dependencyNode = dependenciesNode.appendNode('dependency')
                        dependencyNode.appendNode('groupId', it.group)
                        dependencyNode.appendNode('artifactId', it.name)
                        dependencyNode.appendNode('version', it.version)
                    }
                }
            }
        }
    }

}

signing {
    def signingKeyId = findProperty("signingKeyId")
    def signingKey = findProperty("signingKey")
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
    sign publishing.publications
}