-
Notifications
You must be signed in to change notification settings - Fork 0
/
frames_category.lgt
188 lines (167 loc) · 6.81 KB
/
frames_category.lgt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
:- op(50, xfy, to).
:- category(frames_category).
:- info([
version is 2:0:0,
author is 'Paul Brown',
date is 2021-04-23,
comment is 'A Frame Collection is a dataset consisting of frames'
]).
:- uses(navltree, [
insert_in/4,
lookup_in/3,
update_in/4,
delete_in/4
]).
:- uses(avltree, [
keys/2,
lookup/3,
insert/4,
new/1 as new_dict/1
]).
:- public(new/1).
:- mode(new(--nested_dictionary), zero_or_more).
:- info(new/1, [
comment is 'An empty collection of frames',
argnames is ['EmptyFrameCollection']
]).
new(Frames) :-
new_dict(Frames).
:- public(subjects/2).
:- mode(subjects(++nested_dictionary, -list), one).
:- info(subjects/2, [
comment is 'The subjects in the frame collection',
argnames is ['FrameCollection', 'Subjects']
]).
subjects(Frames, Subjects) :-
keys(Frames, Subjects).
:- public(get_frame/3).
:- mode(get_frame(?nested_dictionary, ?atomic, +list), zero_or_more).
:- info(get_frame/3, [
comment is 'Read the value of the slots in the frame',
argnames is ['FrameCollection', 'Subject', 'Slots'],
exceptions is [
'``FrameCollection`` is a variable'-error(instantiation_error, logtalk(get_frame('FrameCollection', 'Subject', 'Slots'), 'Call'))
]
]).
get_frame(Collection, Subject, Slots) :-
( var(Collection)
-> instantiation_error
; var(Slots)
-> findall(Key-Value, get_slot(Collection, Subject, Key-Value), Slots)
; get_slots(Collection, Subject, Slots)
).
get_slots(_Collection, _Subject, []).
get_slots(Collection, Subject, [Slot|Slots]) :-
get_slot(Collection, Subject, Slot),
get_slots(Collection, Subject, Slots).
:- public(get_data/3).
:- mode(get_data(?nested_dictionary, ?atomic, ?pair), zero_or_more).
:- info(get_data/3, [
comment is 'Read the value of a slot in the frame with no reasoning',
argnames is ['FrameCollection', 'Subject', 'Key-Value'],
exceptions is [
'``FrameCollection`` is a variable'-error(instantiation_error, logtalk(get_data('FrameCollection', 'Subject', 'Key-Value'), 'Call'))
]
]).
get_data(Collection, _, _) :-
var(Collection),
instantiation_error.
% Direct from frame
get_data(Collection, Subject, Key-Value) :-
lookup_in([Subject, Key], Values, Collection),
set::member(Value, Values).
:- public(get_slot/3).
:- mode(get_slot(?nested_dictionary, ?atomic, ?pair), zero_or_more).
:- info(get_slot/3, [
comment is 'Get the value of a slot in the frame, includes read facet',
argnames is ['FrameCollection', 'Subject', 'Key-Value'],
exceptions is [
'``FrameCollection`` is a variable'-error(instantiation_error, logtalk(get_data('FrameCollection', 'Subject', 'Key-Value'), 'Call'))
]
]).
get_slot(Collection, _, _) :-
var(Collection),
instantiation_error.
get_slot(Collection, Subject, Key-Value) :-
get_data(Collection, Subject, Key-Value).
get_slot(Collection, Subject, Key-Value) :-
::calculate(Collection, Subject, Key-Value).
:- public(update_frame/4).
:- mode(update_frame(++nested_dictionary, +atomic, ++list(pair), -nested_dictionary), zero_or_one).
:- info(update_frame/4, [
comment is 'Update the ``FrameCollection`` so that the slots described by ``Subject`` are as described by the key-value pairs',
argnames is ['OldFrames', 'Subject', 'UpdatePairs', 'NewFrames']
]).
update_frame(OldFrames, Subject, [], NewFrames) :-
::after_update(OldFrames, Subject, NewFrames).
update_frame(OldFrames, Subject, [Pair|UpdatePairs], NewFrames) :-
once(unpack_pair(Pair, Key, OldValue, NewValue)),
update_frame_(OldFrames, Subject, Key, OldValue, NewValue, AccFrames0),
::after_update(AccFrames0, Subject, Key, OldValue, NewValue, AccFrames),
update_frame(AccFrames, Subject, UpdatePairs, NewFrames).
update_frame_(OldFrames, Subject, Key, OldValue, NewValue, AccFrames) :-
% to set, and so on down the object
lookup_in([Subject, Key], Values, OldFrames),
set::select(OldValue, Values, Subtracted),
set::insert(Subtracted, NewValue, NewValues),
update_in(OldFrames, [Subject, Key], NewValues, AccFrames).
unpack_pair(Key-OldValue to NewValue, Key, OldValue, NewValue) :-
nonvar(OldValue).
unpack_pair(Key-NewValue, Key, _OldValue, NewValue) :-
NewValue \= _ to _.
:- public(delete_frame/3).
:- mode(delete_frame(++nested_dictionary, +atomic, -nested_dictionary), one).
:- info(delete_frame/3, [
comment is 'Delete the frame associated with ``Subject`` from the frames',
argnames is ['OldFrames', 'Subject', 'NewFrames']
]).
delete_frame(OldFrames, Subject, NewFrames) :-
delete_in(OldFrames, [Subject], _Slots, AccFrames),
::after_delete_frame(AccFrames, Subject, NewFrames).
:- public(delete_frame/4).
:- mode(delete_frame(++nested_dictionary, +atomic, +list(pair), -nested_dictionary), one).
:- info(delete_frame/4, [
comment is 'Delete the pairs associated with ``Subject`` from the frames. Keys must be ground, values will unify.',
argnames is ['OldFrames', 'Subject', 'Pairs', 'NewFrames']
]).
delete_frame(OldFrames, Subject, [], NewFrames) :-
::after_delete_slots(OldFrames, Subject, NewFrames).
delete_frame(OldFrames, Subject, [Key-Value|DeletePairs], NewFrames) :-
delete_frame_(OldFrames, Subject, Key, Value, AccFrames0),
::after_delete_slot(AccFrames0, Subject, Key, Value, AccFrames),
delete_frame(AccFrames, Subject, DeletePairs, NewFrames).
delete_frame_(OldFrames, Subject, Key, Value, AccFrames):-
lookup_in([Subject, Key], Values, OldFrames),
set::select(Value, Values, Subtracted),
( set::empty(Subtracted)
-> delete_in(OldFrames, [Subject, Key], Values, AccFrames)
; update_in(OldFrames, [Subject, Key], Subtracted, AccFrames)
).
:- public(add_frame/4).
:- mode(add_frame(++nested_dictionary, +atomic, ++list(pair), -nested_dictionary), zero_or_one).
:- info(add_frame/4, [
comment is 'Add to the ``FrameCollection`` so that the slots described by ``Subject`` are as described by the key-value pairs',
argnames is ['OldFrames', 'Subject', 'UpdatePairs', 'NewFrames']
]).
add_frame(OldFrames, Subject, Slots, NewFrames) :-
atomic(Subject),
( lookup(Subject, _, OldFrames)
-> OldFrames = AccFrames
; new_dict(Empty),
insert(OldFrames, Subject, Empty, AccFrames)
),
add_frame_slots(AccFrames, Subject, Slots, AccFrames0),
::after_add(AccFrames0, Subject, NewFrames).
add_frame_slots(OldFrames, _Subject, [], OldFrames).
add_frame_slots(OldFrames, Subject, [Key-NewValue|UpdatePairs], NewFrames) :-
ground([Subject, Key, NewValue]),
add_frame_slots_(OldFrames, Subject, Key, NewValue, AccFrames0),
::after_add(AccFrames0, Subject, Key, NewValue, AccFrames),
add_frame_slots(AccFrames, Subject, UpdatePairs, NewFrames).
add_frame_slots_(OldFrames, Subject, Key, NewValue, AccFrames) :-
( lookup_in([Subject, Key], Values, OldFrames)
-> set::insert(Values, NewValue, Updated),
update_in(OldFrames, [Subject, Key], Updated, AccFrames)
; insert_in(OldFrames, [Subject, Key], [NewValue], AccFrames)
).
:- end_category.