build.gradle

buildscript {
    ext {
        springBootVersion = '2.4.1'
        springDependencyManagementVersion = '1.0.10.RELEASE'
    }
}

plugins {
    id 'org.springframework.boot' version "${springBootVersion}"
    id 'io.spring.dependency-management' version "${springDependencyManagementVersion}"
    id 'java'
    id 'signing'
    id 'maven-publish'
}

repositories {
    mavenCentral()
    mavenLocal()
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}


bootJar.enabled(false)
jar.enabled(true)

allprojects {
    group 'io.easywalk'
    version '0.0.4.RELEASE'
}

subprojects {
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'signing'

    sourceCompatibility = '11'
    targetCompatibility = '11'

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
    }

    dependencies {
        implementation group: 'org.reflections', name: 'reflections', version: '0.9.12'
        implementation 'com.google.code.gson:gson:2.8.6'
        implementation 'org.springframework.boot:spring-boot-starter-validation'


        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        testImplementation('org.springframework.boot:spring-boot-starter-test') {
            exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
        }
    }


    task initSourceFolders {
        sourceSets*.java.srcDirs*.each {
            if (!it.exists()) {
                it.mkdirs()
            }
        }
        sourceSets*.resources.srcDirs*.each {
            if (!it.exists()) {
                it.mkdirs()
            }
        }

        def gradleFile = new File(projectDir, "build.gradle")
        if (!gradleFile.exists())
            gradleFile.text = ""
    }

    task javadocJar(type: Jar) {
        classifier = 'javadoc'
        from javadoc
    }

    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    artifacts {
        archives javadocJar, sourcesJar
    }

    signing {
        sign configurations.archives
    }

}


project(':simply-common') {

}

project(':simply-serviceable') {
    dependencies {
        implementation project(':simply-common')
    }
}

project(':simply-controllable') {
    dependencies {
        implementation project(':simply-common')
        implementation project(':simply-serviceable')
    }
}

project(':simply-eventable-kafka-binder') {
    dependencies {
        implementation project(':simply-common')
        implementation project(':simply-serviceable')
    }
}

project(':simply-clientable') {
    dependencies {
        implementation project(':simply-common')
    }
}