-
Notifications
You must be signed in to change notification settings - Fork 0
/
ugreenfoot.pas
2561 lines (2344 loc) · 81.6 KB
/
ugreenfoot.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(******************************************************************************)
(* *)
(* Author : Uwe Schächterle (Corpsman) *)
(* *)
(* This file is part of Greenfoot for Lazarus *)
(* *)
(* See the file license.md, located under: *)
(* https://github.com/PascalCorpsman/Software_Licenses/blob/main/license.md *)
(* for details about the license. *)
(* *)
(* It is not allowed to change or remove this text from any *)
(* source file of the project. *)
(* *)
(******************************************************************************)
(*
* This Unit implements some of the Greenfoot Base Classes
* If you want to create a new World you have to derive it from TWorld
* Use TActor to create Actors in your World. For Further informations read
* the beginning comment of unit1.pas from this project.
*
* Original Dokumentation :
* http://www.greenfoot.org/files/javadoc/greenfoot/package-summary.html
*
* The version of this unit is : 0.01
*
*
* History : 0.01 = Initial version
* TWorld, TActor, TGreenfootImage, TRandomizer
*)
Unit ugreenfoot;
{$MODE objfpc}{$H+}
Interface
Uses
Classes, SysUtils,
FileUtil,
dglOpenGL, // http://wiki.delphigl.com/index.php/dglOpenGL.pas
math,
uvectormath, // http://corpsman.de/index.php?doc=opengl/opengl_graphikengine
OpenGLContext, // TOpenGLControl ( default komponente unter Lazarus )
graphics;
Type
TMouseButton = (MB_None = 0, MB_Left = 1, MB_Middle = 2, MB_Right = 3);
TMouseState = (MS_ButtonsDown, MS_Moving);
TMouseStateSet = Set Of TMouseState;
TKeys = // Alle Tasten, welche durch den Benutzer abgefragt werden können
(
key_a, key_b, key_c, key_d, key_e, key_f, key_g, key_h, key_i, key_j, // Fertig
key_k, key_l, key_m, key_n, key_o, key_p, key_q, key_r, key_s, key_t, // Fertig
key_u, key_v, key_w, key_x, key_y, key_z, // Fertig
key_up, key_down, key_left, key_right, // Fertig
key_enter, key_space, key_tab, key_escape, key_backspace, key_shift, key_control,
key_f1, key_f2, key_f3, key_f4, key_f5, key_f6, key_f7, key_f8, key_f9, key_f10, key_f11, key_f12,
key_None
);
TSpeedCallback = Procedure(Sender: TObject; NewSpeed: integer; Visible: Boolean) Of Object;
TCallbacks = Record // List of all Callbacks which are needed to Controll the Main App
StartEvent: TNotifyEvent;
StopEvent: TNotifyEvent;
SpeedCallback: TSpeedCallback;
End;
TGreenFootColor = Record
Red: Byte;
Green: Byte;
Blue: Byte;
Alpha: BYte;
End;
TActor = Class;
TActorList = Array Of TActor;
TGreenfootImage = Class;
TActorData = Record
Actor: TActor;
x, y, rotation: integer;
End;
TSortedClasses = Record
Class_: TClass;
Elements: Array Of Integer;
End;
{ TGreenfootBase }
TGreenfootBase = Class
private
FWidth: Integer; // Die Breite in Pixeln
fHeight: integer; // Die Höhe in Pixeln
FImage: TGreenfootImage; // Das Bild
public
Name: String; // Einfach nur so, falls jemand den setzen will
Constructor create(); virtual;
Destructor destroy; override;
End;
{ TWorld }
TWorld = Class(TGreenfootBase)
private
FActOrderClasses: Array Of TClass; // Speichert die ActOrder
FActClasses: Array Of Array Of Integer; // Alle Objecte in ihrer "Act" Order
FPaintOrderClasses: Array Of TClass; // Speichert in welcher Reihenfolge Objekte gerendert werden sollen ( ist wichtig, da es keinen Tiefenpuffer gibt )
FPaintClasses: Array Of Array Of Integer; // Hier werden alle Objecte Eingetragen und entsprechend gerendert.
FObjects: Array Of TActorData; // Die Actoren die in der Welt Aggieren
fParent: TOpenGLControl; // Das OpenGLControl in dem die Welt gerendert wird.
fSortedClasses: Array Of TSortedClasses; // Zur Beschleunigung von Intersect Routinen sind alle Objekte Sortiert nach Typ hinterlegt
ftoDeleteList: Array Of TActor;
fworldHeight: integer; // Die Welthöhe gemessen in "Zellen"
fworldWidth: integer; // Die Weltbreite gemessen in "Zellen"
fcellsize: integer; // Die Zellengröße
fBounded: Boolean; // Gibt an ob die Welt ein Donut ist oder nicht
Procedure removeObject_helper(Object_: TActor); // Löscht ein Object aus der Welt
public
(*
* Der Ursprung ist unten Links ( nicht wie bei Windows oben Rechts !! )
*)
Constructor create(Parent: TOpenGLControl; worldWidth, worldHeight, cellSize: integer; bounded: Boolean = false); reintroduce;
Destructor destroy(); override;
Procedure SystemAct(); // Führt einen Act Schritt aller Objecte aus
Procedure Act(); virtual; // Auch die Welt hat einen "Act"
Procedure addObject(Object_: TActor; x, y: integer);
Function getBackground(): TGreenfootImage;
Function getHeight(): integer; // Gibt die Welt Höhe in Zellen zurück
Function getCellSize(): integer; // Gibt die ZUellengröße zurück
Function getColorAt(x, y: integer): TGreenFootColor;
Function getOneObject(Object_: TClass): TActor; // Gibt genau ein Object der gesuchten Klasse zurück, wenn Object_ = nil, dann wird das 1. Object zurückggeben
Function getObjects(Object_: TClass): TActorList;
Function getOneObjectAt(x, y: integer; Object_: TClass): TActor;
Function getObjectsAt(x, y: integer; Object_: TClass): TActorList; // Gibt eine Liste der Objecte Zurück, welche alle den Mittelpunkt der Zelle x,y überdecken
Function getWidth(): integer; // Gibt die Welt Breite in Zellen zurück
Procedure removeObject(Object_: TActor); // Löscht ein Object aus der Welt
Procedure removeObjects(Objectlist: TActorList); // Löscht ein Object aus der Welt
Procedure rePaint(); // Do not Call this Method, it is used by the Greenfoot Simulating System
Procedure setActOrder(Const Order: Array Of TClass);
Procedure setBackground(Filename: String);
Procedure setBackground(Const Image: TGreenfootImage);
Procedure setPaintOrder(Const Order: Array Of TClass);
End;
{ TActor }
TActor = Class(TGreenfootBase)
private
fworld: TWorld;
FIndexInWorld: integer; // Beschleunigt den Zugriff auf das Objekt in der Welt.
FisAlive: Boolean; // Wenn True, dann ist das Object in einer TWorld und am Leben, wenn False, dann wartet es auf sein Löschen
FWorldRotation: Integer; // Wird nur benutzt, falls diese Werte schon zugewiesen werden bevor das Objekt in die Welt geadded wird.
Function clone: TActor; // Erzeugt eine Neue Instanz der Klasse ( klappt auch mit Kindklassen )
protected
Procedure act(); virtual;
Procedure addedToWorld(Const World: TWorld); virtual; // Wird Aufgerufen, wenn der TActor Erfolgreich in die Welt eingegliedert wurde
public
Constructor create(); override;
Destructor destroy; override;
Function getHeight: integer;
Function getImage(): TGreenfootImage;
Function getIntersectingObjects(cls: TClass): TActorList;
Function getNeighbours(distance: integer; diagonal: Boolean; cls: TClass): TActorList;
Function getOneObjectAtOffset(dx, dy: integer; cls: TClass): Tactor;
Function getOneIntersectingObject(cls: TClass): TActor;
Function getObjectsInRange(radius: integer; cls: TClass): TActorList;
Function getRotation(): integer;
Function getWidth: integer;
Function getWorld(): TWorld;
Function getx: integer;
Function gety: integer;
Function intersects(Const Other: TActor): Boolean;
Procedure rePaint(); // Do not Call this Method, it is used by the Greenfoot Simulating System
Procedure setImage(Filename: String);
Procedure setImage(Image: TGreenfootImage);
Procedure setLocation(x, y: integer; ThrowExceptionOnLeaveWorld: Boolean = True);
Procedure setRotation(rotation: integer);
End;
{ TGreenfootImage }
TGreenfootImage = Class
private
FRohdaten: Array Of Array[0..3] Of Byte; // Eine Schattenkopie von dem Was im OpenGL Buffer ist.
FimageTexCoords: Array[0..1] Of TVector2; // Die Zugehörigen Texturkoordinaten
Fimage: integer; // Der BildPointer im OpenGL Buffer
fWidth: integer; // Die nach außen Sichtbare "Echte" Breite des Bildes
fHeight: Integer; // Die nach außen Sichtbare "Echte" Höhe des Bildes
fWidthHalf: integer; // Die hälfte der Breite (nur Intern gebraucht)
fHeightHalf: Integer; // Die hälfte der Höhe (nur Intern gebraucht)
fCurrentColor: TGreenFootColor; // Die Aktuelle Farbe des Pinsels
fOpenGLWidth, FOpenGLHeight: integer; // Die Breite und Höhe im OpenGL Buffer
fUpdateing: integer; // Hilft bei Begin / Endupdate
fOwnedByGraphikEngine: Boolean; // True, wenn das Bild der GraphikEngine hinzugefügt wurde -> dann kümmert sich die GraphikEngine um das Freigeben
Function FileToBitmap(Filename: String): TBitmap; // Wandelt eine "Datei" in ein TBitmap um, das dann weiter verarbetet werden kann
public
FontSize: integer; // Legt fest wie Hoch die Schrift in Pixeln sein soll ( - Height Spiegelt an der X-Achse )
Constructor Create(Filename: String);
Constructor Create(Width, Height: Integer);
Constructor Create(Image: TGreenfootImage);
Destructor destroy(); override;
Procedure clear();
Procedure drawImage(Const img: TGreenfootImage; x, y: integer);
Procedure drawLine(x1, y1, x2, y2: integer);
Procedure drawOval(x, y, width, height: integer);
Procedure drawPolygon(xPoints, yPoints: Array Of Integer; npoints: integer);
Procedure drawRect(x, y, width, height: integer);
Procedure drawString(String_: String; x, y: integer);
Procedure fillOval(x, y, width, height: integer);
Procedure fillPolygon(xPoints, yPoints: Array Of Integer; npoints: integer);
Procedure fillRect(x, y, width, height: integer);
Function GetColorAt(x, y: integer): TGreenFootColor;
Function GetHeight: integer;
Function GetWidth: integer;
Procedure RePaint(); // Do not Call this Method, it is used by the Greenfoot Simulating System
Procedure Rotate(degrees: integer);
Procedure Scale(Width, Height: integer);
Procedure SetColor(Color: TGreenFootColor);
Procedure SetColorAt(x, y: integer; Color: TGreenFootColor);
Procedure mirrorHorizontally();
Function TextWidth(Text: String): integer; // Gibt die Breite eines Textes in Pixeln zurück
Function TextHeight(Text: String): integer; // Gibt die Höhe eines Textes in Pixeln zurück
(*
* Diese beiden Routinen sind nicht unbedingt notwendig,
* Sie beschleunigen aber den Pixelweisen Zugriff, wenn "Viele" Pixel geändert werden.
*)
Procedure BeginUpdate();
Procedure EndUpdate();
End;
{ TGreenFootGraphicEngine }
(*
* Diese Klasse stellt einen Globalen Container zum Arbeiten mit Graphiken
* zur Verfügung. Die Einmal hinzugefügten Graphiken, werden automatisch wieder
* Freigegeben.
*)
TGreenFootGraphicEngine = Class
private
FImages: Array Of TGreenfootImage;
fNames: Array Of String;
public
Constructor create();
Destructor destroy; override;
Procedure AddImage(Const Image: TGreenfootImage; Name: String);
Function FindImage(Name: String): TGreenfootImage;
Procedure Clear(); // Löscht - entfernt alle in der Engine Registrierten Bilder (bei Reset Notwendig, sollte nicht durch User aufgerufen werden!)
End;
{ TRandomizer }
TRandomizer = Class
private
State: integer;
in1, in2, out1, out2: Double;
Procedure Boxmuller(g1, g2: Double; Out s1, s2: Double);
public
Constructor create;
Function nextGaussian: Single; // Berechnet eine Standart Normal Verteilte Zufallsvariable nach dem BoxMuller Verfahren
Function nextInt(limit: Integer): Integer;
End;
{ TMouseInfo }
TMouseInfo = Class
private
fOnMouseDownActor: TActor; // Der Actor, der sich unter der Maus befand als der MouseDown Event Kam !
fOnMouseUpActor: TActor; // Der Actor, der sich unter der Maus befand als der MouseDown Event Kam !
fOnMoveActor: TActor;
fx, fy: integer;
fWorld: TWorld;
fMouseState: TMouseStateSet;
fMouseButtondown, fMouseButtonup: TMouseButton;
public
Constructor create;
Function getActor(): TActor;
Function getButton(): TMouseButton;
Function getClickCount(): integer;
Function getX(): integer;
Function getY(): integer;
Procedure MouseDown(Const World: TWorld; x, y: integer; Shift: TShiftState); // Do not Call this Method, it is used by the Greenfoot Simulating System
Procedure MouseMove(Const World: TWorld; x, y: integer); // Do not Call this Method, it is used by the Greenfoot Simulating System
Procedure MouseUp(); // Do not Call this Method, it is used by the Greenfoot Simulating System
Procedure Reset(); // Do not Call this Method, it is used by the Greenfoot Simulating System
End;
Const
white: TGreenFootColor = (Red: $FF; Green: $FF; Blue: $FF; Alpha: 255);
light_gray: TGreenFootColor = (Red: $C0; Green: $C0; Blue: $C0; Alpha: 255);
gray: TGreenFootColor = (Red: $80; Green: $80; Blue: $80; Alpha: 255);
dark_gray: TGreenFootColor = (Red: $40; Green: $40; Blue: $40; Alpha: 255);
black: TGreenFootColor = (Red: $00; Green: $00; Blue: $00; Alpha: 255);
red: TGreenFootColor = (Red: $FF; Green: $00; Blue: $00; Alpha: 255);
pink: TGreenFootColor = (Red: $FF; Green: $AF; Blue: $AF; Alpha: 255);
orange: TGreenFootColor = (Red: $FF; Green: $C8; Blue: $00; Alpha: 255);
yellow: TGreenFootColor = (Red: $FF; Green: $FF; Blue: $00; Alpha: 255);
green: TGreenFootColor = (Red: $00; Green: $FF; Blue: $00; Alpha: 255);
magenta: TGreenFootColor = (Red: $FF; Green: $00; Blue: $FF; Alpha: 255);
cyan: TGreenFootColor = (Red: $00; Green: $FF; Blue: $FF; Alpha: 255);
blue: TGreenFootColor = (Red: $00; Green: $00; Blue: $FF; Alpha: 255);
Var
Randomizer: TRandomizer; // Der Zufallszahlengenerator steht immer zur Verfügung.
GreenFootGraphicEngine: TGreenFootGraphicEngine;
MouseInfo: TMouseInfo;
(*
* Basis Routinen, welche durch die Library zur Verfügung gestellt werden
*)
Operator = (a, b: TGreenFootColor): Boolean;
Function Color(Red, Green, Blue: byte): TGreenFootColor; overload; // Wandelt RGB Farben in TGreenFootColor um.
Function Color(Red, Green, Blue, Alpha: byte): TGreenFootColor; overload; // Wandelt RGB Farben in TGreenFootColor um.
Function getMouseInfo(): TMouseInfo;
Function getRandomNumber(limit: integer): integer; // Liefert eine Gleichverteilte Zufallsvariable im x mit 0 <= x < Limit
Function isKeyDown(keyname: String): Boolean; overload;
Function isKeyDown(key: TKeys): Boolean; overload;
Procedure Start();
Procedure Stop();
Procedure SetSpeed(Speed: integer; AllowFurtherChanges: Boolean = true);
Procedure PlaySound(Filename: String);
Function mouseDragged(Obj_: TGreenfootBase): Boolean;
Function mouseDragEnded(Obj_: TGreenfootBase): Boolean;
Function mouseClicked(Obj_: TGreenfootBase): Boolean;
(*
* All Routines below this line should never be called by the user !!
*)
Procedure InitSystem(Callbacks: TCallbacks); // Will be called by the Main App to Register all Needed Callback.
Procedure Keypressed(value: TKeys);
Procedure KeyReleased(value: TKeys);
Procedure ReleaseAllKeys();
Procedure Nop(); // Zum Debuggen, wenn man nen Haltepunkt setzen möchte ..
Implementation
Uses IntfGraphics, LResources, LConvEncoding, LazFileUtils, lazutf8,
fpImage // TFPColor type
;
Const
CharWidth = 8;
Charheight = 12;
Type
TLetter = Array Of Array Of boolean;
{ TGreenFootHelperFont }
TGreenFootHelperFont = Class // stellt eine Wrapperklasse für das Pixelbasierte Schreiben in FRohdaten zur Verfügung.
private
fCharWidth: integer;
fCharHeight: Integer;
Letters: Array[0..255] Of TLetter; // Speichert die Punkte Liste der Pixel
fDefaultHeight: integer;
Procedure DrawLetter(Const Image: TGreenfootImage; X, Y, Width, Height, Letter: integer);
public
Property DefaultHeight: integer read fDefaultHeight;
Constructor create();
Destructor destroy(); override;
Procedure Textout(Image: TGreenfootImage; x, y: Integer; Text: String);
End;
Var
GreenFootHelperFont: TGreenFootHelperFont;
GreenFootCallbacks: TCallbacks;
VirtualKeys: Array[TKeys] Of boolean;
RecentKey: TKeys;
oldMouseState: TMouseStateSet;
Procedure Nop();
Begin
End;
Function FPColorToColor(Const Color: TFPColor): TColor;
Begin
result := byte(color.red Shr 8) Or (color.green And $FF00) Or ((color.blue And $FF00) Shl 8);
End;
Function getMouseInfo: TMouseInfo;
Begin
result := MouseInfo;
End;
Function getRandomNumber(limit: integer): integer;
Begin
result := Randomizer.nextInt(limit);
End;
Operator = (a, b: TGreenFootColor): Boolean;
Begin
result := (a.Red = b.Red) And
(a.Green = b.Green) And
(a.Blue = b.Blue) And
(a.Alpha = b.Alpha);
End;
Function GetNextUpperPowerOfTwo(Value: Integer): Integer;
Var
i: Integer;
Begin
i := 1;
While i < Value Do
i := i Shl 1;
result := i;
End;
Function Color(Red, Green, Blue: byte): TGreenFootColor; overload;
Begin
result.Red := red;
result.Green := Green;
result.Blue := Blue;
result.Alpha := 255; // Eine Farbe ohne Transparenz ist Opak
End;
Function Color(Red, Green, Blue, Alpha: byte): TGreenFootColor; overload;
Begin
result.Red := red;
result.Green := Green;
result.Blue := Blue;
result.Alpha := Alpha;
End;
Procedure Go2d(Width, Height: integer);
Begin
glMatrixMode(GL_PROJECTION);
glPushMatrix(); // Store The Projection Matrix
glLoadIdentity(); // Reset The Projection Matrix
glOrtho(0, Width, height, 0, -1, 1); // Set Up An Ortho Screen
glMatrixMode(GL_MODELVIEW);
glPushMatrix(); // Store old Modelview Matrix
glLoadIdentity(); // Reset The Modelview Matrix
End;
Procedure Exit2d();
Begin
glMatrixMode(GL_PROJECTION);
glPopMatrix(); // Restore old Projection Matrix
glMatrixMode(GL_MODELVIEW);
glPopMatrix(); // Restore old Projection Matrix
End;
Function mouseDragged(Obj_: TGreenfootBase): Boolean;
Begin
result := MouseInfo.fOnMouseDownActor = obj_;
End;
Function mouseDragEnded(Obj_: TGreenfootBase): Boolean;
Begin
result := MouseInfo.fOnMouseUpActor = obj_;
// Das Tut noch nicht unbedingt so wie es soll, aber es geht schon ein bischen..
End;
Function mouseClicked(Obj_: TGreenfootBase): Boolean;
Begin
result := (MS_ButtonsDown In oldMouseState) And
(Not (MS_ButtonsDown In MouseInfo.fMouseState));
If result And assigned(obj_) Then Begin
result := obj_ = MouseInfo.fOnMouseUpActor;
End;
End;
Procedure InitSystem(Callbacks: TCallbacks);
Begin
GreenFootCallbacks := Callbacks;
ReleaseAllKeys();
End;
Procedure Keypressed(value: TKeys);
Begin
VirtualKeys[value] := true;
RecentKey := value;
End;
Procedure KeyReleased(value: TKeys);
Begin
VirtualKeys[value] := false;
RecentKey := key_None;
End;
Procedure ReleaseAllKeys;
Var
i: TKeys;
Begin
For i := low(VirtualKeys) To high(VirtualKeys) Do
VirtualKeys[i] := false;
RecentKey := key_None;
End;
Function isKeyDown(keyname: String): Boolean; overload;
Begin
keyname := lowercase(keyname);
result := false;
Case keyname Of
'up': result := isKeyDown(key_up);
'down': result := isKeyDown(key_down);
'left': result := isKeyDown(key_left);
'right': result := isKeyDown(key_right);
'space': result := isKeyDown(key_space);
'a': result := isKeyDown(key_a);
'b': result := isKeyDown(key_b);
'c': result := isKeyDown(key_c);
'd': result := isKeyDown(key_d);
'e': result := isKeyDown(key_e);
'f': result := isKeyDown(key_f);
'g': result := isKeyDown(key_g);
'h': result := isKeyDown(key_h);
'i': result := isKeyDown(key_i);
'j': result := isKeyDown(key_j);
'k': result := isKeyDown(key_k);
'l': result := isKeyDown(key_l);
'm': result := isKeyDown(key_m);
'n': result := isKeyDown(key_n);
'o': result := isKeyDown(key_o);
'p': result := isKeyDown(key_p);
'q': result := isKeyDown(key_q);
'r': result := isKeyDown(key_r);
's': result := isKeyDown(key_s);
't': result := isKeyDown(key_t);
'u': result := isKeyDown(key_u);
'v': result := isKeyDown(key_v);
'w': result := isKeyDown(key_w);
'x': result := isKeyDown(key_x);
'y': result := isKeyDown(key_y);
'z': result := isKeyDown(key_z);
End;
End;
Function isKeyDown(key: TKeys): Boolean;
Begin
result := VirtualKeys[key];
End;
Procedure Start;
Begin
GreenFootCallbacks.StartEvent(Nil);
End;
Procedure Stop();
Begin
GreenFootCallbacks.StopEvent(Nil);
End;
Procedure SetSpeed(Speed: integer; AllowFurtherChanges: Boolean = true);
Begin
GreenFootCallbacks.SpeedCallback(Nil, speed, AllowFurtherChanges);
End;
Procedure PlaySound(Filename: String);
Begin
// Todo : PlaySound
End;
{ TGreenfootBase }
Constructor TGreenfootBase.create;
Begin
Inherited create;
fWidth := 0;
fHeight := 0;
fImage := Nil;
name := Self.ClassName;
End;
Destructor TGreenfootBase.destroy;
Begin
End;
{ TMouseInfo }
Constructor TMouseInfo.create;
Begin
Inherited create;
reset;
End;
Function TMouseInfo.getActor: TActor;
Begin
If assigned(fOnMouseDownActor) Then Begin
result := fOnMouseDownActor;
End
Else Begin
If assigned(fworld) Then Begin
result := fworld.getOneObjectAt(fx, fy, Nil);
End
Else Begin
result := Nil;
End;
End;
End;
Function TMouseInfo.getButton: TMouseButton;
Begin
// Todo : TMouseInfo.getButton
result := fMouseButtonUp;
End;
Function TMouseInfo.getClickCount: integer;
Begin
// Todo : TMouseInfo.getClickCount
result := 0;
End;
Function TMouseInfo.getX: integer;
Begin
result := fx;
End;
Function TMouseInfo.getY: integer;
Begin
result := fy;
End;
Procedure TMouseInfo.MouseDown(Const World: TWorld; x, y: integer;
Shift: TShiftState);
//Var
// img: TGreenfootImage;
Begin
fOnMouseUpActor := Nil;
fx := x;
fy := y;
fOnMouseDownActor := World.getOneObjectAt(x, y, Nil);
// If assigned(fOnMouseDownActor) Then Begin
// img := TGreenfootImage.Create(fOnMouseDownActor.getImage());
// img.clear();
// fOnMouseDownActor.setImage(img);
// End;
fOnMoveActor := fOnMouseDownActor;
fMouseState := fMouseState + [MS_ButtonsDown];
fMouseButtonup := MB_None;
If ssRight In Shift Then Begin
fMouseButtondown := MB_Right;
End
Else Begin
If ssMiddle In Shift Then Begin
fMouseButtondown := MB_Middle;
End
Else Begin
If ssLeft In Shift Then Begin
fMouseButtondown := MB_Left;
End
Else Begin
fMouseButtondown := MB_None;
End;
End;
End;
End;
Procedure TMouseInfo.MouseMove(Const World: TWorld; x, y: integer);
Begin
fMouseState := fMouseState + [MS_Moving];
fOnMouseUpActor := Nil;
fx := x;
fy := y;
End;
Procedure TMouseInfo.MouseUp;
Begin
fOnMouseUpActor := fOnMouseDownActor;
fOnMouseDownActor := Nil;
fMouseState := fMouseState - [MS_ButtonsDown];
fMouseButtonup := fMouseButtondown;
End;
Procedure TMouseInfo.Reset;
Begin
fOnMouseUpActor := Nil;
fOnMouseDownActor := Nil;
fWorld := Nil;
fMouseState := [];
fMouseButtondown := MB_None;
fMouseButtonup := MB_None;
End;
{ TGreenFootGraphicEngine }
Constructor TGreenFootGraphicEngine.create();
Begin
Inherited create;
setlength(FImages, 0);
setlength(fNames, 0);
End;
Destructor TGreenFootGraphicEngine.destroy;
Begin
Clear();
End;
Procedure TGreenFootGraphicEngine.AddImage(Const Image: TGreenfootImage;
Name: String);
Var
img: TGreenfootImage;
Begin
img := FindImage(Name);
If assigned(img) Then Begin
Raise exception.create('Error, you are not allowed to add two images with the same name.');
End;
Image.fOwnedByGraphikEngine := true;
setlength(fNames, high(fNames) + 2);
setlength(FImages, high(FImages) + 2);
fnames[high(fNames)] := LowerCase(Name);
FImages[high(FImages)] := Image;
End;
Function TGreenFootGraphicEngine.FindImage(Name: String): TGreenfootImage;
Var
i: integer;
Begin
result := Nil;
name := lowercase(name);
For i := 0 To high(fNames) Do Begin
If fNames[i] = Name Then Begin
result := FImages[i];
exit;
End;
End;
End;
Procedure TGreenFootGraphicEngine.Clear();
Var
i: Integer;
Begin
For i := 0 To high(FImages) Do
FImages[i].Free;
setlength(FImages, 0);
setlength(fNames, 0);
End;
{ TGreenfootImage }
Constructor TGreenfootImage.Create(Filename: String);
Var
b: TBitmap;
i, j, c: integer;
IntfImg1: TLazIntfImage;
col: TFPColor;
Begin
Inherited create;
fOwnedByGraphikEngine := false;
FontSize := GreenFootHelperFont.DefaultHeight;
fUpdateing := 0;
fCurrentColor := Color(0, 0, 0, 0);
b := FileToBitmap(Filename);
IntfImg1 := TLazIntfImage.Create(0, 0);
IntfImg1.LoadFromBitmap(B.Handle, B.MaskHandle);
fOpenGLWidth := GetNextUpperPowerOfTwo(b.Width);
FOpenGLHeight := GetNextUpperPowerOfTwo(b.Height);
fWidth := b.Width;
fHeight := b.Height;
fWidthHalf := fWidth Div 2;
fHeightHalf := fHeight Div 2;
FimageTexCoords[0] := v2(0, fHeight / FOpenGLHeight);
FimageTexCoords[1] := v2(fWidth / fOpenGLWidth, 0);
SetLength(FRohdaten, fOpenGLWidth * FOpenGLHeight);
c := 0;
For j := 0 To FOpenGLHeight - 1 Do Begin
For i := 0 To fOpenGLWidth - 1 Do Begin
If (i < fWidth) And (j < fHeight) Then Begin
col := IntfImg1.Colors[i, j];
// Berücksichtigen der Transparenz ( clFuchsia = Durchsichtig )
If (col.red And $FF00 = $FF00) And
(col.green And $FF00 = $0000) And
(col.blue And $FF00 = $FF00) Then Begin
FRohdaten[c][0] := 0;
FRohdaten[c][1] := 0;
FRohdaten[c][2] := 0;
FRohdaten[c][3] := 0; // Komplett Durchsichtig
End
Else Begin
FRohdaten[c][0] := col.red Div 256;
FRohdaten[c][1] := col.green Div 256;
FRohdaten[c][2] := col.blue Div 256;
FRohdaten[c][3] := 255; // Komplett Opak
End;
End
Else Begin // Bildbereiche Auserhalb des Sichtbaren
// CLNone
FRohdaten[c][0] := 0;
FRohdaten[c][1] := 0;
FRohdaten[c][2] := 0;
FRohdaten[c][3] := 0; // Komplett Durchsichtig
End;
inc(c);
End;
End;
IntfImg1.free;
b.free;
glGenTextures(1, @Fimage);
glBindTexture(GL_TEXTURE_2D, fimage);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, fOpenGLWidth, FOpenGLHeight, 0, GL_RGBA, GL_UNSIGNED_BYTE, @FRohdaten[0][0]);
End;
Constructor TGreenfootImage.Create(Width, Height: Integer);
Var
i: Integer;
Begin
Inherited create;
fOwnedByGraphikEngine := false;
FontSize := GreenFootHelperFont.DefaultHeight;
fUpdateing := 0;
fCurrentColor := Color(0, 0, 0, 0);
fOpenGLWidth := GetNextUpperPowerOfTwo(Width);
FOpenGLHeight := GetNextUpperPowerOfTwo(Height);
fWidth := Width;
fHeight := Height;
fWidthHalf := fWidth Div 2;
fHeightHalf := fHeight Div 2;
FimageTexCoords[0] := v2(0, fHeight / FOpenGLHeight);
FimageTexCoords[1] := v2(fWidth / fOpenGLWidth, 0);
setlength(FRohdaten, fOpenGLWidth * FOpenGLHeight);
For i := 0 To high(FRohdaten) Do Begin
FRohdaten[i][0] := 0;
FRohdaten[i][1] := 0;
FRohdaten[i][2] := 0;
FRohdaten[i][3] := 0;
End;
// Der OpenGL Teil
glGenTextures(1, @Fimage);
glBindTexture(GL_TEXTURE_2D, fimage);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, fOpenGLWidth, FOpenGLHeight, 0, GL_RGBA, GL_UNSIGNED_BYTE, @FRohdaten[0][0]);
End;
Constructor TGreenfootImage.Create(Image: TGreenfootImage);
Var
i: Integer;
Begin
Inherited create;
fOwnedByGraphikEngine := false;
FontSize := GreenFootHelperFont.DefaultHeight;
fUpdateing := 0;
fCurrentColor := Color(0, 0, 0, 0);
fOpenGLWidth := GetNextUpperPowerOfTwo(image.fWidth);
FOpenGLHeight := GetNextUpperPowerOfTwo(image.fHeight);
fWidth := image.fWidth;
fHeight := image.fHeight;
fWidthHalf := fWidth Div 2;
fHeightHalf := fHeight Div 2;
FimageTexCoords[0] := image.FimageTexCoords[0];
FimageTexCoords[1] := image.FimageTexCoords[1];
setlength(FRohdaten, fOpenGLWidth * FOpenGLHeight);
For i := 0 To high(FRohdaten) Do Begin
FRohdaten[i][0] := image.FRohdaten[i][0];
FRohdaten[i][1] := image.FRohdaten[i][1];
FRohdaten[i][2] := image.FRohdaten[i][2];
FRohdaten[i][3] := image.FRohdaten[i][3];
End;
// Der OpenGL Teil
glGenTextures(1, @Fimage);
glBindTexture(GL_TEXTURE_2D, fimage);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, fOpenGLWidth, FOpenGLHeight, 0, GL_RGBA, GL_UNSIGNED_BYTE, @FRohdaten[0][0]);
End;
Destructor TGreenfootImage.destroy;
Begin
setlength(FRohdaten, 0);
glDeleteTextures(1, @fimage);
End;
Function TGreenfootImage.FileToBitmap(Filename: String): TBitmap;
Var
p: TPortableNetworkGraphic;
j: TJPEGImage;
Begin
If Not FileExistsUTF8(Filename) Then Begin
Raise exception.create('Error could not Find : "' + Filename + '"');
End;
result := TBitmap.create;
If lowercase(ExtractFileExt(filename)) = '.bmp' Then Begin
result.LoadFromFile(utf8tosys(Filename));
End
Else Begin
If lowercase(ExtractFileExt(filename)) = '.png' Then Begin
p := TPortableNetworkGraphic.Create;
p.LoadFromFile(utf8tosys(Filename));
result.Assign(p);
p.free;
End
Else Begin
If lowercase(ExtractFileExt(filename)) = '.jpg' Then Begin
j := TJPEGImage.Create;
j.LoadFromFile(utf8tosys(Filename));
result.Assign(j);
j.free;
End
Else Begin
Raise exception.create('Error unsupported file format : "' + Filename + '"');
End;
End;
End;
End;
Procedure TGreenfootImage.clear;
Var
i: Integer;
Begin
fCurrentColor := Color(0, 0, 0, 0);
For i := 0 To high(FRohdaten) Do Begin
FRohdaten[i][0] := 0;
FRohdaten[i][1] := 0;
FRohdaten[i][2] := 0;
FRohdaten[i][3] := 0;
End;
If fUpdateing = 0 Then Begin
glBindTexture(GL_TEXTURE_2D, fimage);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
glTexSubImage2D(gl_texture_2d, 0, 0, 0, fOpenGLWidth, FOpenGLHeight, GL_RGBA, GL_UNSIGNED_BYTE, @Frohdaten[0][0]);
End;
End;
Procedure TGreenfootImage.RePaint;
Var
b: Boolean;
Begin
B := glIsEnabled(gl_Blend);
If Not b Then
glenable(gl_Blend);
If Fimage <> 0 Then Begin
glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
glColor4f(1, 1, 1, 1);
glBindTexture(GL_TEXTURE_2D, FImage);
glBegin(GL_QUADS);
// glTexCoord2f(0, 0);
glTexCoord2f(FimageTexCoords[0].x, FimageTexCoords[1].y);
glVertex2f(-fWidthHalf, -fHeightHalf);
// glTexCoord2f(1, 0);
glTexCoord2f(FimageTexCoords[1].x, FimageTexCoords[1].y);
glVertex2f(fWidthHalf + 1, -fHeightHalf);
// glTexCoord2f(1, 1);
glTexCoord2f(FimageTexCoords[1].x, FimageTexCoords[0].y);
glVertex2f(fWidthHalf + 1, fHeightHalf + 1);
// glTexCoord2f(0, 1);
glTexCoord2f(FimageTexCoords[0].x, FimageTexCoords[0].y);
glVertex2f(-fWidthHalf, fHeightHalf + 1);
glend();
End;
If Not b Then
gldisable(gl_Blend);
End;
Procedure TGreenfootImage.Rotate(degrees: integer);
//Var
// x, y, i, j: integer;
// tmp: Array Of Array[0..3] Of byte;
Begin
// Todo : Rotates this image around the center.
{ // Aktuell ist nur ein 90° weises Schlampiges Ding implementiert
While degrees < 0 Do
degrees := degrees + 360;
degrees := degrees Mod 360;
If degrees = 180 Then Begin
glDeleteTextures(1, @fimage); // Altes OpenGL Image Löschen
setlength(tmp, length(FRohdaten));
// Kopie anlegen
For i := 0 To high(tmp) Do
tmp[i] := FRohdaten[i];
// Drehung Durchführen
For i := 0 To fWidth * fHeight - 1 Do Begin
x := i Mod fWidth;
y := i Div fWidth;
j := (fHeight - y) * (fOpenGLWidth - 1) + (fWidth - x-1);
// j := (fHeight - (i Div fWidth) - 1) * fOpenGLWidth + (i Mod fWidth);
FRohdaten[i] := tmp[j];
End;
glGenTextures(1, @Fimage);
glBindTexture(GL_TEXTURE_2D, fimage);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, fOpenGLWidth, FOpenGLHeight, 0, GL_RGBA, GL_UNSIGNED_BYTE, @FRohdaten[0][0]);
End;}
End;
Procedure TGreenfootImage.Scale(Width, Height: integer);
Type
tcol = Array[0..3] Of byte;
Var