Change lib module name, add bintray deployment files.

Author: arthufimtcev

lib/.gitignore renamed to android-ui-toolkit/.gitignore

@@ -0,0 +1,66 @@
+apply plugin: 'com.jfrog.bintray'
+
+version = libraryVersion
+
+/*
+ * Comment the following part if you only want to distribute .aar files.
+ * (For example, your source code is obfuscated by Proguard and is not shown to outsite developers)
+ * Without source code .jar files, you only can publish on bintray respository but not jcenter.
+ */
+
+/*--------------------------------*/
+if (project.hasProperty("android")) {
+	task sourcesJar(type: Jar) {
+		classifier = 'sources'
+		from android.sourceSets.main.java.srcDirs
+	}
+
+	task javadoc(type: Javadoc) {
+		source = android.sourceSets.main.java.srcDirs
+		classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
+	}
+} else { // Java libraries
+	task sourcesJar(type: Jar, dependsOn: classes) {
+		classifier = 'sources'
+		from sourceSets.main.allSource
+	}
+}
+
+task javadocJar(type: Jar, dependsOn: javadoc) {
+	classifier = 'javadoc'
+	from javadoc.destinationDir
+}
+
+artifacts {
+	archives javadocJar
+	archives sourcesJar
+}
+/*--------------------------------*/
+
+// Bintray
+Properties properties = new Properties()
+properties.load(project.rootProject.file('local.properties').newDataInputStream())
+
+bintray {
+	user = properties.getProperty("bintray.user")
+	key = properties.getProperty("bintray.apikey")
+
+	configurations = ['archives']
+	pkg {
+		repo = bintrayRepo
+		name = bintrayName
+		desc = libraryDescription
+		websiteUrl = siteUrl
+		vcsUrl = gitUrl
+		licenses = allLicenses
+		publish = true
+		publicDownloadNumbers = true
+		version {
+			desc = libraryDescription
+			gpg {
+				sign = true
+				passphrase = properties.getProperty("bintray.gpg.password")
+			}
+		}
+	}
+}

android-ui-toolkit/bintray.gradle

@@ -0,0 +1,63 @@
+apply plugin: 'com.android.library'
+
+android {
+	compileSdkVersion 26
+
+
+
+	defaultConfig {
+		minSdkVersion 16
+		targetSdkVersion 26
+		versionCode 1
+		versionName "1.0"
+
+		testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
+
+	}
+
+	buildTypes {
+		release {
+			minifyEnabled false
+			proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
+		}
+	}
+
+}
+
+dependencies {
+	implementation fileTree(dir: 'libs', include: ['*.jar'])
+
+	implementation 'com.android.support:appcompat-v7:26.1.0'
+	testImplementation 'junit:junit:4.12'
+	androidTestImplementation 'com.android.support.test:runner:1.0.2'
+	androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
+}
+
+ext {
+
+	bintrayRepo = 'maven'
+	bintrayName = 'android-ui-toolkit'
+
+	publishedGroupId = 'io.supernova'
+	libraryName = 'android-ui-toolkit'
+	artifact = 'android-ui-toolkit'
+
+	libraryDescription = 'Set of Android SDK extensions to make things where the SDK is not enough.'
+
+	siteUrl = 'https://github.com/Supernova-Studio/android-ui-toolkit'
+	gitUrl = 'https://github.com/Supernova-Studio/android-ui-toolkit.git'
+
+	libraryVersion = '1.0.0'
+
+	developerId = 'supernova-studio'
+	developerName = 'Supernova Studio'
+	developerEmail = 'accounts.tech@supernova.studio'
+
+	licenseName = 'The Apache Software License, Version 2.0'
+	licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
+	allLicenses = ["Apache-2.0"]
+
+}
+
+apply from: 'install.gradle'
+apply from: 'bintray.gradle'

android-ui-toolkit/build.gradle

@@ -0,0 +1,39 @@
+apply plugin: 'com.github.dcendents.android-maven'
+
+group = publishedGroupId // Maven Group ID for the artifact
+
+install {
+	repositories.mavenInstaller {
+		// This generates POM.xml with proper parameters
+		pom.project {
+			packaging 'aar'
+			groupId publishedGroupId
+			artifactId artifact
+
+			name libraryName
+			description libraryDescription
+			url siteUrl
+
+			licenses {
+				license {
+					name licenseName
+					url licenseUrl
+				}
+			}
+			developers {
+				developer {
+					id developerId
+					name developerName
+					email developerEmail
+				}
+			}
+			scm {
+				connection gitUrl
+				developerConnection gitUrl
+				url siteUrl
+
+			}
+		}
+
+	}
+}