build.gradle

import net.minecraftforge.gradleutils.PomUtils

plugins {
    id 'idea'
    id 'eclipse'
    id 'java-library'
    id 'maven-publish'
    alias libs.plugins.license
    //alias libs.plugins.versions
    alias libs.plugins.gradleutils
}

group = 'net.minecraftforge'
version = gradleutils.tagOffsetVersion
println "Version: $version"

java {
    toolchain.languageVersion = JavaLanguageVersion.of(17)
    withSourcesJar()
}

repositories {
    mavenCentral()
    maven gradleutils.forgeMaven
    mavenLocal()
}

changelog {
    from '1.0.0'
}

license {
    header = file('LICENSE-header.txt')
    newLine = false
}

dependencies {
    compileOnly(libs.modlauncher)
    compileOnly(libs.securemodules)
    compileOnly(libs.log4j.api)
    compileOnly(libs.nulls)
    compileOnly(libs.forgespi)
    
    api(libs.bundles.asm)
    implementation(libs.nashorn)
}

tasks.named('jar', Jar) {
    manifest {
        attributes([
            'Specification-Title': 'coremods',
            'Specification-Vendor': 'Forge Development LLC',
            'Specification-Version': '1', // TODO: Use the tag
            'Implementation-Title': project.name,
            'Implementation-Version': project.version,
            'Implementation-Vendor' :'Forge Development LLC'
        ], 'net/minecraftforge/coremod/')
    }
}

publishing {
    publications.register('mavenJava', MavenPublication) {
        pom {
            from components.java
            artifactId = 'coremods'
            name = 'Core Mods'
            description = 'JavaScript based core modding framework for use with Forge'
            url = 'https://github.com/MinecraftForge/CoreMods'
            PomUtils.setGitHubDetails(pom, 'CoreMods')
            license PomUtils.Licenses.LGPLv2_1
            
            developers {
                developer PomUtils.Developers.LexManos
                developer PomUtils.Developers.cpw
            }
        }
    }
    
    repositories {
        maven gradleutils.publishingForgeMaven
    }
}

allprojects {
    ext.VALID_VMS = [
        'Adoptium':  (17..21),
        'Amazon':    (17..21),
        'Azul':      (17..21),
        'BellSoft':  (17..21),
        'Graal_VM':  [17,     19, 20, 21],
        'IBM':       [17, 18, 19, 20    ],
        'Microsoft': [17,             21],
        'Oracle':    (17..21),
        'SAP':       (17..20)
    ]
    ext.VALID_VMS = [ 'Adoptium':  [17] ]
}

idea.module {
    downloadJavadoc = downloadSources = true
}