Apply microtus patches 1-20

Author: TheMeinerLP

build-logic/build.gradle.kts

@@ -0,0 +1,18 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    mavenCentral()
+    gradlePluginPortal()
+}
+
+dependencies {
+    val indraVersion = "3.1.3"
+    implementation("org.jetbrains.kotlin", "kotlin-gradle-plugin", "1.9.20")
+    implementation("net.kyori", "indra-common", indraVersion)
+    implementation("net.kyori", "indra-common", indraVersion)
+    implementation("net.kyori", "indra-publishing-sonatype", indraVersion)
+    implementation("org.graalvm.buildtools", "native-gradle-plugin", "0.9.28")
+    implementation("io.github.gradle-nexus", "publish-plugin", "2.0.0-rc-1")
+}

build-logic/src/main/kotlin/minestom.common-conventions.gradle.kts

@@ -0,0 +1,28 @@
+plugins {
+    java
+}
+
+// Always exclude checker-qual. This is the single most annoying thing that always reappears.
+configurations.all {
+    // We only use Jetbrains Annotations
+    exclude("org.checkerframework", "checker-qual")
+}
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(21))
+    }
+}
+
+tasks {
+    withType<JavaCompile> {
+        // We are fully aware, that we should be suppressing these instead of ignoring them here, but man keep my terminal clean.
+        options.compilerArgs.addAll(listOf("-Xlint:none", "-Xlint:-deprecation", "-Xlint:-unchecked"))
+    }
+    withType<Test> {
+        useJUnitPlatform()
+        // Viewable packets make tracking harder. Could be re-enabled later.
+        jvmArgs("-Dminestom.viewable-packet=false")
+        jvmArgs("-Dminestom.inside-test=true")
+    }
+}

build-logic/src/main/kotlin/minestom.native-conventions.gradle.kts

@@ -0,0 +1,14 @@
+plugins {
+    id("minestom.common-conventions")
+    id("org.graalvm.buildtools.native")
+}
+
+graalvmNative {
+    binaries {
+        named("main") {
+            buildArgs.add("--allow-incomplete-classpath")
+            // One day toolchains will support getting this automagically, but that day is not today.
+            toolchainDetection.set(false)
+        }
+    }
+}

build-logic/src/main/kotlin/minestom.publishing-conventions.gradle.kts

@@ -0,0 +1,40 @@
+plugins {
+    id("net.kyori.indra")
+    id("net.kyori.indra.publishing")
+    id("net.kyori.indra.publishing.sonatype")
+    id("io.github.gradle-nexus.publish-plugin")
+}
+
+indra {
+    javaVersions {
+        target(21)
+        testWith(21)
+    }
+
+    github("OneLiteFeatherNET", "Microtus") {
+        ci(true)
+        publishing(false)
+    }
+    mitLicense()
+    signWithKeyFromPrefixedProperties("onelitefeather")
+    configurePublications {
+        pom {
+            developers {
+                developer {
+                    id.set("themeinerlp")
+                    name.set("Phillipp Glanz")
+                    email.set("p.glanz@madfix.me")
+                }
+                developer {
+                    id.set("theEvilReaper")
+                    name.set("Steffen Wonning")
+                    email.set("steffenwx@gmail.com")
+                }
+            }
+        }
+    }
+}
+
+indraSonatype {
+    useAlternateSonatypeOSSHost("s01")
+}

build.gradle.kts

@@ -1,92 +1,50 @@
-import java.time.Duration
+import java.util.*
 
 plugins {
     `java-library`
+    id("minestom.publishing-conventions")
+    id("minestom.native-conventions")
     alias(libs.plugins.blossom)
-
-    `maven-publish`
     signing
-    alias(libs.plugins.nexuspublish)
 }
 
-// Read env vars (used for publishing generally)
-version = System.getenv("MINESTOM_VERSION") ?: "dev"
-val channel = System.getenv("MINESTOM_CHANNEL") ?: "local" // local, snapshot, release
-
-val shortDescription = "1.20.4 Lightweight Minecraft server"
-
-allprojects {
-    apply(plugin = "java")
-
-    group = "net.minestom"
-    version = rootProject.version
-    description = shortDescription
+var baseVersion by extra("1.3.2")
+var snapshot by extra("-SNAPSHOT")
 
-    repositories {
-        mavenCentral()
-        maven(url = "https://jitpack.io")
-    }
+group = "net.onelitefeather.microtus"
 
-    configurations.all {
-        // We only use Jetbrains Annotations
-        exclude("org.checkerframework", "checker-qual")
-    }
 
-    java {
-        withSourcesJar()
-        withJavadocJar()
+version = "%s%s".format(Locale.ROOT, baseVersion, snapshot)
 
-        sourceCompatibility = JavaVersion.VERSION_21
-        targetCompatibility = JavaVersion.VERSION_21
-    }
-
-    tasks.withType<Zip> {
-        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
-    }
-
-    tasks.withType<Test> {
-        useJUnitPlatform()
-
-        // Viewable packets make tracking harder. Could be re-enabled later.
-        jvmArgs("-Dminestom.viewable-packet=false")
-        jvmArgs("-Dminestom.inside-test=true")
-        minHeapSize = "512m"
-        maxHeapSize = "1024m"
-    }
-
-    tasks.withType<JavaCompile> {
-        options.encoding = "UTF-8"
-    }
+allprojects {
+    group = "net.onelitefeather.microtus"
+    version = "%s%s".format(Locale.ROOT, baseVersion, snapshot)
+    description = "Lightweight and multi-threaded Minecraft server implementation"
 }
 
 sourceSets {
     main {
-        java.srcDir(file("src/main/java"))
-        java.srcDir(file("src/autogenerated/java"))
+        java {
+            srcDir(file("src/autogenerated/java"))
+        }
+        blossom {
+            javaSources {
+                val gitCommit = System.getenv("GIT_COMMIT")
+                val gitBranch = System.getenv("GIT_BRANCH")
+                val group = System.getenv("GROUP")
+                val artifact = System.getenv("ARTIFACT")
+                property("\"&COMMIT\"", if (gitCommit == null) "null" else "\"${gitCommit}\"")
+                property("\"&BRANCH\"", if (gitBranch == null) "null" else "\"${gitBranch}\"")
+                property("\"&GROUP\"", if (group == null) "null" else "\"${group}\"")
+                property("\"&ARTIFACT\"", if (artifact == null) "null" else "\"${artifact}\"")
+            }
+        }
     }
 }
 
-dependencies {
-    // Core dependencies
-    api(libs.slf4j)
-    api(libs.jetbrainsAnnotations)
-    api(libs.bundles.adventure)
-    api(libs.hydrazine)
-    api(libs.bundles.kotlin)
-    api(libs.bundles.hephaistos)
-    implementation(libs.minestomData)
-    implementation(libs.dependencyGetter)
-
-    // Performance/data structures
-    implementation(libs.caffeine)
-    api(libs.fastutil)
-    implementation(libs.bundles.flare)
-    api(libs.gson)
-    implementation(libs.jcTools)
-
-    // Testing
-    testImplementation(libs.bundles.junit)
-    testImplementation(project(":testing"))
+java {
+    withJavadocJar()
+    withSourcesJar()
 }
 
 tasks {
@@ -107,98 +65,63 @@ tasks {
             links("https://jd.adventure.kyori.net/api/${libs.versions.adventure.get()}/")
         }
     }
-
-    blossom {
-        val gitFile = "src/main/java/net/minestom/server/Git.java"
-
-        val gitCommit = System.getenv("GIT_COMMIT")
-        val gitBranch = System.getenv("GIT_BRANCH")
-        val group = System.getenv("GROUP")
-        val artifact = System.getenv("ARTIFACT")
-
-        replaceToken("\"&COMMIT\"", if (gitCommit == null) "null" else "\"${gitCommit}\"", gitFile)
-        replaceToken("\"&BRANCH\"", if (gitBranch == null) "null" else "\"${gitBranch}\"", gitFile)
-        replaceToken("\"&GROUP\"", if (group == null) "null" else "\"${group}\"", gitFile)
-        replaceToken("\"&ARTIFACT\"", if (artifact == null) "null" else "\"${artifact}\"", gitFile)
+    withType<Zip> {
+        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
     }
+    withType<Test> {
+        useJUnitPlatform()
 
-    nexusPublishing{
-        useStaging.set(true)
-        this.packageGroup.set("net.minestom")
-
-        transitionCheckOptions {
-            maxRetries.set(360) // 1 hour
-            delayBetween.set(Duration.ofSeconds(10))
-        }
+        // Viewable packets make tracking harder. Could be re-enabled later.
+        jvmArgs("-Dminestom.viewable-packet=false")
+        jvmArgs("-Dminestom.inside-test=true")
+        minHeapSize = "512m"
+        maxHeapSize = "1024m"
+    }
 
-        repositories.sonatype {
-            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
-            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
 
-            if (System.getenv("SONATYPE_USERNAME") != null) {
-                username.set(System.getenv("SONATYPE_USERNAME"))
-                password.set(System.getenv("SONATYPE_PASSWORD"))
-            }
-        }
-    }
+}
 
-    publishing.publications.create<MavenPublication>("maven") {
-        groupId = "net.minestom"
-        // todo: decide on publishing scheme
-        artifactId = if (channel == "snapshot") "minestom-snapshots" else "minestom-snapshots"
-        version = project.version.toString()
+dependencies {
+    // Testing Framework
+    testImplementation(project(mapOf("path" to ":testing")))
+    // Only here to ensure J9 module support for extensions and our classloaders
+    testCompileOnly(libs.mockito.core)
 
-        from(project.components["java"])
 
-        pom {
-            name.set(this@create.artifactId)
-            description.set(shortDescription)
-            url.set("https://github.com/minestom/minestom")
+    // Logging
+    implementation(libs.bundles.logging)
+    // Libraries required for the terminal
+    implementation(libs.bundles.terminal)
 
-            licenses {
-                license {
-                    name.set("Apache 2.0")
-                    url.set("https://github.com/minestom/minestom/blob/main/LICENSE")
-                }
-            }
+    // Performance improving libraries
+    implementation(libs.caffeine)
+    api(libs.fastutil)
+    implementation(libs.bundles.flare)
 
-            developers {
-                developer {
-                    id.set("TheMode")
-                }
-                developer {
-                    id.set("mworzala")
-                    name.set("Matt Worzala")
-                    email.set("matt@hollowcube.dev")
-                }
-            }
+    // Libraries
+    api(libs.gson)
+    implementation(libs.jcTools)
+    // Path finding
+    api(libs.hydrazine)
 
-            issueManagement {
-                system.set("GitHub")
-                url.set("https://github.com/minestom/minestom/issues")
-            }
+    // Adventure, for user-interface
+    api(libs.bundles.adventure)
 
-            scm {
-                connection.set("scm:git:git://github.com/minestom/minestom.git")
-                developerConnection.set("scm:git:git@github.com:minestom/minestom.git")
-                url.set("https://github.com/minestom/minestom")
-                tag.set("HEAD")
-            }
+    // Kotlin Libraries
+    api(libs.bundles.kotlin)
 
-            ciManagement {
-                system.set("Github Actions")
-                url.set("https://github.com/minestom/minestom/actions")
-            }
-        }
-    }
+    api(libs.maven.resolver)
+    api(libs.maven.connector)
+    api(libs.maven.transport.http)
 
-    signing {
-        isRequired = System.getenv("CI") != null
+    // Minestom Data (From MinestomDataGenerator)
+    implementation(libs.minestomData)
 
-        val privateKey = System.getenv("GPG_PRIVATE_KEY")
-        val keyPassphrase = System.getenv()["GPG_PASSPHRASE"]
-        useInMemoryPgpKeys(privateKey, keyPassphrase)
+    // NBT parsing/manipulation/saving
+    api("io.github.jglrxavpok.hephaistos:common:${libs.versions.hephaistos.get()}")
+    api("io.github.jglrxavpok.hephaistos:gson:${libs.versions.hephaistos.get()}")
 
-        sign(publishing.publications)
-    }
+    // BStats
+    api(libs.bstats.base)
 }
+

code-generators/build.gradle.kts

@@ -2,6 +2,11 @@ plugins {
     application
 }
 
+repositories {
+    mavenLocal()
+    mavenCentral()
+}
+
 dependencies {
     // Provides the input JSON to generate from
     implementation(libs.minestomData)